Windows定時刪除某天前文件的批處理腳本
備註:
1.如XP下因為沒有forfiles.exe,拷貝windows2003下的forfiles.exe文件到XP的system32目錄即可使用forfiles命令。
2.該文檔適用於windows客戶端操作系統xp win7/8/10，windows服務器端操作系統 server 2003/2008/2012/2016。
3.如有錯漏，煩勞指出，謝謝！
forfiles.exe及幫助
描述:
選擇一個文件(或一組文件)並在那個文件上執行一個命令。這有助於批處理作業。
語法:
forfiles /p <目標目錄名> /d <天數> /c <執行的命令>
1.看看列出的三個參數都有什麽用處：(簡單解析)
/p 指定了要在哪個目錄裏查找文件，默認是當前工作目錄。
/d 指定一個日期或天數，用於比較文件的最後修改日期是否符合條件。
/c 對每個找到的文件執行的命令。
2.看看列出的三個參數都有什麽用處：(詳細解析)
/p <Path> ： 指定開始搜索文件的位置，如果不指定則默認為當前目錄。
/m <SearchMask> ： 文件查找所使用的通配符如代碼中的"*.log"則為所有日誌文件，當然也可以指定諸如"manmee_*.log"這樣以manmee開頭的所有日誌文件。如果不指定此參數則默認為"*.*"。
/d [{+|-}][{<Date>|<Days>}] ： 指定想選擇文件的最後修改時間，上文中用了 "/d -7" 表示所有以當天為基礎，7天以前的文件。
當然這裏還可以指定具體時間，例如："/d -08/18/2009"這樣所有早於2009年8月18日的文件。註意指定的時間必須是"MM/DD/YYYY"的格式。
/c 對所有文件以此執行指定的命令，命令體須在雙引號(")內，默認是"cmd /c echo @file"。上文中用到的是"cmd /c del /f @path"刪除指定文件。（這裏的@file 和 @path 為變量，下文中將進行解釋。
====================例子說明==========================
例1.要把在C盤根目錄下最後修改日期大於或等於2007年7月1日的文件復制到D盤根目錄下
forfiles /p "c:\" /d "2007-7-1" /c "cmd /c copy @path d:\"
例2.1 刪除在C盤backup目錄下最後修改日期在10天前的文件：
forfiles /p "c:\backup" /d -10 /c "cmd /c echo deleting @file ... && del /f @path"
例2.2 自動刪除D盤test目錄最後修改日期在7天前文件
forfiles /p "d:\test" /s /m *.* /d -7 /c "cmd /c del @path"
例2.3 刪除當前目錄下28天以前的擴展名為bkf文件（以當前系統時間為基準）
forfiles /m *.bkf /d -28 /c "cmd /c del @file /f"
刪除文件的語法解析
forefiles /p /m -d /c
forfiles /p 包含要刪除文件的完整路徑（如：F:\Logfiles) /m *.log -d -7 /c "cmd /c del /f @path"
解釋一下相關參數及命令
@PATH ： 表示文件的完整的路徑。
@File ： 表示文件名稱。
==========案例操作============
1.刪除所有的空目錄(以刪除d:\test目錄下為例)
dir /ad/b/s d:\test\ |sort /r >d:\kill.txt
For /f "tokens=*" %%i in (d:\kill.txt) DO rd "%%i"
del d:\kill.txt
2.自動刪除7天前文件和目錄
｛建一個bat文件的快捷方式在啟動，d:\test換成你要的目錄路徑。日期是指修改的日期。 ｝
原理：先刪過期文件，再刪所有的空目錄,這才是一個完整的刪除過程
@echo off
forfiles /p "d:\test" /s /m *.* /d -7 /c "cmd /c del @path"
dir /ad/b/s d:\test\ |sort /r >d:\kill.txt
For /f "tokens=*" %%i in (d:\kill.txt) DO rd "%%i"
del d:\kill.txt
Windows定時刪除某天前文件的批處理腳本