TightVNC 企業內部部署
阿新 • • 發佈：2017-11-20
tightvnc
安裝腳本
安裝包放在ftp服務器上，使用ftp下載，再使用msiexec靜默安裝
@echo off
Rem 創建目錄
mkdir c:\temp
Rem 獲取網卡信息存放到單獨一臺ftp上（非必須）
ipconfig /all >>c:\temp\%username%.txt
Rem 上傳網卡信息
echo open 10.10.29.107 >putip.txt
Rem ftpuser是賬號 test.test是密碼
echo user ftpuser test.test >>putip.txt
echo binary >>putip.txt
echo put "c:\temp\%username%.txt" >>putip.txt
echo bye >>putip.txt
ftp -n -s:putip.txt
del putip.txt
rem 下載vnc
Rem 判斷系統是否64位是則下載64位安裝包，否則下載32位安裝包
if "%PROCESSOR_ARCHITECTURE%" == "AMD64" (set tightvnc=tightvnc288x64.msi) else (set tightvnc=tightvnc288x86.msi)
echo open 10.10.50.3 >ftp.txt
Rem ftpuser是賬號 test.test是密碼
echo user ftpuser test.test >>ftp.txt
rem dfws.2016 >>ftp.txt
echo cd "/資料共享庫/辦公軟件/00.裝機必備/vnc" >>ftp.txt
echo lcd "c:/temp" >>ftp.txt
echo binary >>ftp.txt
echo get %tightvnc% >>ftp.txt
echo bye >>ftp.txt
ftp -n -s:ftp.txt
del ftp.txt
rem 安裝vnc
Rem 靜默安裝參數，^是bat續行符 ADDLOCAL是選擇安裝那個客戶端Server是服務端，Client是客戶端
Rem 同時設置3個密碼都是test.9999 第一個是主要密碼，第二個是連接密碼 第三個是管理員密碼.
msiexec.exe /i c:\temp\%tightvnc% /qb /norestart ^
ADDLOCAL=Server SET_USEVNCAUTHENTICATION=1 VALUE_OF_USEVNCAUTHENTICATION=1 ^
SET_PASSWORD=1 VALUE_OF_PASSWORD=test.9999 ^
SET_VIEWONLYPASSWORD=1 VALUE_OF_VIEWONLYPASSWORD=test.9999 ^
SET_USECONTROLAUTHENTICATION=1 VALUE_OF_USECONTROLAUTHENTICATION=1 ^
SET_CONTROLPASSWORD=1 VALUE_OF_CONTROLPASSWORD=test.9999
Rem 彈出安裝成功是否提示
If errorlevel 1 (mshta vbscript:msgbox("安裝VNC失敗",64,"提示")(window.close))
else (mshta vbscript:msgbox("安裝VNC成功",64,"提示")(window.close))
本文出自 “天天向上” 博客，請務必保留此出處http://bshark.blog.51cto.com/10309374/1983384
TightVNC 企業內部部署