我們可以用一個cmd文件，通過doskey命令模擬linux下的alias，指定一些我們習慣的命令名，比如：

env.cmd

@echo off
doskey alias=doskey /macros
doskey ls=dir $*
doskey ll=dir /a $*
doskey cat=type $*
doskey open=explorer $*
doskey ps=tasklist $*

然後可以通過註冊表的 HKCU\Software\Microsoft\Command Processor 下的 AutoRun （REG_SZ）指定這個env.cmd的全名即可。

也可以利用下面這個cmd來設置它：

make_env.cmd

@echo off
pushd "%~dp0"
set sp0=------------------
set sp1=創建CMD啟動環境
set envfile="%CD%\env.cmd"
set getadminfile="%temp%\getadmin.vbs"
title %sp1%
color 5f
:: -=UAC功能開始=-
echo.
echo 正在啟動，請稍後...
attrib %envfile% | find "找不到" >nul 2>nul
if %errorlevel
 
%==0 goto patherror
"%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\SYSTEM" >nul 2>nul
if %errorlevel%==0 (
    goto Administrator
) else (
    if %errorlevel%==2 (
        goto patherror
    ) else (
        goto UAC
    )
)
:patherror
cls
echo 暫不支持從第三方軟件啟動，請手動運行。
 
echo.
echo 按任意鍵打開"%~n0%~x0"所在文件夾...
pause >nul
start "" explorer.exe /select,"%~f0"
goto :end
:UAC
echo Set sh = CreateObject^("Shell.Application"^) > %getadminfile%
echo sh.ShellExecute "%~f0", "", "", "runas", 1 >> %getadminfile%
ping 127.1 -n 1 >nul
%getadminfile%
goto :end
:Administrator
if exist %getadminfile% ( del %getadminfile% )
:: -=UAC功能結束=-
:mainmenu
cls
echo %sp0%
echo %sp1%
echo %sp0%
echo 1. 註冊
echo 2. 刪除
echo Q. 退出
echo.
set input=
set /p input=請選擇（直接回車：查看）：
if "%input%"=="" goto :show
if "%input%"=="1" goto :reg
if "%input%"=="2" goto :del
if /i "%input%"=="Q" goto :end
echo.
echo 輸入錯誤，請重新輸入!
ping 127.1 -n 2 >nul
goto :mainmenu
:show
reg query "HKCU\Software\Microsoft\Command Processor" /v AutoRun
echo %sp0%
echo %envfile%
echo %sp0%
type "%envfile%"
goto :gotomain
:reg
cls
echo 註冊
echo.
reg add "HKCU\Software\Microsoft\Command Processor" /v AutoRun /t REG_SZ /d "%envfile%" /f >nul
if %errorlevel% EQU 0 (
echo 註冊成功！
ping 127.1 -n 2 >nul
goto :mainmenu
) else (
echo 註冊失敗。
goto :gotomain
)
:del
cls
echo 刪除
echo.
reg delete "HKCU\Software\Microsoft\Command Processor" /v AutoRun /f >nul
if %errorlevel% EQU 0 (
echo 刪除成功！
ping 127.1 -n 2 >nul
goto :mainmenu
) else (
echo 刪除失敗。
goto :gotomain
)
:gotomain
echo.
echo 按任意鍵鍵返回主菜單...
pause>nul
goto :mainmenu
:end
if exist %getadminfile% ( del %getadminfile% )
color
title %ComSpec%
popd
exit /B

創建CMD啟動環境