Shader "Custom/DifSpecPoint" {
    Properties {
        _Spec ("Spec", Color) = (1,1,1,1)  //高光顏色
        _Shin ("Shin", range(1,32)) = 2      //高光強度系數
    }
    SubShader {
        pass {
            tags{ "lightmode" = "forwardbase" }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "unitycg.cginc"
            #include "lighting.cginc"
            fixed4 _Spec;
            float _Shin;
            struct v2f{
                float4 pos:POSITION;
                float3 normal:NORMAL;
                float4 vertex:TEXCOORD2;
            };
            v2f vert(appdata_base v)
            {
                v2f o;
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.normal = normalize(v.normal);
                o.vertex = v.vertex;
                return o;
            }
            fixed4 frag(v2f IN):COLOR
            {
                float3 wpos = mul(unity_ObjectToWorld, IN.vertex).xyz;  //計算世界坐標系空間中的物體坐標（三維向量）
                //diffuse 漫反射
                float3 N = UnityObjectToWorldNormal(IN.normal);     //計算世界坐標空間中的法線向量
                float3 L = normalize(_WorldSpaceLightPos0).xyz;    //計算世界坐標空間中平行光向量
                float ndotl = saturate(dot(N, L));                                    //點積得平行光顏色系數
                fixed4 col = _LightColor0*ndotl;                                   //平行光顏色*系數得顏色
                //specular  高光
                float3 V = normalize(WorldSpaceViewDir(IN.vertex));    //計算世界坐標空間中的視向量
                float3 R = 2 * dot(N, L)*N - L; //phong                                //反射向量
                float3 H = normalize(V + L);    //blinnphong                         //半角向量：點到光源+點到攝像的單位向量，平均值
                float specScale = pow(saturate(dot(R, V)), _Shin);  //phong
                //specScale = pow(saturate(dot(H, N)), _Shin);      //blinnphong
                col += _Spec*specScale;                                       //顏色+高光*高光系數

                //pointlight  接收點光源
                //Shade4PointLights來自unitycg.cginc
                //其中用的參數前七個unity_4LightPosX0~unity4LightAtten0來自UnityShaderVariables.cginc，內建不需引用
                float3 pL = Shade4PointLights(unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0,
                    unity_LightColor[0].rgb, unity_LightColor[1].rgb, unity_LightColor[2].rgb, unity_LightColor[3].rgb,
                    unity_4LightAtten0,
                    wpos, N);
                col.rgb += pL;     //顏色+點光源反光

                col += UNITY_LIGHTMODEL_AMBIENT;  //最後加上環境光
                return col;
            }
            ENDCG
        }
    }
}
 

其中phong和blinnphong是兩種光照模型，所說blinnphong更好。

ShaderLab學習小結（三）漫反射+高光+點光源