程式碼有註解。看不懂請留言。

Imports System.IO
Imports System.Net
Imports System.Net.Sockets
Imports System.Threading
Imports System.Text

Public Class Form1
    Private timeoutObject As ManualResetEvent
    Private ssocket As Socket
    Private isConn As Boolean

    
    Public Function CheckFtp(ByVal ip As String, ByVal ftpuser As String, ByVal ftppas As String, ByRef errmsg As String, Optional port As Integer = 21, Optional timeout As Integer = 2000) As Boolean
        '*********輸入資料檢查開始*********
        If ftpuser.Trim.Length = 0 Then
            errmsg = "FTP使用者名稱不能為空,請檢查設定!"
            Return False
        End If
        If ftppas.Trim.Length = 0 Then
            errmsg = "FTP密碼不能為空,請檢查設定!"
            Return False
        End If

        Dim address As IPAddress = Nothing

        Try
            address = IPAddress.Parse(ip)
        Catch ex As Exception
            errmsg = String.Format("FTP伺服器IP:{0}解析失敗,請檢查是否設定正確!", ip)
            Return False
        End Try
        '*********輸入資料檢查結束*********
        isConn = False
        Dim ret As Boolean = False
        Dim result(1024) As Byte
        '連線返回,使用者名稱返回,密碼返回,退出返回
        Dim pingStatus As Integer = 0
        Dim userStatus As Integer = 0
        Dim pasStatus As Integer = 0
        Dim exitStatus As Integer = 0

        timeoutObject = New ManualResetEvent(False)
        Try
            Dim receivelength As Integer
            ssocket = New Socket(AddressFamily.InterNetwork, SocketType.Stream, ProtocolType.Tcp)
            ssocket.SendTimeout = timeout
            ssocket.ReceiveTimeout = timeout

            Try
                ssocket.BeginConnect(New IPEndPoint(address, port), New AsyncCallback(AddressOf callBackMethod), ssocket)
                If timeoutObject.WaitOne(timeout, False) = False Then '阻止當前執行緒
                    ssocket.Close()
                    ssocket = Nothing
                    pingStatus = -1 '超時返回狀態碼-1，並返回false值
                End If
                If isConn = True Then '連線狀態
                    pingStatus = 200
                Else
                    pingStatus = -1
                End If
            Catch ex As Exception
                pingStatus = -1
            End Try

            If pingStatus = 200 Then '狀態碼200 - TCP連線成功
                receivelength = ssocket.Receive(result)
                pingStatus = getFtpReturnCode(result, receivelength) ' 連線狀態
                If pingStatus = 220 Then '狀態碼220 - FTP返回歡迎語
                    ssocket.Send(Encoding.Default.GetBytes(String.Format("{0}{1}", "USER " + ftpuser, Environment.NewLine)))
                    receivelength = ssocket.Receive(result)
                    userStatus = getFtpReturnCode(result, receivelength)
                    If userStatus = 331 Then
                        ssocket.Send(Encoding.Default.GetBytes(String.Format("{0}{1}", "PASS " + ftppas, Environment.NewLine)))
                        receivelength = ssocket.Receive(result)
                        pasStatus = getFtpReturnCode(result, receivelength)
                        If pasStatus = 230 Then
                            errmsg = String.Format("FTP:{0}@{1}登陸成功", ip, port)
                            ret = True
                            ssocket.Send(Encoding.Default.GetBytes(String.Format("{0}{1}", "QUIT", Environment.NewLine))) '登出FTP
                            receivelength = ssocket.Receive(result)
                            exitStatus = getFtpReturnCode(result, receivelength)
                        Else
                            errmsg = String.Format("FTP:{0}@{1}登陸失敗,使用者名稱或密碼錯誤({2})", ip, port, pasStatus) '狀態碼230的錯誤
                        End If
                    Else
                        errmsg = String.Format("使用使用者名稱:'{0}'登陸FTP:{1}@{2}時發生錯誤({3}),請檢查FTP是否正常配置!", ftpuser, ip, port, userStatus) '狀態碼331的錯誤
                    End If
                Else
                    errmsg = String.Format("FTP:{0}@{1}返回狀態錯誤({2}),請檢查FTP服務是否正常執行!", ip, port, pingStatus) '狀態碼220的錯誤
                End If
            Else
                errmsg = String.Format("無法連線FTP伺服器:{0}@{1},請檢查FTP服務是否啟動!", ip, port) '狀態碼200的錯誤
            End If
        Catch ex As Exception
            '連接出錯
            errmsg = String.Format("FTP:{0}@{1}連接出錯:", ip, port) + ex.Message
            'Common.logger(errmsg) '寫日誌
            ret = False
        Finally
            If ssocket IsNot Nothing Then
                ssocket.Close() '關閉socket
                ssocket = Nothing
            End If
        End Try
        Return ret
    End Function

    Private Sub callBackMethod(ByVal asyncResult As IAsyncResult)
        Try
            ssocket = asyncResult.AsyncState
            If ssocket IsNot Nothing Then
                ssocket.EndConnect(asyncResult)
                isConn = True
            End If
        Catch ex As Exception
            isConn = False
        Finally
            timeoutObject.Set()
        End Try
    End Sub
    ''' <summary>
    ''' 傳遞FTP返回的byte陣列和長度,返回狀態碼(Integer)
    ''' </summary>
    ''' <param name="retByte"></param>
    ''' <param name="retLen"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Private Function getFtpReturnCode(ByVal retByte() As Byte, ByVal retLen As Integer) As Integer
        Try
            Dim str As String = Encoding.ASCII.GetString(retByte, 0, retLen).Trim
            MsgBox(Encoding.UTF8.GetString(retByte)) '檢視每次返回情況
            Return Integer.Parse(str.Substring(0, 3))
        Catch ex As Exception
            Return -1
        End Try
    End Function
End Class