#

# 這段程式碼被連線到system模組的最前面，這也是它為什麼稱之為head.s的原因。

# 從這裡開始核心完全執行在保護模式下。head.s採用的是at&t格式的

# 彙編。注意的是程式碼中的賦值方向是從左到右。

#

# 這段程式實際上是出於記憶體的絕對地址0開始處。首先是載入各個資料段暫存器。

# 重新設定全域性描述符表gdt --> 檢測a20地址線是否真的開啟，沒有開啟，loop

# 掉了 --> 檢測pc是否含有數學協處理器 --> 設定管理記憶體分頁的處理機制 -->

# 將頁目錄放置在記憶體地址0開始處。所以這段程式將被覆蓋掉。 --> 最後利用ret

# 指令彈出預先壓入的/init/main.c程式的入口地址，去執行main.c程式。

#

/*

 *  linux/boot/head.s

 *

 *  (C) 1991  Linus Torvalds

 */

/*

 *  head.s contains the 32-bit startup code.

 *

 * NOTE!!! Startup happens at absolute address 0x00000000, which is also where

 * the page directory will exist. The startup code will be overwritten by

 * the page directory.

 */

.text

.globl _idt,_gdt,_pg_dir,_tmp_floppy_area

_pg_dir: #頁目錄將會存放在這裡

startup_32:

#############################################

# 設定段暫存器

# 再次注意，現在程式已經執行在32模式，因此這裡

# 的0x10並不是把地址0x10裝入各個段暫存器，它現在

# 是全域性段描述符表的偏移量。這裡的0x10正好指向

# 在setup.s中設定的資料段的描述符。

#

# 下面程式碼的含義是，置ds，es，fs，gs中的選擇符

# 為setup.s中構造的資料段，並將堆疊放置在資料段

# _stack_start陣列內，然後使用新的中斷描述符表

# 和全域性描述符表，新的全域性段描述符表中初始化內

# 容和setup.s中完全相同。

#

#

movl $0x10,%eax

mov %ax,%ds

mov %ax,%es

mov %ax,%fs

mov %ax,%gs

#############################################

# 載入堆疊指標寄指令

# long user_stack [ PAGE_SIZE>>2 ] ;

#

# struct {

# long * a;

# short b;

# } stack_start = { & user_stack [PAGE_SIZE>>2] , 0x10 };

#

lss _stack_start,%esp # 設定系統堆疊段

# _stack_start -> ss:esp

call setup_idt

call setup_gdt

############################################

# 因為修改了gdt，需要重新載入所有的段暫存器。

movl $0x10,%eax # reload all the segment registers

mov %ax,%ds # after changing gdt. CS was already

mov %ax,%es # reloaded in 'setup_gdt'

mov %ax,%fs

mov %ax,%gs

lss _stack_start,%esp

#############################################

# 下面檢測是否開啟a20地址線採用的方法是向0x000000

# 處寫入一個數值，然後看記憶體地址0x100000處是否也是

# 這個數值。如果一直相同的話，loop死掉。

#

xorl %eax,%eax

1: incl %eax # check that A20 really IS enabled

movl %eax,0x000000 # loop forever if it isn't

cmpl %eax,0x100000

je 1b

/*

 * NOTE! 486 should set bit 16, to check for write-protect in supervisor

 * mode. Then it would be unnecessary with the "verify_area()"-calls.

 * 486 users probably want to set the NE (#5) bit also, so as to use

 * int 16 for math errors.

 */

 #####################################################

 # 檢查數學協處理器是否存在。採用的方法是先假設協處理器存在，

 # 執行一個協處理器指令，出錯，表明不存在協處理器。

movl %cr0,%eax # check math chip

andl $0x80000011,%eax # Save PG,PE,ET

/* "orl $0x10020,%eax" here for 486 might be good */

orl $2,%eax # set MP

movl %eax,%cr0

call check_x87

jmp after_page_tables

/*

 * We depend on ET to be correct. This checks for 287/387.

 */

check_x87:

fninit

fstsw %ax

cmpb $0,%al

je 1f /* no coprocessor: have to set bits */

movl %cr0,%eax

xorl $6,%eax /* reset MP, set EM */

movl %eax,%cr0

ret

.align 2

1: .byte 0xDB,0xE4 /* fsetpm for 287, ignored by 387 */

ret

####################################################

/*

 *  setup_idt

 *

 *  sets up a idt with 256 entries pointing to

 *  ignore_int, interrupt gates. It then loads

 *  idt. Everything that wants to install itself

 *  in the idt-table may do so themselves. Interrupts

 *  are enabled elsewhere, when we can be relatively

 *  sure everything is ok. This routine will be over-

 *  written by the page tables.

 */

/*

 * 將中斷描述符表idt設定成具有256項，並且都指向邋ignore_int

 * 中斷門。然後載入中斷描述符暫存器lidt。真正使用的中斷門

 * 以後再安裝。當我們認為其他地方認為一切正常時，在開啟中斷。

 *

蓋子程式會被頁表覆蓋掉。

 *

 * 中斷描述表中的項8個位元組。它的0-1，6-7位元組是偏移量，2-3位元組

 * 是選擇符，4-5是一些標誌。

 *

 */

setup_idt:

lea ignore_int,%edx # ignore_int的有效地址移動到edx

movl $0x00080000,%eax

movw %dx,%ax /* selector = 0x0008 = cs */

movw $0x8E00,%dx /* interrupt gate - dpl=0, present */

lea _idt,%edi # 將_idt的值載入到edi。

mov $256,%ecx # 下面跳轉使用跳轉使用。dec %ecx

rp_sidt:

movl %eax,(%edi) # 在上面將movl $0x00080000,%eax

# 設定為$0x00080000

movl %edx,4(%edi) # 在上面已經設定了edx的值

addl $8,%edi

dec %ecx

jne rp_sidt

lidt idt_descr # 載入idt，其中idt_descr在下面

# 定義。

ret

/*

 *  setup_gdt

 *

 *  This routines sets up a new gdt and loads it.

 *  Only two entries are currently built, the same

 *  ones that were built in init.s. The routine

 *  is VERY complicated at two whole lines, so this

 *  rather long comment is certainly needed :-).

 *  This routine will beoverwritten by the page tables.

 */

 #

 # 這個子程式設定全域性描述表gdt，並載入。

 #

setup_gdt:

lgdt gdt_descr # 載入全域性描述符表暫存器。

ret

/*

 * I put the kernel page tables right after the page directory,

 * using 4 of them to span 16 Mb of physical memory. People with

 * more than 16MB will have to expand this.

 */

 #

 # Linus將核心的記憶體頁表直接放置在頁目錄之後，使用4個表來定址

 # 16mb的實體記憶體。

 #

 # 每個表項的格式是，0-11 一些標誌位，12-31 表示一頁記憶體的物理起始地址。

.org 0x1000 # 從0x1000處開始是第1頁表。

pg0:

.org 0x2000

pg1:

.org 0x3000

pg2:

.org 0x4000

pg3:

.org 0x5000 # 下面定義的記憶體資料塊從偏移量0x5000處開始。

/*

 * tmp_floppy_area is used by the floppy-driver when DMA cannot

 * reach to a buffer-block. It needs to be aligned, so that it isn't

 * on a 64kB border.

 */

_tmp_floppy_area: # 用作dma緩衝區，_tmp_floppy_area記憶體供

# 軟碟機驅動程式使用。

.fill 1024,1,0 # 供保留1024項，每項一個位元組，填充0.

#

# 下面這幾個入棧操作pushl永固為呼叫/init/main.c程式和返回做準備。

# 前面三個入棧操作不知道作什麼用的。也許是linus用於在除錯時能夠

# 看清機器碼用的。

# pushl $L6入棧操作是模擬呼叫main.c程式時，首先將返回地址入棧操作。

# 所以如果main.c程式真正退出時，就會返回這裡標號l6處繼續執行下去。

# 即形成死迴圈。

# pushl $_main將main程式的地址壓入堆疊，這樣在設定分頁處理結束之後，

# 執行ret指令返回指令時就會將main.c程式的地址彈出堆疊，並去執行main.c

# 程式去了。

#

after_page_tables:

# 這些是呼叫main程式的引數。

pushl $0 # These are the parameters to main :-)

pushl $0

pushl $0

pushl $L6 # return address for main, if it decides to.

pushl $_main # _main是編譯程式對main的內部表示方法。

jmp setup_paging

L6:

jmp L6 # main should never return here, but

# just in case, we know what happens.

/* This is the default interrupt "handler" :-) */

# 下面是預設的中斷向量控制代碼。

int_msg:

.asciz "Unknown interrupt\n\r"

.align 2

ignore_int:

pushl %eax

pushl %ecx

pushl %edx

push %ds

push %es

push %fs

movl $0x10,%eax # 設定段選擇符

mov %ax,%ds

mov %ax,%es

mov %ax,%fs

pushl $int_msg # 把呼叫printk函式的引數的指標入棧。

call _printk # 呼叫printk函式。該函式在/kernel/printk.c

# _printk是printk編譯後模組內部的表示方法。

popl %eax

pop %fs

pop %es

pop %ds

popl %edx

popl %ecx

popl %eax

iret # 中斷返回，吧中斷呼叫是壓入棧的cpu

# 標誌暫存器的值夜彈出。

/*

 * Setup_paging

 *

 * This routine sets up paging by setting the page bit

 * in cr0. The page tables are set up, identity-mapping

 * the first 16MB. The pager assumes that no illegal

 * addresses are produced (ie >4Mb on a 4Mb machine).

 *

 * NOTE! Although all physical memory should be identity

 * mapped by this routine, only the kernel page functions

 * use the >1Mb addresses directly. All "normal" functions

 * use just the lower 1Mb, or the local data space, which

 * will be mapped to some other place - mm keeps track of

 * that.

 *

 * For those with more memory than 16 Mb - tough luck. I've

 * not got it, why should you :-) The source is here. Change

 * it. (Seriously - it shouldn't be too difficult. Mostly

 * change some constants etc. I left it at 16Mb, as my machine

 * even cannot be extended past that (ok, but it was cheap :-)

 * I've tried to show which constants to change by having

 * some kind of marker at them (search for "16Mb"), but I

 * won't guarantee that's all :-( )

 */

 # 這個子程式通過設定控制暫存器cr0的標誌來開啟cpu對記憶體的分頁處理

 # ，並設定各個頁表內容。

 #

 #

.align 2 # 按4位元組方式對其記憶體地址邊界。

setup_paging: # 首先對5頁清0

movl $1024*5,%ecx /* 5 pages - pg_dir+4 page tables */

xorl %eax,%eax

xorl %edi,%edi /* pg_dir is at 0x000 */

cld

rep

#stosl等指令表示將一段記憶體（源）中的資料複製到另一段記憶體（目標）中去。

stosl

##############################################################

# 下面四句設定頁目錄項，我們共有4個頁表，所以只需要設定4項。

# 頁目錄的結構與頁表中的項的結構是相同的，4個位元組為1項。

# $pg0 + 7表示0x00001007，是頁目錄表的第一項。

# 則第一頁表所在的地址0x00001007 & 0xfffff000 = 0x1000

# 第一頁的屬性標誌是 0x00001007 & 0x00000fff = 0x07，表示

# 該頁存在，使用者可以讀寫。

movl $pg0+7,_pg_dir /* set present bit/user r/w */

movl $pg1+7,_pg_dir+4 /*  --------- " " --------- */

movl $pg2+7,_pg_dir+8 /*  --------- " " --------- */

movl $pg3+7,_pg_dir+12 /*  --------- " " --------- */

##############################################################

#############################################################

# 下面的程式碼段填寫4個頁表中所有的項內容。

#

# 每項的內容是，當前項所對映的實體記憶體地址 + 該頁的標誌。

movl $pg3+4092,%edi # edi -> 最後一頁的最後一項

movl $0xfff007,%eax /*  16Mb - 4096 + 7 (r/w user,p) */

std # 方向置位，edi自減。

1: stosl /* fill pages backwards - more efficient :-) */

subl $0x1000,%eax # 每填好一項，地址自減。

jge 1b # 如果小於0，則表示全部填好。

##########################################################

# 設定也目錄基址暫存器cr3的值，指向頁目錄表。

xorl %eax,%eax /* pg_dir is at 0x0000 */

# 頁目錄在0x0000處

movl %eax,%cr3 /* cr3 - page directory start */

# 設定啟動分頁處理功能。

movl %cr0,%eax

orl $0x80000000,%eax

movl %eax,%cr0 /* set paging (PG) bit */

#########################################################

# 在改變分頁處理標誌之後，要求使用轉移指令來重新整理予取指令佇列，

# 這裡使用的是指令ret。該返回指令的另一個作用是將堆疊中的main

# 程式的返回地址彈出，並開始執行/init/main.c程式。

#

# 呵呵，啟動程式終於完了。

ret /* this also flushes prefetch-queue */

##########################################################

.align 2 # 按4位元組方式對齊記憶體邊界地址

.word 0

idt_descr:

.word 256*8-1 # idt contains 256 entries

.long _idt

.align 2

.word 0

gdt_descr:

.word 256*8-1 # so does gdt (not that that's any

.long _gdt # magic number, but it works for me :^)

.align 3

_idt: .fill 256,8,0 # idt is uninitialized

###############################################################

#

# 全域性描述符表，前四項分別為空項，程式碼段描述符，資料段描述符

# 系統段描述符。其中系統段描述符在linux中沒有起到作用。後面還預留

# 了252項用於建立任務的ldt和tss

#

_gdt: .quad 0x0000000000000000 /* NULL descriptor */

.quad 0x00c09a0000000fff /* 16Mb */

.quad 0x00c0920000000fff /* 16Mb */

.quad 0x0000000000000000 /* TEMPORARY - don't use */

.fill 252,8,0 /* space for LDT's and TSS's etc */

################################################################

# head.s程式執行結束之後，已經正式的完成了記憶體頁目錄和頁表的設定，

# 並重新設定了核心實際使用的中斷描述符表idt和全域性描述符表gdt。另外

# 還給軟盤的驅動程式開闢了1kb的位元組緩衝區。此時的system模組在記憶體中

# 的詳細映像如下 :

#

# 1-----------------------------1

# 1       .........                    1

# 1-----------------------------1

# 1      lib模組程式碼               1

# 1-----------------------------1

# 1      mm模組程式碼             1

# 1-----------------------------1

# 1      kernel模組程式碼         1

# 1-----------------------------1

# 1        main.c程式            1

# 1-----------------------------1

# 1           gdt                    1

# 1-----------------------------1

# 1           idt                     1

# 1-----------------------------1

# 1        head.s部分程式碼     1

# 1-----------------------------1

# 1        軟盤緩衝區 1k        1

# 1-----------------------------1

# 1        記憶體頁表 pg3         1

# 1-----------------------------1

# 1         pg2                      1

# 1-----------------------------1

# 1         pg1                     1

# 1-----------------------------1

# 1         pg0                     1

# 1-----------------------------1

# 1         記憶體頁目錄表        1

# 1-----------------------------1

參考《linux核心完全註釋》和網上相關文章