1.開啟目標excel,按alt + f11鍵開啟VBE視窗

2.選擇插入->模組貼上下面程式碼到編輯器中

程式碼：

Sub 保留表頭拆分資料為若干新工作簿()
 Dim arr, d As Object, k, t, i&, lc%, rng As Range, c%
 c = Application.InputBox("請輸入拆分列號", , 4, , , , , 1)
 If c = 0 Then Exit Sub
 Application.ScreenUpdating = False
 Application.DisplayAlerts = False
 arr = [a1].CurrentRegion
 lc = UBound(arr, 2)
 Set rng = [a1].Resize(, lc)
 Set d = CreateObject("scripting.dictionary")
 For i = 2 To UBound(arr)
 If Not d.Exists(arr(i, c)) Then
Set d(arr(i, c)) = Cells(i, 1).Resize(1, lc)
 Else
Set d(arr(i, c)) = Union(d(arr(i, c)), Cells(i, 1).Resize(1, lc))
 End If
 Next
 k = d.Keys
 t = d.Items
 For i = 0 To d.Count - 1
 With Workbooks.Add(xlWBATWorksheet)
rng.Copy .Sheets(1).[a1]
 t(i).Copy .Sheets(1).[a2]
 .SaveAs Filename:=ThisWorkbook.Path & "\" & k(i) & ".xls"
 .Close
 End With
 Next
 Application.DisplayAlerts = True
 Application.ScreenUpdating = True
 MsgBox "完畢"
End Sub
 

3.儲存後回到excel檔案，選擇開發工具->插入->表單控制元件(按鈕(窗體控制元件))，沒有開發工具選項的在設定裡面開啟選項如圖

4.按住滑鼠左鍵不動然後在excel中劃定一個按鈕區域，然後會自動彈出的視窗，選擇剛才儲存的巨集，點選確定

5.滑鼠從按鈕上面移開  ，然後點選按鈕輸入要列號，就是根據哪列的資料進行拆分檔案，下圖我們輸入4就是按照班級進行拆分，根據不同的班級拆分成不同的檔案

5.點選確定後，如果彈出完畢提示框代表拆分完成

6.到原始檔所在的目錄檔案中檢視拆分的檔案

Ref:   https://blog.csdn.net/ntotl/article/details/79141314