Unix系統通過向核心發出系統呼叫（system call）實現了使用者態程序和硬體裝置之間的大部分介面。系統呼叫是作業系統提供的服務，使用者程式通過各種系統呼叫，來引用核心提供的各種服務，系統呼叫的執行讓使用者程式陷入核心，該陷入動作由swi軟中斷完成。

應用程式設計介面（API）與系統呼叫的不同在於，前者只是一個函式定義，說明了如何獲得一個給定的服務，而後者是通過軟體中斷向核心發出的一個明確的請求。POSIX標準針對API，而不針對系統呼叫。Unix系統給程式設計師提供了很多API庫函式。libc的標準c庫所定義的一些API引用了封裝例程（wrapper routine）(其唯一目的就是釋出系統呼叫)。通常情況下，每個系統呼叫對應一個封裝例程，而封裝例程定義了應用程式使用的API。反之則不然，一個API沒必要對應一個特定的系統呼叫。從程式設計者的觀點看，API和系統呼叫之間的差別是沒有關係的：唯一相關的事情就是函式名、引數型別及返回程式碼的含義。然而，從核心設計者的觀點看，這種差別確實有關係，因為系統呼叫屬於核心，而使用者態的庫函式不屬於核心。

大部分封裝例程返回一個整數，其值的含義依賴於相應的系統呼叫。返回-1通常表示核心不能滿足程序的請求。系統呼叫處理程式的失敗可能是由無效引數引起的，也可能是因為缺乏可用資源，或硬體出了問題等等。在libd庫中定義的errno變數包含特定的出錯碼。每個出錯碼定義為一個常量巨集。

當用戶態的程序呼叫一個系統呼叫時，CPU切換到核心態並開始執行一個核心函式。因為核心實現了很多不同的系統呼叫，因此程序必須傳遞一個名為系統呼叫號（system call number）的引數來識別所需的系統呼叫。所有的系統呼叫都返回一個整數值。這些返回值與封裝例程返回值的約定是不同的。在核心中，整數或0表示系統呼叫成功結束，而負數表示一個出錯條件。在後一種情況下，這個值就是存放在errno變數中必須返回給應用程式的負出錯碼。

ARM Linux系統利用SWI指令來從使用者空間進入核心空間，還是先讓我們瞭解下這個SWI指令吧。SWI指令用於產生軟體中斷，從而實現從使用者模式變換到管理模式，CPSR儲存到管理模式的SPSR，執行轉移到SWI向量。在其他模式下也可使用SWI指令，處理器同樣地切換到管理模式。指令格式如下：

SWI{cond} immed_24

其中：

immed_24  24位立即數，值為從0――16777215之間的整數。

使用SWI指令時，通常使用一下兩種方法進行引數傳遞，SWI異常處理程式可以提供相關的服務，這兩種方法均是使用者軟體協定。SWI異常中斷處理程式要通過讀取引起軟體中斷的SWI指令，以取得24為立即數。

1）、指令中24位的立即數指定了使用者請求的服務型別，引數通過通用暫存器傳遞。如：

MOV R0,#34

SWI 12

2）、指令中的24位立即數被忽略，使用者請求的服務型別有暫存器R0的只決定，引數通過其他的通用暫存器傳遞。如：

MOV R0, #12

MOV R1, #34

SWI 0

在SWI異常處理程式中，去除SWI立即數的步驟為：首先確定一起軟中斷的SWI指令時ARM指令還是Thumb指令，這可通過對SPSR訪問得到；然後取得該SWI指令的地址，這可通過訪問LR暫存器得到；接著讀出指令，分解出立即數（低24位）。

下面的程式碼大家可以在entry-common.S中找到。

在2.6.21中，認真研究大家會發現，你迴避不了這樣一個概念，EABI是什麼東西？

核心裡面談EABI,OABI,其實相對於系統呼叫的方式，當然我們所說的系統限於arm系統。
EABI (Extended ABI),說的是這樣的一種新的系統呼叫方式

mov r7, #num
swi 0x0

原來的系統呼叫方式是這樣，
swi (#num | 0x900000) (0x900000是個magic值)

也就是說原來的呼叫方式(Old ABI)是通過跟隨在swi指令中的呼叫號來進行的，現在的是根據r7中的值。

現在看兩個巨集，一個是
CONFIG_OABI_COMPAT 意思是說和old ABI相容

另一個是
CONFIG_AEABI 意思是說指定現在的方式為EABI

這兩個巨集可以同時配置，也可以都不配，也可以配置任何一種。

我說一下核心是怎麼處理這一問題的。
我們知道，sys_call_table 在核心中是個跳轉表，這個表中儲存的是一系列的函式指標，這些指標就是系統呼叫函式的指標，如(sys_open).系統呼叫是根據一個呼叫號（通常就是表的索引）找到實際該呼叫核心哪個函式，然後執行該函式完成的。

首先，對於old ABI,核心給出的處理是給它建立一個單獨的system call table,叫sys_oabi_call_table，這樣，相容方式下就會有兩個system call table, 以old ABI方式的系統呼叫會執行old_syscall_table表中的系統呼叫函式，EABI方式的系統呼叫會用sys_call_table中的函式指標。

配置無外乎以下4中

第一 兩個巨集都配置 行為就是上面說的那樣

第二 只配置CONFIG_OABI_COMPAT ， 那麼以old ABI方式呼叫的會用sys_oabi_call_table，以EABI方式呼叫的 用sys_call_table，和1實質相同，只是情況1更加明確。

第三 只配置CONFIG_AEABI 系統中不存在 sys_oabi_call_table， 對old ABI方式呼叫不相容。只能 以EABI方式呼叫，用sys_call_table

第四 兩個都沒有配置 系統預設會只允許old ABI方式，但是不存在old_syscall_table，最終會通過sys_call_table 完成函式呼叫

可以參考下面的程式碼
對我們的專案比較有用。

.align 5 
ENTRY(vector_swi) 
sub sp, sp, #S_FRAME_SIZE 
stmia sp, {r0 - r12} @ Calling r0 - r12 
add r8, sp, #S_PC 
stmdb r8, {sp, lr}^ @ Calling sp, lr 
mrs r8, spsr @ called from non-FIQ mode, so ok. 
str lr, [sp, #S_PC] @ Save calling PC 
str r8, [sp, #S_PSR] @ Save CPSR 
str r0, [sp, #S_OLD_R0] @ Save OLD_R0 
zero_fp 

/* 
* Get the system call number. 
*/ 

#if defined(CONFIG_OABI_COMPAT) 

/* 
* If we have CONFIG_OABI_COMPAT then we need to look at the swi 
* value to determine if it is an EABI or an old ABI call. 
*/ 
#ifdef CONFIG_ARM_THUMB 
tst r8, #PSR_T_BIT 
movne r10, #0 @ no thumb OABI emulation 
ldreq r10, [lr, #-4] @ get SWI instruction 
#else 
ldr r10, [lr, #-4] @ get SWI instruction 
A710( and ip, r10, #0x0f000000 @ check for SWI ) 
A710( teq ip, #0x0f000000 ) 
A710( bne .Larm710bug ) 
#endif 

#elif defined(CONFIG_AEABI) 

/* 
* Pure EABI user space always put syscall number into scno (r7). 
*/ 
A710( ldr ip, [lr, #-4] @ get SWI instruction ) 
A710( and ip, ip, #0x0f000000 @ check for SWI ) 
A710( teq ip, #0x0f000000 ) 
A710( bne .Larm710bug ) 

#elif defined(CONFIG_ARM_THUMB) 

/* Legacy ABI only, possibly thumb mode. */ 
tst r8, #PSR_T_BIT @ this is SPSR from save_user_regs 
addne scno, r7, #__NR_SYSCALL_BASE @ put OS number in 
ldreq scno, [lr, #-4] 

#else 

/* Legacy ABI only. */ 
ldr scno, [lr, #-4] @ get SWI instruction 
A710( and ip, scno, #0x0f000000 @ check for SWI ) 
A710( teq ip, #0x0f000000 ) 
A710( bne .Larm710bug ) 

#endif 

#ifdef CONFIG_ALIGNMENT_TRAP 
ldr ip, __cr_alignment 
ldr ip, [ip] 
mcr p15, 0, ip, c1, c0 @ update control register 
#endif 
enable_irq 

get_thread_info tsk 
adr tbl, sys_call_table @ load syscall table pointer 
ldr ip, [tsk, #TI_FLAGS] @ check for syscall tracing 

#if defined(CONFIG_OABI_COMPAT) 
/* 
* If the swi argument is zero, this is an EABI call and we do nothing. 
* 
* If this is an old ABI call, get the syscall number into scno and 
* get the old ABI syscall table address. 
*/ 
bics r10, r10, #0xff000000 
eorne scno, r10, #__NR_OABI_SYSCALL_BASE 
ldrne tbl, =sys_oabi_call_table 
#elif !defined(CONFIG_AEABI) 
bic scno, scno, #0xff000000 @ mask off SWI op-code 
eor scno, scno, #__NR_SYSCALL_BASE @ check OS number 
#endif 

stmdb sp!, {r4, r5} @ push fifth and sixth args 
tst ip, #_TIF_SYSCALL_TRACE @ are we tracing syscalls? 
bne __sys_trace 

cmp scno, #NR_syscalls @ check upper syscall limit 
adr lr, ret_fast_syscall @ return address 
ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine 

add r1, sp, #S_OFF 
2: mov why, #0 @ no longer a real syscall 
cmp scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE) 
eor r0, scno, #__NR_SYSCALL_BASE @ put OS number back 
bcs arm_syscall 
b sys_ni_syscall @ not private func 

/* 
* This is the really slow path. We're going to be doing 
* context switches, and waiting for our parent to respond. 
*/ 
__sys_trace: 
mov r2, scno 
add r1, sp, #S_OFF 
mov r0, #0 @ trace entry [IP = 0] 
bl syscall_trace 

adr lr, __sys_trace_return @ return address 
mov scno, r0 @ syscall number (possibly new) 
add r1, sp, #S_R0 + S_OFF @ pointer to regs 
cmp scno, #NR_syscalls @ check upper syscall limit 
ldmccia r1, {r0 - r3} @ have to reload r0 - r3 
ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine 

系統呼叫是os作業系統提供的服務,使用者程式通過各種系統呼叫,來引用核心提供的各種服務,系統呼叫的執行讓使用者程式陷入核心,該陷入動作由swi軟中斷完成.

At91rm9200處理器對應的linux2.4.19核心系統呼叫對應的軟中斷定義如下:

#if defined(__thumb__)                             //thumb模式
#define __syscall(name)                          \
    "push    {r7}\n\t"                           \
    "mov    r7, #" __sys1(__NR_##name) "\n\t"    \
    "swi    0\n\t"                               \
    "pop    {r7}"
#else                                              //arm模式
#define __syscall(name) "swi\t" __sys1(__NR_##name) "\n\t"
#endif

#define __sys2(x) #x
#define __sys1(x) __sys2(x)
#define __NR_SYSCALL_BASE    0x900000               //此為OS_NUMBER << 20運算值
#define __NR_open            (__NR_SYSCALL_BASE+ 5) //0x900005 

舉一個例子來說:open系統呼叫,庫函式最終會呼叫__syscall(open),巨集展開之後為swi #__NR_open,即,swi #0x900005觸發中斷,中斷號0x900005存放在[lr,#-4]地址中,處理器跳轉到arch/arm/kernel/entry-common.S中vector_swi讀取[lr,#-4]地址中的中斷號,之後查詢arch/arm/kernel/entry-common.S中的sys_call_table系統呼叫表,該表內容在arch/arm/kernel/calls.S中定義,__NR_open在表中對應的順序號為

__syscall_start:

.long    SYMBOL_NAME(sys_open)                     //第5個
...
將sys_call_table[5]中內容傳給pc,系統進入sys_open函式,處理實質的open動作

注:用到的一些函式資料所在檔案,如下所示
arch/arm/kernel/calls.S聲明瞭系統呼叫函式
include/asm-arm/unistd.h定義了系統呼叫的呼叫號規則

vector_swi定義在arch/arm/kernel/entry-common.S
vector_IRQ定義在arch/arm/kernel/entry-armv.S
vector_FIQ定義在arch/arm/kernel/entry-armv.S

arch/arm/kernel/entry-common.S中對sys_call_table進行了定義:
    .type    sys_call_table, #object
ENTRY(sys_call_table)
#include "calls.S"                                 //將calls.S中的內容順序連結到這裡

源程式：

ENTRY(vector_swi)
    save_user_regs
    zero_fp
    get_scno                                        //將[lr,#-4]中的中斷號轉儲到scno(r7)
    arm710_bug_check scno, ip
#ifdef CONFIG_ALIGNMENT_TRAP
    ldr    ip, __cr_alignment
    ldr    ip, [ip]
    mcr    p15, 0, ip, c1, c0                       @ update control register
#endif
    enable_irq ip

    str    r4, [sp, #-S_OFF]!                       @ push fifth arg

    get_current_task tsk
    ldr    ip, [tsk, #TSK_PTRACE]                   @ check for syscall tracing
    bic    scno, scno, #0xff000000                  @ mask off SWI op-code
//#define OS_NUMBER    9[entry-header.S]
//所以對於上面示例中open系統呼叫號scno=0x900005
//eor scno,scno,#0x900000
//之後scno=0x05
    eor    scno, scno, #OS_NUMBER << 20             @ check OS number
//sys_call_table項為calls.S的內容
    adr    tbl, sys_call_table                      @ load syscall table pointer
    tst    ip, #PT_TRACESYS                         @ are we tracing syscalls?
    bne    __sys_trace

    adrsvc    al, lr, ret_fast_syscall              @ return address
    cmp    scno, #NR_syscalls                       @ check upper syscall limit
//執行sys_open函式
    ldrcc    pc, [tbl, scno, lsl #2]                @ call sys_* routine
    add    r1, sp, #S_OFF
2:  mov    why, #0                                  @ no longer a real syscall
    cmp    scno, #ARMSWI_OFFSET
    eor    r0, scno, #OS_NUMBER << 20               @ put OS number back
    bcs    SYMBOL_NAME(arm_syscall)    
    b    SYMBOL_NAME(sys_ni_syscall)                @ not private func
    /*
     * This is the really slow path. We're going to be doing
     * context switches, and waiting for our parent to respond.
     */
__sys_trace:
    add    r1, sp, #S_OFF
    mov    r0, #0                                   @ trace entry [IP = 0]
    bl    SYMBOL_NAME(syscall_trace)
/*
//2007-07-01 gliethttp [entry-header.S]
//Like adr, but force SVC mode (if required)
  .macro adrsvc, cond, reg, label
     adr\cond \reg, \label
  .endm
//對應反彙編:
//add lr, pc, #16 ; lr = __sys_trace_return
*/
    adrsvc    al, lr, __sys_trace_return            @ return address
    add    r1, sp, #S_R0 + S_OFF                    @ pointer to regs
    cmp    scno, #NR_syscalls                       @ check upper syscall limit
    ldmccia    r1, {r0 - r3}                        @ have to reload r0 - r3
    ldrcc    pc, [tbl, scno, lsl #2]                @ call sys_* routine
    b    2b

__sys_trace_return:
    str    r0, [sp, #S_R0 + S_OFF]!                 @ save returned r0
    mov    r1, sp
    mov    r0, #1                                   @ trace exit [IP = 1]
    bl    SYMBOL_NAME(syscall_trace)
    b    ret_disable_irq

    .align    5
#ifdef CONFIG_ALIGNMENT_TRAP
    .type    __cr_alignment, #object
__cr_alignment:
    .word    SYMBOL_NAME(cr_alignment)
#endif

    .type    sys_call_table, #object
ENTRY(sys_call_table)
#include "calls.S"