pmtest1.asm

; pmtest1.asm
; 編譯方法：nasm pmtest1.asm -o pmtest1.com
; ==========================================

%include	"pm.inc"	; 常量, 巨集, 以及一些說明

org	0100h
	jmp	LABEL_BEGIN

[SECTION .gdt]
; GDT
;                                         段基址,      段界限     , 屬性
LABEL_GDT:		Descriptor	       0,                0, 0     		; 空描述符
LABEL_DESC_CODE32:	Descriptor	       0, SegCode32Len - 1, DA_C + DA_32	; 非一致程式碼段, 32
LABEL_DESC_VIDEO:	Descriptor	 0B8000h,           0ffffh, DA_DRW		; 視訊記憶體首地址
; GDT 結束

GdtLen		equ	$ - LABEL_GDT	; GDT長度
GdtPtr		dw	GdtLen - 1	; GDT界限
		dd	0		; GDT基地址

; GDT 選擇子
SelectorCode32		equ	LABEL_DESC_CODE32	- LABEL_GDT
SelectorVideo		equ	LABEL_DESC_VIDEO	- LABEL_GDT
; END of [SECTION .gdt]

[SECTION .s16]
[BITS	16]
LABEL_BEGIN:
	mov	ax, cs
	mov	ds, ax
	mov	es, ax
	mov	ss, ax
	mov	sp, 0100h

	; 初始化 32 位程式碼段描述符
	xor	eax, eax
	mov	ax, cs
	shl	eax, 4
	add	eax, LABEL_SEG_CODE32
	mov	word [LABEL_DESC_CODE32 + 2], ax
	shr	eax, 16
	mov	byte [LABEL_DESC_CODE32 + 4], al
	mov	byte [LABEL_DESC_CODE32 + 7], ah

	; 為載入 GDTR 作準備
	xor	eax, eax
	mov	ax, ds
	shl	eax, 4
	add	eax, LABEL_GDT		; eax <- gdt 基地址
	mov	dword [GdtPtr + 2], eax	; [GdtPtr + 2] <- gdt 基地址

	; 載入 GDTR
	lgdt	[GdtPtr]

	; 關中斷
	cli

	; 開啟地址線A20
	in	al, 92h
	or	al, 00000010b
	out	92h, al

	; 準備切換到保護模式
	mov	eax, cr0
	or	eax, 1
	mov	cr0, eax

	; 真正進入保護模式
	jmp	dword SelectorCode32:0	; 執行這一句會把 SelectorCode32 裝入 cs, 並跳轉到 Code32Selector:0  處
; END of [SECTION .s16]


[SECTION .s32]; 32 位程式碼段. 由真實模式跳入.
[BITS	32]

LABEL_SEG_CODE32:
	mov	ax, SelectorVideo
	mov	gs, ax			; 視訊段選擇子(目的)

	mov	edi, (80 * 10 + 0) * 2	; 螢幕第 10 行, 第 0 列。
	mov	ah, 0Ch			; 0000: 黑底    1100: 紅字
	mov	al, 'P'
	mov	[gs:edi], ax

	; 到此停止
	jmp	$

SegCode32Len	equ	$ - LABEL_SEG_CODE32
; END of [SECTION .s32]
 

下面我以pmtest1.asm為例，回答下面的問題。
（1）[SECTION .XXX]為何物？
（2）段描述符(Descriptor)、全域性描述符表(GDT)、全域性描述符表暫存器(GDTR)、選擇子(SelectorXXX) 為何物？有什麼作用？
（3）真實模式下的定址方式與保護模式下的定址方式的區別？
（4）段描述符巨集定義和初始化段描述符
（5）載入GDTR

1、[SECTION .XXX]為何物？
SECTION和SEGMENT的作用相類似，就是代表“段”的意思。從整個程式來看，該程式分為3個模組，分別是[SECTION .gdt]、[SECITON .s16]、[SECTION .s32]三部分。我們很容易就可以看出，其中的[SECTION .gdt]應該是資料段，其他的兩個是程式碼段。通過[SECTION .XXX]將程式分成不同模組，完成不同的功能，使得程式看起來清晰明瞭。

2、描述符(Descriptor)、全域性描述符表(GDT)、全域性描述符表暫存器(GDTR)、選擇子(SelectorXXX) 是什麼？用來做什麼？

段（Segment），在80X86中，分段機制將記憶體空間分成一個或者多個線性區域，我們把這些線性區域稱為段。我們需要將這些段區分開來，於是分段機制為每個段賦予3個屬性，分別是：段基址(Base address)：指定段線上性地址空間中的開始地址。段界限(Limit)：表示了段內最大可用偏移量，也就是說它定義了段的長度。段屬性(Attribute)：指定了段的特性，包括：可讀，可寫或者可執行，特權等級等特性。

段描述符(Descriptor)，

在程式中，我們需要定義一個數據結構來記錄段的屬性，有段基址(Base)，段界限(Limit)，段屬性(Attribute)，我們稱它為段描述符(Descriptor)。段是邏輯概念，而段描述符是表示段的資料結構，每個段描述符要佔用8個位元組的空間。

段描述符表(Descriptor Table)，在一個程式中，不只存在一個段（段描述符）。所以我們需要將這些段描述符組織起來，於是定義了一個儲存段描述符的陣列，稱為段描述符表。段描述符表有兩種，一種是全域性描述符表（GDT），一種是區域性描述符表（LDT），系統中供所有的任務共享的是全域性描述符表，而不同的任務卻是使用自己的區域性描述符表。

段選擇子(SelectorXXX)，把所有段描述符都儲存在段描述符表中，當我們使用其中某一個段的時候，我們並不直接指向該段，而是通過該段描述符在段描述符表中的位置來訪問的。故段選擇子，就是一個16位的識別符號，用來標識該段描述符在描述符表中的位置。

段描述符表暫存器，如何讓系統知道段描述符表在什麼地方呢？處理器提供了記憶體管理暫存器，分別是全域性描述符表暫存器(GDTR)、區域性描述符表暫存器(LDTR)。GDTR暫存器中用於存放全域性描述符表GDT的32位線性基地址和16位的表的長度值。LDTR暫存器中用於存放區域性描述符表LDT的32位線性基地址和16位的表的長度值。通過系統指令，lgdt將GDT的線性基址和長度值載入到GDTR暫存器中，lldt將LDT的線性基址和長度值載入到LDTR暫存器中。

下面我們來分析pmtest1.asm中的原始碼：

[SECTION .gdt]
; GDT
;                                         段基址,      段界限     , 屬性
LABEL_GDT:		Descriptor	       0,                0, 0     		; 空描述符
LABEL_DESC_CODE32:	Descriptor	       0, SegCode32Len - 1, DA_C + DA_32	; 非一致程式碼段, 32
LABEL_DESC_VIDEO:	Descriptor	 0B8000h,           0ffffh, DA_DRW		; 視訊記憶體首地址
; GDT 結束

GdtLen		equ	$ - LABEL_GDT	; GDT長度
GdtPtr		dw	GdtLen - 1	; GDT界限
		dd	0		; GDT基地址

; GDT 選擇子
SelectorCode32		equ	LABEL_DESC_CODE32	- LABEL_GDT
SelectorVideo		equ	LABEL_DESC_VIDEO	- LABEL_GDT
; END of [SECTION .gdt]

在程式中，4、5、6行定義了3個段描述符，LABEL_GDT（空描述符），LABEL_DESC_CODE32（32位程式碼段描述符），LABEL_SESC_VIDEO（顯示記憶體描述符）。每個描述符都包含了3個屬性，段基址、段界限、段屬性。將三個描述符組織到一起構成一個全域性段描述符表(GDT)。

GdtLen是GDT的長度。GdtPtr為一個數據結構，包含兩個元素，第一個元素是2 bytes的GDT界限。第二個元素是4 bytes的GDT的基地址。該資料結構與全域性描述符表暫存器（GDTR）的資料結構相同，所以在載入GDTR的時候(原始碼55行)，就是將該GdtPtr載入到GDTR中。

由於第一個段LABEL_GDT是空描述符，它僅僅代表該GDT的初始地址，所以該描述符為空描述符，一般情況下，不為它建立選擇子。然後該程式建立了兩個選擇子(24、25行)SelectorCode32和SelectorVideo，分別對應著這兩個段LABEL_SESC_CODE32和LABEL_DESC_VIDEO。

這段程式碼的結構大家應該明白了吧。

下面我要分別介紹段描述符，全域性描述符表暫存器，選擇子的資料結構。
段描述符(Descriptor)的結構圖如下：

段描述符佔有8個位元組，在這裡我只想提醒大家一下，段基址分別佔有BYTE2、BYTE3、BYTE4和BYTE7。

段選擇子(SelectorXXX)的結構圖如下圖所示：

在這裡簡單的介紹一下，它使用13位來表示描述符索引，故每一個描述符表最多隻用8192個描述符，除去第一個空描述符，則可以使用的描述符為8191個描述符。
TI標誌著該選擇子所指向的段描述符是全域性描述符，還是區域性描述符。當TI=0時，表示全域性描述符，當TI=1時，表示區域性描述符。
RPL請求優先順序，稍後下一節將會提到。

全域性描述符表暫存器(GDT)的結構圖如下所示：

在這裡，你可以和上面程式中的GdtPtr資料結構做比較，是不是格式相同。2個位元組表示GDT界限，4個位元組表示GDT基地址。

3、真實模式下的定址方式與保護模式下的定址方式有什麼不同？

在真實模式下，也就是在8086系統下的定址方式。 Intel 8086是16位的CPU，它有著16位的暫存器(Register)，16位的資料匯流排(Data Bus)以及20位的地址匯流排(Address Bus)和1MB的定址能力。一個地址是由段和偏移兩部分組成的，實體地址遵循這樣的計算公式：
實體地址(Physical Address) = 段值(Segment) * 16 + 偏移(Offset)。其中段值和偏移都是16位的。故定址範圍為1MB。

在保護模式下，有了分段機制，所以它的定址方式發生了很大的變化。具體如下圖所示：

在保護模式下，首先使用段選擇子在段描述符表中查詢到相對應的段描述符，找到32位段基址，然後在與32位的偏移量相加，得到線性地址。段基址和段偏移量都是32位的，所以定址範圍大小為4GB。在程式中jmp dword SlectorCode32:0的作用，就是進入保護模式下的定址方式。其中，在使用某個段時，它的段選擇子是儲存在段暫存器中的。

這裡面存在著一個問題，是否我們每次定址都要先去全域性描述符表暫存器（GDTR）中，查詢到全域性描述符表(GDT)的基址，然後再次根據選擇子的索引跳轉到該描述符所在的位置，然後取得段描述符中的基址，如果這樣的話，我們裡裡外外採訪了幾次記憶體，太浪費時間了。實際上段暫存器結構是這樣的：

這樣的好處就是，我們可以直接獲取段描述符。

4、描述符巨集定義和初始化段描述符

描述符巨集定義：

; 描述符
; usage: Descriptor Base, Limit, Attr
;        Base:  dd
;        Limit: dd (low 20 bits available)
;        Attr:  dw (lower 4 bits of higher byte are always 0)
%macro Descriptor 3
	dw	%2 & 0FFFFh				; 段界限 1				(2 位元組)
	dw	%1 & 0FFFFh				; 段基址 1				(2 位元組)
	db	(%1 >> 16) & 0FFh			; 段基址 2				(1 位元組)
	dw	((%2 >> 8) & 0F00h) | (%3 & 0F0FFh)	; 屬性 1 + 段界限 2 + 屬性 2		(2 位元組)
	db	(%1 >> 24) & 0FFh			; 段基址 3				(1 位元組)
%endmacro ; 共 8 位元組

2、3、4、5行註釋告訴我們，該巨集定義需要三個變數，分別是段基址(4 bytes)，段界限(4 bytes)，段屬性(dw)。              
回顧剛才的段描述符結構，該巨集定義，就是將變數Base,Limit,Attr分別安插到描述符中相應的位置。Base是%1，Limit是%2，Attr是%3。
7行是將Limit低16位賦值給描述符的BYTE0和BYTE1
8 行是將Base低16位賦值給描述符的BYTE2和BYTE3
9 行是將Base右移16位後的低8位（也就是原Base的第16—23位）賦值給描述符的BYTE4
10行是將Limit右移8位之後的第8—11位和Attr的0—7和12—15位，組合起來儲存到描述符的BYTE5和BYTE6
11行是將Base右移24位後的低8位（也就是原Base的24—32位）賦值給描述符的BYTE7

初始化段描述符程式碼：

; 初始化 32 位程式碼段描述符
xor	eax, eax
mov	ax, cs
shl	eax, 4
add	eax, LABEL_SEG_CODE32
mov	word [LABEL_DESC_CODE32 + 2], ax
shr	eax, 16
mov	byte [LABEL_DESC_CODE32 + 4], al
mov	byte [LABEL_DESC_CODE32 + 7], ah

為什麼要初始化？你會發現這裡只是修改了段描述符基地址，即LABEL_DESC_CODE32的BYTE2，BYTE4，BYTE7。是不是突然恍然大悟？因為在我們初始化該LABEL_DESC_CODE32描述符時，將其基地址初始化為0，所以我們要修改描述符的基地址為其實際的地址。這也是在前面介紹段描述符的時候，我提醒大家需要注意的地方，即描述符的基地址所佔有的位元組是BYTE2，BYTE4，BYTE7。

5、載入GDTR

; 為載入 GDTR 作準備
xor	eax, eax
mov	ax, ds
shl	eax, 4
add	eax, LABEL_GDT		; eax <- gdt 基地址
mov	dword [GdtPtr + 2], eax	; [GdtPtr + 2] <- gdt 基地址

; 載入 GDTR
lgdt	[GdtPtr]

這個很好理解，我們就是對GdtPtr進行賦值，主要是初始化GDT的基地址。也就是將GDT的初始地址，賦值給GdtPtr的BYTE2，BYTE3，BYTE4，BYTE5。使GdtPtr的資料結構剛好符合GDTR，然後執行lgdt [GdtPtr]，載入全域性描述符表暫存器。將GDT的基地址和界限賦值給GDTR。

最近做了一個 Json 格式化，線上時間戳轉換，Md5 編碼，URL 編碼，Base64 編解碼，正則表示式，Linux 命令大全 等功能，歡迎大家使用和加入。