FOR這條命令基本上都被用來處理文字,但還有其他一些好用的功能!

看看他的基本格式(這裡我引用的是批處理中的格式,直接在命令列只需要一個%號)
FOR 引數 %%變數名 IN (相關檔案或命令) DO 執行的命令

引數:FOR有4個引數 /d   /l   /r   /f   他們的作用我在下面用例子解釋
%%變數名 :這個變數名可以是小寫a-z或者大寫A-Z,他們區分大小寫,FOR會把每個讀取到的值給他;
IN:命令的格式,照寫就是了;
(相關檔案或命令) :FOR要把什麼東西讀取然後賦值給變數,看下面的例子
do:命令的格式,照寫就是了!
執行的命令:對每個變數的值要執行什麼操作就寫在這.

可以在CMD輸入for /?看系統提供的幫助!對照一下
FOR %%variable IN (set) DO command [command-parameters]

%%variable 指定一個單一字母可替換的引數。
(set)      指定一個或一組檔案。可以使用萬用字元。
command    指定對每個檔案執行的命令。
command-parameters
             為特定命令指定引數或命令列開關。

現在開始講每個引數的意思

/d 
僅為目錄 
如果 Set (也就是我上面寫的 "相關檔案或命令") 包含萬用字元（* 和 ?），將對與 Set 相匹配的每個目

錄（而不是指定目錄中的檔案組）執行指定的 Command。

系統幫助的格式:FOR /D %%variable IN (set) DO command
他主要用於目錄搜尋,不會搜尋檔案,看這樣的例子

@echo off
for /d %%i in (*) do @echo %%i
pause

把他儲存放在C盤根目錄執行,就會把C盤目錄下的全部目錄名字打印出來,而檔名字一個也不顯示!
在來一個,比如我們要把當前路徑下資料夾的名字只有1-3個字母的打出來

@echo off
for /d %%i in (???) do @echo %%i
pause

這樣的話如果你當前目錄下有目錄名字只有1-3個字母的,就會顯示出來,沒有就不顯示了

思考題目:

@echo off
for /d %%i in (window?) do @echo %%i
pause

儲存到C盤下執行,會顯示什麼呢?自己看吧!
/D引數只能顯示當前目錄下的目錄名字,這個大家要注意!

/R
遞迴 
進入根目錄樹 [Drive:]Path，在樹的每個目錄中執行 for 語句。如果在 /R 後沒有指定目錄，則認為是

當前目錄。如果 Set 只是一個句點 (.)，則只列舉目錄樹。
系統幫助的格式:FOR /R [[drive:]path] %%variable IN (set) DO command

上面我們知道,/D只能顯示當前路徑下的目錄名字,那麼現在這個/R也是和目錄有關,他能幹嘛呢?放心他比

/D強大多了!
他可以把當前或者你指定路徑下的檔名字全部讀取,注意是檔名字,有什麼用看例子!

@echo off
for /r c:/ %%i in (*.exe) do @echo %%i
pause

咋們把這個BAT儲存到D盤隨便哪裡然後執行,我會就會看到,他把C盤根目錄,和每個目錄的子目錄下面全部

的EXE檔案都列出來了,這裡的c:/就是目錄了。

再來一個
@echo off
for /r %%i in (*.exe) do @echo %%i
pause

引數不一樣了，這個命令前面沒加那個C:/也就是搜尋路徑,這樣他就會以當前目錄為搜尋路徑,比如你這

個BAT你把他防災d:/test目錄下執行,那麼他就會把D:/test目錄和他下面的子目錄的全部EXE檔案列出

來!!!

/L
迭代數值範圍 
使用迭代變數設定起始值 (Start#)，然後逐步執行一組範圍的值，直到該值超過所設定的終止值 (End#)

。/L 將通過對 Start# 與 End# 進行比較來執行迭代變數。如果 Start# 小於 End#，就會執行該命令。

如果迭代變數超過 End#，則命令解釋程式退出此迴圈。還可以使用負的 Step# 以遞減數值的方式逐步執

行此範圍內的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 則生成序列 (5 4 3 2 1)。語法是：

系統幫助的格式:for /L %% Variable in (Start#,Step#,End#) do Command

例如：

@echo off
for /l %%i in (1,1,5) do @echo %%i
pause

儲存執行看效果,他會列印從1 2 3 4 5 這樣5個數字
(1,1,5)這個引數也就是表示從1開始每次加1直到5終止!

再看這個例子
@echo off
for /l %%i in (1,1,5) do start cmd
pause

執行後是不是嚇了一跳,怎麼多了5個CMD視窗,呵呵!如果把那個 (1,1,5)改成 (1,1,65535)會有什麼結果,

我先告訴大家,會開啟65535個CMD視窗....這麼多你不宕機算你強!

當然我們也可以把那個start cmd改成md %%i 這樣就會建立指定個目錄了!!!名字為1-65535

看完這個被我賦予破壞性質的引數後,我們來看最後一個引數

/f

含有/F的for詳細說明

含有/F的for有很大的用處，在批處理中使用的最多，用法如下：
格式：
FOR /F ["options"] %%i IN (file) DO command

FOR /F ["options"] %%i IN ("string") DO command

FOR /F ["options"] %%i IN ('command') DO command

這個可能是最常用的，也是最強的命令，主要用來處理檔案和一些命令的輸出結果。

file代表一個或多個檔案

string 代表字串

command代表命令

["options"] 可選

對於FOR /F %%i IN (file) DO command

file為檔名，按照官方的說法是，for會依次將file中的檔案開啟，並且在進行到下一個檔案之前將每個檔案讀取到記憶體，按照每一行分成一個一個的元素，忽略空白的行，看個例子。

假如檔案a.txt中有如下內容：

第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列

你想顯示a.txt中的內容，會用什麼命令呢？當然是type，type a.txt

for也可以完成同樣的命令：

for /f %%i in (a.txt) do echo %%i

還是先從括號執行，因為含有引數/f,所以for會先開啟a.txt，然後讀出a.txt裡面的所有內容，把它作為一個集合，並且以每一行作為一個元素，所以會產生這樣的集合，

{“第1行第1列 第1行第2列 第1行第3列”， //第一個元素

“第2行第1列 第2行第2列 第2行第3列”， //第二個元素

“第3行第1列 第3行第2列 第3行第3列”}   //第三個元素

集合中只有3個元素，同樣用%%i依次代替每個元素，然後執行do後面的命令。

具體過程：

用%%i代替“第1行第1列 第1行第2列 第1行第3列”，執行do後面的echo %%i，顯示“第1行第1列 第1行第2列第1行第3列”，

用%%i代替“第2行第1列 第2行第2列 第2行第3列”，執行echo %%i，顯示“第2行第1列 第2行第2列第2行第3列”，

依次，直到每個元素都代替完為止。

為了加強理解/f的作用，請執行一下兩個命令，對比即可明白：

for /f %%i in (a.txt) do echo %%i //這個會顯示a.txt裡面的內容，因為/f的作用，會讀出a.txt中 
的內容。

for %%i in (a.txt) do echo %%i //而這個只會顯示a.txt這個名字，並不會讀取其中的內容。

通過上面的學習，我們發現for /f會預設以每一行來作為一個元素，但是如果我們還想把每一行再分解更小的內容，該怎麼辦呢？不用擔心，for命令還為我們提供了更詳細的引數，使我們將每一行分為更小的元素成為可能。

它們就是：delims和tokens

delims 用來告訴for每一行應該拿什麼作為分隔符，預設的分隔符是空格和tab鍵

比如，還是上面的檔案，我們執行下面的命令：

for /f "delims= " %%i in (a.txt) do echo %%i

顯示的結果是：

第1行第1列
第2行第1列
第3行第1列

為什麼是這樣的呢。因為這裡有了delims這個引數，=後面有一個空格，意思是再將每個元素以空格分割，預設是隻取分割之後的第一個元素。

執行過程是：

將第一個元素“第1行第1列 第1行第2列 第1行第3列”分成三個元素：“第1行第1列” “第1行第2列” “第1行第3列”，它預設只取第一個，即“第1行第1列”，然後執行do後面的命令，依次類推。

但是這樣還是有侷限的，如果我們想要每一行的第二列元素，那又如何呢？

這時候，tokens跳出來說，我能做到。

它的作用就是當你通過delims將每一行分為更小的元素時，由它來控制要取哪一個或哪幾個。

還是上面的例子，執行如下命令：

for /f "tokens=2 delims= " %%i in (a.txt) do echo %%i

執行結果：

第1行第2列
第2行第2列
第3行第2列

如果要顯示第三列，那就換成tokens=3。

同時tokens支援萬用字元*，以及限定範圍。

如果要顯示第二列和第三列，則換成tokens=2,3或tokens=2-3,如果還有更多的則為：tokens=2-10之類的。

此時的命令為：

for /f "tokens=2,3 delims= " %%i in (a.txt) do echo %%i %%j

怎麼多出一個%%j？

這是因為你的tokens後面要取每一行的兩列，用%%i來替換第二列，用%%j來替換第三列。

並且必須是按照英文字母順序排列的，%%j不能換成%%k，因為i後面是j

執行結果為：

第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列

對以萬用字元*，就是把這一行全部或者這一行的剩餘部分當作一個元素了。

比如：

for /f "tokens=* delims= " %%i in (a.txt) do echo %%i

執行結果為：

第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列

其實就跟for /f %%i in (a.txt) do echo %%i的執行結果是一樣的。

再如：

for /f "tokens=2,* delims= " %%i in (a.txt) do echo %%i %%j

執行結果為：

第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列

用%%i代替第二列，用%%j代替剩餘的所有

最後還有skip合eol，這倆個簡單，skip就是要忽略檔案的前多少行，而eol用來指定當一行以什麼符號開始時，就忽略它。

比如：

for /f "skip=2 tokens=*" %%i in (a.txt) do echo %%i

結果為:

第3行第1列 第3行第2列 第3行第3列

用skip來告訴for跳過前兩行。

如果不加tokens=*的話，執行結果為：

第3行第1列

不知道怎麼回事。

再如，當a.txt內容變成：

.第1行第1列 第1行第2列 第1行第3列
.第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列

執行for /f "eol=. tokens=*" %%i in (a.txt) do echo %%i結果是：

第3行第1列 第3行第2列 第3行第3列

用eol來告訴for忽略以“.”開頭的行。

同樣也必須加tokens=*，否則只會顯示“第3行第1列”

在For命令語句的引數F中，最難理解的就是Delims和Tokens兩個選項，本文簡單的做一個比較和總結。
“For /f”常用來解析文字，讀取字串。分工上，delims負責切分字串，而tokens負責提取字串。如果把字串當作蛋糕，Delims像刀子，用來切蛋糕，tokens像叉子，用來取切好的蛋糕。下面我們用例項來進行理解。

把以下內容儲存為文字檔案“歌曲列表.txt”，注意副檔名為“.txt”：
序號、歌手名-歌曲名.字尾名
1、饒天亮-玫瑰愛人.wma 
2、高一首-我不願錯過.mp3
3、黃凱芹-傷感的戀人.MP3
4、黃燦-黃玫瑰.lrc
5、黎姿-如此這般的愛情故事.mp3

程式碼1：顯示全部內容
@echo off
for /f %%i in (歌曲列表.txt) do echo %%i
pause>nul
執行結果：
序號、歌手名-歌曲名.字尾名
1、饒天亮-玫瑰愛人.wma
2、高一首-我不願錯過.mp3
3、黃凱芹-傷感的戀人.MP3
4、黃燦-黃玫瑰.lrc
5、黎姿-如此這般的愛情故事.mp3

講解：
如果不使用引數“/f”，執行結果只顯示括號裡的文字字元“歌曲列表.txt”，而不能讀取文字檔案“歌曲列表.txt”中的內容。可見，“/f”是解析文字字串的好工具。

一、delims
假如只要序號，不要歌手名、歌曲名和字尾名，如何辦到？
程式碼2：預設提取第一列
@echo off
for /f "delims=、" %%i in (歌曲列表.txt) do echo %%i
pause>nul
執行結果：
序號
1
2
3
4
5

講解：
"delims=、"表示定義頓號“、”為分隔符，並用該分隔符“、”切分文字字串。字串就是“歌曲列表.txt”裡的內容，也就是檔案裡的文字和標點符號。
該頓號是原文中就有的。除了頓號“、”，原文中還有減號“-”和點號“.”，因此你也可以用它們來做分隔符。

程式碼3：用減號“-”做分隔符
@echo off
for /f "delims=-" %%i in (歌曲列表.txt) do echo %%i
pause>nul
執行結果：
序號、歌手名
1、饒天亮
2、高一首
3、黃凱芹
4、黃燦
5、黎姿

講解：
因為，當減號“-”被用做分隔符時，每行內容被減號“-”分隔成前後兩半，預設只顯示前半部分，而後半部分連同分隔符減號“-”都被忽略（省略）了。

程式碼4：用點號“.”做分隔符
@echo off
for /f "delims=." %%i in (歌曲列表.txt) do echo %%i
pause>nul
執行結果：
序號、歌手名-歌曲名
1、饒天亮-玫瑰愛人
2、高一首-我不願錯過
3、黃凱芹-傷感的戀人
4、黃燦-黃玫瑰
5、黎姿-如此這般的愛情故事

講解：
預設情況下，單純使用delims而不用tokens時，只顯示第一個分隔符前的內容，第一個分隔符和第一個分隔符後面的內容將被忽略。

程式碼5：定義多個分隔符
@echo off
for /f "delims=、-." %%i in (歌曲列表.txt) do echo %%i
pause>nul
執行結果：
序號
1
2
3
4
5

講解：
原因是，當定義頓號“、”、減號“-”和點號“.”三個標點符號為分隔符後，原文被分隔成四個部分。
如第二行“1、饒天亮-玫瑰愛人.wma”將被分隔成“1”、“饒天亮”、“玫瑰愛人”和“wma” 四個部分。
從第一行到最後一行，每行的每個部分對應下來相當於一個豎列。因此，原文就有“序號”、“歌手名”、“歌曲名”、“字尾名”四列。
一般情況下，只讀取第一列的內容。後面的內容需要用tokens選項提取。

二、tokens
假如只要歌手名和歌曲名，不要序號和字尾名，如何辦到？
程式碼6：提取單列
@echo off
for /f "tokens=2 delims=、." %%i in (歌曲列表.txt) do echo %%i
pause>nul
執行結果將顯示：
歌手名-歌曲名
饒天亮-玫瑰愛人
高一首-我不願錯過
黃凱芹-傷感的戀人
黃燦-黃玫瑰
黎姿-如此這般的愛情故事

講解：
用delims定義頓號“、”和點號“.”作為分隔符，將原文分成三部分。
如第六行“5、黎姿-如此這般的愛情故事.mp3”被分割成：
第一部分（第一列）：5
第二部分（第二列）：黎姿-如此這般的愛情故事
第三部分（第三列）：mp3
“tokens=2”表示用tokens提取第二列的字串，即“黎姿-如此這般的愛情故事”。
沒有被tokens定義提取的第一列和第三列將被忽略。

假如只要序號和歌曲名，而不要歌手名和字尾名，如何辦到？
程式碼7：提取多列
@echo off
for /f "tokens=1,3 delims=、-." %%i in (歌曲列表.txt) do echo %%i %%j
pause>nul
執行結果將顯示：
序號歌曲名
1  玫瑰愛人
2  我不願錯過
3  傷感的戀人
4  黃玫瑰
5  如此這般的愛情故事

講解：
“delims=、-.”表示定義頓號、減號和點號為分隔符。
“tokens=1,3”表示只提取第一列和第三列。
“%%i %%j”對應於“token”後面的列數。有多少列就要有多少個輸出變數，並且各變數中的字母存在先後順序。


如何只提取文字，不要標點符號？
程式碼8：忽略分隔符
@echo off
for /f "tokens=1,2-4 delims=、-." %%i in (歌曲列表.txt) do echo %%i %%j %%k %%l
pause>nul
執行結果：
序號歌手名 歌曲名 字尾名
1  饒天亮玫瑰愛人 wma
2  高一首我不願錯過 mp3
3  黃凱芹傷感的戀人 MP3
4  黃燦黃玫瑰 lrc
5  黎姿如此這般的愛情故事 mp3

講解：
預設情況下，用做分隔符的標點符號將被忽略。
“tokens=1,2-4”中的“2-4”表示第二至第四列。

三、小結

“For /f”
一句話總結：解析文字，讀取字串。

Delims的語法：
FOR /F "Delims=符號集"  %%I

IN (Command1) DO
Command2
一句話總結：忽略分隔符，切分字串。

delims的意義包括兩個方面：
第一、指定原文中的標點符號作為分隔符。使得文字被劃分為許多小部分，方便使用批處理命令讀取和編輯。
第二、讀取第一個分隔符之前的內容。忽略第一個分隔符和分隔符後面的內容，如需讀取和編輯，需要使用tokens等命令。

注意分隔符和標點符號的聯絡和區別。
分隔符就是原文中的標點符號，可以是一個標點符號也可以是多個。但原文中的標點符號不一定是分隔符。
分隔符需要定義，即用”delims=”來指定，等於號後面跟被用來做分隔符的標點符號，該標點符號來自原文。
當有多個標點符號被定義為分隔符時，標點符號之間沒有空格。當用空格做分隔符時，空格應該放在其它用作分隔符的標點符號之後。
即使不使用delims，預設情況下，批處理也將空格作為分隔符。如檔名“Program Files”中含有空格時，批處理一般只讀取空格前的“Program”，剩下的“Files”被忽略了。
例：
程式碼9：空格預設作為分隔符
@echo off
for /f "delims=" %%a in ("偉大的中國人民萬歲 萬歲 萬萬歲") do echo %%a
pause>nul
執行結果：
偉大的中國人民萬歲 萬歲 萬萬歲
講解：
“delims=”代表取消預設以空格作為分隔符。
批處理預設空格是分隔符，分隔符會隱藏第一個分隔符後面的所有內容。為了顯示完整的資訊，所以有必要取消該功能。
因此，當檔名或路徑中含有空格時，需要用雙引號括住。如果不使用雙引號，括號內的內容將被當做檔名，如果檔名不存在，將提示“系統找不到……”。
如果不使用“delims=”，即使使用雙引號，也只能顯示第一個空格前面的字串，後面的字串將被預設忽略。


Tokens的語法：
FOR /F "tokens=x,y,m-n"  %%I   IN (Command1) DO Command2
一句話總結：提取列。

Tokens的意義就是，提取指定的列。
注意列與句的聯絡與區別。
文字內容由許多文字字串組成，它們被標點符號分隔，兩個標點符號之間的語句我們稱為“句子”。
當標點符號被“tokens=”指定為分隔符之後，文字將被分成多個部分。對應的每行的每個部分我們稱之為“列”。
一列可能是一個句子，也可能包含多個句子，視delims定義的標點符號而定。

其它方面：關於“行”的提取，前面做過一個很簡單的：
@echo off
findstr /n .* 12.txt>>122.txt
set /p m=請輸入要定位的行：
findstr   /b "%m%" 122.txt