首先,我們先寫一個簡單的tryfinally 語句,來看一下IL反編譯後的程式碼 ,關於IL的一些知識,可以參考這個人的部落格(http://www.cnblogs.com/zery/p/3366175.html)。或者自己百度一下.NET IL 網上會有很多這樣的介紹,這裡本文不在介紹。下面開始介紹:

static int TestIntReturnInTry()
        {
            int i = 0;
            try
            {
                return i;
            }
            finally
 

            {
                i = 2;
            }
        }

通過IL檢視的效果為:

.method private hidebysig static int32  TestIntReturnInTry() cil managed
{
  // 程式碼大小       16 (0x10)
  /計算棧(Evaluation Stack) 可容納資料項的最大個數
  .maxstack  1
  //定義並初始化引數 並存入 區域性變量表(Record Frame)中 (此時我們會發現 這個區域性變量表中有CS$1$0000 這個其實是真實return 後面的那個變數,這裡我們可以理解為只要return 變數 ,C# 編譯器就會建立兩個變數,一個區域性變數,一個區域性變數的副本,用於真實的返回。我們通過.NET Reflector 可以檢視到，如通過NET Reflector所示(num2其實就是對應的CS$1$0000))
 

  .locals init ([0] int32 i,
           [1] int32 CS$1$0000)   
  //如果修補操作碼，則填充空間。儘管可能消耗處理週期，但未執行任何有意義的操作。
  IL_0000:  nop
  //將整數值 0 作為 int32 推送到計算堆疊上。
  IL_0001:  ldc.i4.0
  //從計算堆疊的頂部彈出當前值並將其儲存到索引 0 處的區域性變數列表中。
  IL_0002:  stloc.0
  .try
  {
   //如果修補操作碼，則填充空間。儘管可能消耗處理週期，但未執行任何有意義的操作。
    IL_0003:  nop
    //將索引 0 處的區域性變數載入到計算堆疊上。
 

    IL_0004:  ldloc.0
    //從計算堆疊的頂部彈出當前值並將其儲存到索引 1 處的區域性變數列表中。
    IL_0005:  stloc.1
    //退出受保護的程式碼區域，無條件將控制轉移到目標指令（縮寫形式）。到IL_000d
    IL_0006:  leave.s    IL_000d
  }  // end .try
  finally
  {
   //如果修補操作碼，則填充空間。儘管可能消耗處理週期，但未執行任何有意義的操作。
    IL_0008:  nop
    //將整數值 2 作為 int32 推送到計算堆疊上。
    IL_0009:  ldc.i4.2
     //從計算堆疊的頂部彈出當前值並將其儲存到索引 0 處的區域性變數列表中。
    IL_000a:  stloc.0
    //如果修補操作碼，則填充空間。儘管可能消耗處理週期，但未執行任何有意義的操作。
    IL_000b:  nop
    //finally 結束
    IL_000c:  endfinally
  }  // end handler
  //如果修補操作碼，則填充空間。儘管可能消耗處理週期，但未執行任何有意義的操作。
  IL_000d:  nop
  //將索引 1 處的區域性變數載入到計算堆疊上。
  IL_000e:  ldloc.1
  // 從當前方法返回，並將返回值（如果存在）從呼叫方的計算堆疊推送到被呼叫方的計算堆疊上。由於上一步(IL_000e) 把索引1處的載入到計算機堆疊上,所以return 返回的就是這個值 即CS$1$0000
  IL_000f:  ret
} // end of method TryRetrunFinally::TestIntReturnInTry

我們簡單來畫一下這個流程(有點粗糙,請讀者見諒):




.NET Reflector 檢視反編譯的結果,返回的是num2

private static int TestIntReturnInTry()
{
    int num2;
    int num = 0;
    try
    {
        num2 = num;
    }
    finally
    {
        num = 2;
    }
    return num2;
}

以上就是簡單返回一個int的情況，下面我們來分析返回一個引用型別(這裡使用User案例分析)。

class User
    {
        public string Name { get; set; }
        public DateTime BirthDay { get; set; }
    }
static User TestUserReturnInTry()
        {
            User user = new User()
            {
                Name = "Mike",
                BirthDay = new DateTime(2010, 1, 1)
            };
            try
            {
                return user;
            }
            finally
            {
                user.Name = "Rose";
                user.BirthDay = new DateTime(2010, 2, 2);
                Console.WriteLine("UserName Has changed");
                user = null;
            }
        }

通過IL檢視的程式碼為:

.method private hidebysig static class NowCoderProgrammingProject.User 
        TestUserReturnInTry() cil managed
{
  // 程式碼大小       93 (0x5d)
  /計算棧(Evaluation Stack) 可容納資料項的最大個數
  .maxstack  4    

   //定義並初始化引數 並存入 區域性變量表(Record Frame)中（<>g__initLocal0 這個是編譯器預設生成的一個區域性變數,CS$1$0000 是return 生的一個區域性變數）
  .locals init ([0] class NowCoderProgrammingProject.User user,
           [1] class NowCoderProgrammingProject.User '<>g__initLocal0',
           [2] class NowCoderProgrammingProject.User CS$1$0000)     
  //如果修補操作碼，則填充空間。儘管可能消耗處理週期，但未執行任何有意義的操作。
  IL_0000:  nop
  //建立一個值型別的新物件或新例項，並將物件引用（User 型別）推送到計算堆疊上。
  IL_0001:  newobj     instance void NowCoderProgrammingProject.User::.ctor()
  //從計算堆疊的頂部彈出當前值並將其儲存到索引 1 處的區域性變數列表中。
  IL_0006:  stloc.1 
  //將索引 1 處的區域性變數載入到計算堆疊上。    
  IL_0007:  ldloc.1 
  //推送對元資料中儲存的字串的新物件引用。
  IL_0008:  ldstr      "Mike"
  //  對物件呼叫後期繫結方法，並且將返回值推送到計算堆疊上。
  IL_000d:  callvirt   instance void NowCoderProgrammingProject.User::set_Name(string) 
  //如果修補操作碼，則填充空間。儘管可能消耗處理週期，但未執行任何有意義的操作。
  IL_0012:  nop
  //將索引 1 處的區域性變數載入到計算堆疊上。
  IL_0013:  ldloc.1
  //將所提供的 int32 型別的值作為 int32 推送到計算堆疊上。
  IL_0014:  ldc.i4     0x7da  
  //將整數值 1 作為 int32 推送到計算堆疊上。
  IL_0019:  ldc.i4.1
   //將整數值 1 作為 int32 推送到計算堆疊上。
  IL_001a:  ldc.i4.1
  //生成一個新的DateTime的例項
  IL_001b:  newobj     instance void [mscorlib]System.DateTime::.ctor(int32,
                                                                      int32,
                                                                      int32)
  //呼叫虛方法設定日期
  IL_0020:  callvirt   instance void NowCoderProgrammingProject.User::set_BirthDay(valuetype [mscorlib]System.DateTime)
  IL_0025:  nop
  //將索引 1 處的區域性變數載入到計算堆疊上。
  IL_0026:  ldloc.1
   //從計算堆疊的頂部彈出當前值並將其儲存到索引 0 處的區域性變數列表中。
  IL_0027:  stloc.0
  .try
  {
    IL_0028:  nop
    //將索引 0 處的區域性變數載入到計算堆疊上。
    IL_0029:  ldloc.0
    //從計算堆疊的頂部彈出當前值並將其儲存到索引 2 處的區域性變數列表中。
    IL_002a:  stloc.2
     //退出受保護的程式碼區域，無條件將控制轉移到目標指令（縮寫形式）。到IL_005a
    IL_002b:  leave.s    IL_005a
  }  // end .try
  finally
  {
    IL_002d:  nop
     //將索引 0 處的區域性變數載入到計算堆疊上。
    IL_002e:  ldloc.0
    //推送對元資料中儲存的字串Rose的新物件引用。
    IL_002f:  ldstr      "Rose"
    //呼叫虛方法設定字串Mame的值
    IL_0034:  callvirt   instance void NowCoderProgrammingProject.User::set_Name(string)
    IL_0039:  nop
     //將索引 0 處的區域性變數載入到計算堆疊上。
    IL_003a:  ldloc.0
    //將所提供的 int32 型別的值作為 int32 推送到計算堆疊上。
    IL_003b:  ldc.i4     0x7da (2010)
    //將整數值 2 作為 int32 推送到計算堆疊上。
    IL_0040:  ldc.i4.2
     //將整數值 2 作為 int32 推送到計算堆疊上。
    IL_0041:  ldc.i4.2
    //生成DateTime的新例項
    IL_0042:  newobj     instance void [mscorlib]System.DateTime::.ctor(int32,
                                                                        int32,
                                                                        int32)
    //呼叫許方法設定BirthDay的值                                                                   
    IL_0047:  callvirt   instance void NowCoderProgrammingProject.User::set_BirthDay(valuetype [mscorlib]System.DateTime)
    IL_004c:  nop
      //推送對元資料中儲存的字串UserName Has changed的新物件引用。
    IL_004d:  ldstr      "UserName Has changed"
    //呼叫虛方法進行輸出
    IL_0052:  call       void [mscorlib]System.Console::WriteLine(string)
    IL_0057:  nop
    //將空引用（O 型別）推送到計算堆疊上。
    IL_0058:  ldnull
    //從計算堆疊的頂部彈出當前值並將其儲存到索引 0 處的區域性變數列表中。
    IL_0059:  stloc.0
    IL_005a:  nop
    IL_005b:  endfinally
  }  // end handler
  IL_005c:  nop
  //  將索引 2 處的區域性變數載入到計算堆疊上。
  IL_005d:  ldloc.2
  IL_005e:  ret
} // end of method TryRetrunFinally::TestUserReturnInTry

IL流程圖如下:

通過.NET Reflaector 檢視的反編譯結果為:

private static User TestUserReturnInTry()
{
    User user3;
    User user = new User {
        Name = "Mike",
        BirthDay = new DateTime(0x7da, 1, 1)
    };
    try
    {
        user3 = user;
    }
    finally
    {
        user.Name = "Rose";
        user.BirthDay = new DateTime(0x7da, 2, 2);
        Console.WriteLine("UserName Has changed");
        user = null;
    }
    return user3;
}

完整的程式碼和輸出如下:

using System;
using System.Collections.Generic;
using System.Linq;
using System.Text;
using System.Threading.Tasks;

namespace NowCoderProgrammingProject
{
    class TryRetrunFinally
    {
        public static void Main()
        {
            int val = TestIntReturnInTry();
            Console.WriteLine("val:"+val);
            User user = TestUserReturnInTry();
            if (user == null)
            {
                Console.WriteLine("User is null");
            }
            else
            {
                Console.WriteLine("user's name:" + user.Name);
                Console.WriteLine("user's birthday:" + user.BirthDay.ToString("yyyy-MM-dd"));
            }
        }

        static int TestIntReturnInTry()
        {
            int i = 0;
            try
            {
                return i;
            }
            finally
            {
                i = 2;
            }
        }

        static User TestUserReturnInTry()
        {
            User user = new User()
            {
                Name = "Mike",
                BirthDay = new DateTime(2010, 1, 1)
            };
            try
            {
                return user;
            }
            finally
            {
                user.Name = "Rose";
                user.BirthDay = new DateTime(2010, 2, 2);
                Console.WriteLine("UserName Has changed");
                user = null;
            }
        }
    }
    class User
    {
        public string Name { get; set; }
        public DateTime BirthDay { get; set; }
    }
}

輸出結果為下圖:

另附.NET 中IL指令表: