題目模板：最短路

https://www.luogu.org/problem/show?pid=3371

千年不過的不用指針的spfa；
原來各位dalao是騙我的！
根本不用ff數組來判重！
加上這題目pas題解比較少就來談談5種AC的思路（順便總結一下）；
①floyd算法 時間：O(n^3)；空間：O（n^2）;
對於20%的數據：N<=5，M<=15
對於40%的數據：N<=100，M<=10000

②dijkstra算法
時間： O(n^2); 空間：O（n^2）;
對於70%的數據：N<=1000，M<=100000

uses math; 
const maxn=5000;
var g:array[1
 
..maxn,1..maxn] of longint;
    d:array[1..maxn] of longint; //pre[i]指最短路徑上I的前驅結點
    n,m,s,x,y,w,i,j:longint;
procedure dijkstra(v0:longint);
 var u:array[1..maxn] of boolean;
     i,j,k:longint; min:longint;
begin
  fillchar(u,sizeof(u),false);
  for i:=1 to n do d[i]:=g[v0,i];
  d[v0]:=0;
  u[v0]:
 
=true;
  for i:=1 to n-1 do begin   //每循環一次加入一個離1集合最近的結點並調整其他結點的參數
    min:=2147483647; k:=0; //k記錄離1集合最近的結點
    for j:=1 to n do
      if (not u[j]) and (d[j]<min) then begin
        k:=j; min:=d[j];
    end;
    if k=0 then break;
    u[k]:=true;
    for j:=1 to n do
      if (not u[j]) and (g[k,j]+d[k]<d[j]) then d[j]:=g[k,j]+d[k];
  end;
end;
begin
  readln(n,m,s);
  
 
for i:=1 to n do
    for j:=1 to n do if i=j then g[i,j]:=0 else g[i,j]:=2147483647;
  for i:=1 to m do begin
    readln(x,y,w);
    g[x,y]:=min(w,g[x,y]);
  end;
  dijkstra(s);      //找出最短路徑
  for i:=1 to n do write(d[i],‘ ‘);
  writeln;
end.

③dijkstra+前向星空間優化+堆優化
時間： O(n log n); 空間：O（kn）;
對於100%的數據：N<=10000，M<=500000

type rec=record
 pre,en,w:longint;
end;
rec2=record
 id,val:longint;
end;
const inf=233333333;
      maxm=500000;
      maxn=10000;
var i,j,n,m,s,x,y,z,tot,nd:longint;
    d,head:array[-maxn..maxn]of longint;
    a:array[-maxm..maxm]of rec;
    dui:array[0..4*maxm]of rec2;
procedure swap(var a,b:rec2);
var t:rec2;
begin
 t:=a; a:=b; b:=t;
end;
procedure adde(u,v,w:longint);
begin
 inc(tot); a[tot].en:=v;
 a[tot].pre:=head[u];
 head[u]:=tot;
 a[tot].w:=w;
end;
procedure swap(var a,b:longint);
var t:longint;
begin t:=a;a:=b;b:=t;end;
procedure up(x:longint);//將一個結點“上浮”
begin
  while x>1 do begin //沒有上浮到最頂層
    if dui[x].val>dui[x div 2].val then break;//如果上方的結點小於此節點，則暫停上浮
    swap(dui[x],dui[x div 2]);//交換上方結點與此結點
    x:=x div 2;
  end;
end;
procedure down(x:longint);//將一個節點“下沈”
  var y:longint;
begin
  while x<nd do begin
    y:=x+x;//y是x的左兒子
    if y>nd then break;//x已經沈到底部
    if (y<nd)and(dui[y+1].val<dui[y].val) then inc(y);//如果x存在右兒子，且右兒子比左兒子小，則將y賦值到右兒子
    if dui[x].val<=dui[y].val then break;//若兩個兒子中的較小值仍然比x大，則停止下沈
    swap(dui[x],dui[y]);//下沈
    x:=y;
  end;
end;
function pop():longint;
begin
  pop:=dui[1].id;
  swap(dui[1],dui[nd]);//將最後的結點（保證其沒有兒子）與最頂端交換
  dec(nd);
  down(1);//下沈頂端
end;
procedure dijkstra(v0:longint);
var i,j,k,minn,u,v,p:longint;
    vis:array[-maxn..maxn]of boolean;
begin
 fillchar(vis,sizeof(vis),false);
 for i:=1 to n do d[i]:=inf;
 d[v0]:=0;
 dui[1].val:=0;
 dui[1].id:=v0;
 nd:=1;
 for i:=1 to n do begin
  u:=pop();
  while vis[u] and (nd>0) do u:=pop();
  vis[u]:=true;
  p:=head[u];
  while p>0 do begin
   v:=a[p].en;
   if (not vis[v]) and(d[u]+a[p].w<d[v]) then begin
    d[v]:=d[u]+a[p].w;
    inc(nd);
    dui[nd].id:=v;
    dui[nd].val:=d[v];
    up(nd);
   end;
   p:=a[p].pre;
  end;
 end;
end;
begin
 readln(n,m,s);
 for i:=1 to m do begin
  readln(x,y,z);
  adde(x,y,z);
 end;
 dijkstra(s);
 for i:=1 to n do
 if d[i]=inf then write(2147483647,‘ ‘)else write(d[i],‘ ‘);
 writeln;

④ spfa隊列優化+指針鄰接表空間優化
時間： O(KE); 空間：O（KE）;
對於100%的數據：N<=10000，M<=500000；

type pp=^node;
      node=record
      en,w:longint;
      pre:pp;
      end;
const maxn=50040;
var dis:array[0..maxn]of longint;
    a:array[0..maxn]of pp;
    n,m,b,u,v,x,y,i,j,l,w,s:longint;
procedure adde(u,v,w:longint);
var p:pp;
begin
 new(p);
 p^.pre:=a[u]^.pre;
 p^.en:=v; p^.w:=w;
 a[u]^.pre:=p;
end;
procedure spfa;
var f:array[0..maxn]of boolean;
    q:array[0..4*maxn]of longint;
    p:pp;
    head,tail,u,v:longint;
begin
 q[1]:=s; dis[s]:=0;
 head:=0; tail:=1;
 fillchar(f,sizeof(f),false);
 while head<tail do begin
  inc(head); u:=q[head]; p:=a[u];
  while p^.pre<>nil do begin
   p:=p^.pre; v:=p^.en; w:=p^.w;
   if dis[v]>dis[u]+w then begin
    dis[v]:=dis[u]+w;
    if not f[v] then begin
     f[v]:=true;
     inc(tail); q[tail]:=v;
    end;
   end;
  end;
  f[u]:=false;
 end;
end;
begin
 readln(n,m,s);
 for i:=1 to n do begin
  new(a[i]);
  a[i]^.pre:=nil;
 end;
 for i:=1 to m do begin
  readln(u,v,w);
  adde(u,v,w);
 end;
  for i:=1 to n do
  dis[i]:=maxlongint div 3;
 spfa;
// writeln;
 for i:=1 to n do
  if dis[i]=maxlongint div 3 then write(‘2147483647 ‘)
  else write(dis[i],‘ ‘);
 close(input);
 close(output);
end.

⑤ spfa隊列優化+鏈式前向星空間優化
時間： O(KE); 空間：O（KE）;
對於100%的數據：N<=10000，M<=500000

type rec=record
 w,en,pre:longint;
end;
var n,m,s,x,y,z,tot,i:longint;
    head,q,d:array[1..1000000]of longint;
    a:array[1..1000000]of rec;
procedure adde(u,v,w:longint);
begin
 inc(tot);
 a[tot].en:=v;
 a[tot].pre:=head[u];
 a[tot].w:=w;
 head[u]:=tot;
end;
procedure spfa;
var h,t,i,v,u:longint;
begin
 for i:=1 to n do d[i]:=maxlongint;
 q[1]:=s; d[s]:=0;
 h:=0; t:=1;
 while h<t do begin
  inc(h);
  u:=q[h];
  i:=head[u];
  while i>0 do begin
   v:=a[i].en;
   if d[v]=maxlongint then begin
    d[v]:=d[u]+a[i].w;
    inc(t);q[t]:=v;
   end else
   if d[v]-d[u]>a[i].w then begin
    inc(t);q[t]:=v;
    d[v]:=a[i].w+d[u];
   end;
   i:=a[i].pre;
  end;
 end;
end;
begin
 readln(n,m,s);
 for i:=1 to m do begin
  readln(x,y,z);
  adde(x,y,z);
 end;
 spfa;
 for i:=1 to n do
  if d[i]=maxlongint then write(‘2147483647 ‘)
  else write(d[i],‘ ‘);
end.

最短路5解