SAP ABAP: 把內表資料以excel或csv格式,通過前臺或者後臺的方式上傳至FTP伺服器
今天接到一個FTP的需求,就是每天晚上把當天某個報表的資料自動儲存excel上傳到FTP伺服器。
SAP已經有現成的FTP函式使用,可以通過函式的方式來實現,實現前先準備一些資料:
User:登入FTP的使用者名稱
Password:登入FTP的密碼
Host:FTP 的IP地址
Path: FTP的檔案存放路徑
RFC_Destination:意思是在前臺還是後臺的方式執行。前臺:SAPFTP 後臺:SAPFTPA
Command:操作FTP的命令,這裡使用 ' CD /Path ' 開啟資料夾
Filename:檔名
先在本地試下能不能連線FTP伺服器
下面簡單說明下FTP常用的函式
HTTP_SCRAMBLE:使用者名稱密碼加密
FTP_CONNECT:建立FTP伺服器連線
FTP_COMMAND:執行FTP命令
FTP_R3_TO_SERVER:在SAP端傳送資料到FTP 伺服器
FTP_DISCONNECT:關閉FTP連線
RFC_CONNECTION_CLOSE:關閉RFC連線
SAP提供的函式組是SFTP,系統提供的函式挺多,可以去研究下,我這裡只用到上面的函式。
接下來就是怎麼把內表的資料轉換成可以上傳的格式,這裡就是把內錶轉換成二進位制,有以下方法可以使用:
SAP_CONVERT_TO_CSV_FORMAT
SAP_CONVERT_TO_TEX_FORMAT
SAP_CONVERT_TO_XLS_FORMAT
SAP_CONVERT_TO_XML_FORMAT
SCMS_TEXT_TO_BINARY
我用到的方法只是前兩個和最後一個,第四個只能直接匯出檔案,可能還沒有找到合適的方法,以後再做彌補。
下面就是上程式碼了
DATA: l_user(30) TYPE c VALUE 'admin', "使用者名稱
l_pwd(30) TYPE c VALUE 'Aa123456', "密碼l_host(64) TYPE c VALUE '192.168.0.3', "FTP伺服器地址
l_path(64) TYPE c VALUE '/HYS', "路徑
l_rc(1),
l_dest TYPE rfcdes-rfcdest VALUE 'SAPFTPA'. "前端:sapftp 後臺執行:sapftpa.
DATA: l_handle TYPE i,
l_command(255) TYPE c,
l_result TYPE TABLE OF txmisporow,
l_filename(50) TYPE c,
l_pwdlength TYPE i,
l_length TYPE i,
l_ftppwd(255) TYPE c,
l_key TYPE i VALUE 26101957,
l_encoding TYPE abap_encoding VALUE '8400'.
DATA: lt_text TYPE truxs_t_text_data.
DATA: l_binary_tab LIKE TABLE OF solix.
DATA: BEGIN OF ls_tab,
tline(4096),
END OF ls_tab.
DATA: lt_tab LIKE TABLE OF ls_tab.
l_pwdlength = strlen( l_pwd ).
*****************開始FTP傳輸資料**********
CALL FUNCTION 'HTTP_SCRAMBLE' “密碼加密
EXPORTING
source = l_pwd
sourcelen = l_pwdlength
key = l_key
IMPORTING
destination = l_ftppwd.
"建立FTP連線
CALL FUNCTION 'FTP_CONNECT'
EXPORTING
user = l_user
password = l_ftppwd
host = l_host
rfc_destination = l_dest
IMPORTING
handle = l_handle
EXCEPTIONS
not_connected = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE 'FTP path error' TYPE 'E'.
ENDIF.
l_rc = COND #( WHEN l_path+(1) = '/' THEN ' ' ELSE ' /' ).
CONCATENATE 'cd' l_path INTO l_command SEPARATED BY l_rc. "拼接FTP命令,這裡是開啟資料夾地址
CALL FUNCTION 'FTP_COMMAND' ”執行FTP命令
EXPORTING
handle = l_handle
command = l_command
TABLES
data = l_result
EXCEPTIONS
tcpip_error = 1
command_error = 2
data_error = 3
OTHERS = 4.
IF sy-subrc <> 0.
PERFORM ftp_disconnect USING l_handle l_dest.
MESSAGE 'FTP path error' TYPE 'E'.
ENDIF.
CONCATENATE 'solist' sy-datum '.csv' INTO l_filename.
"內表資料轉換成CSV或者excel格式
CALL FUNCTION 'SAP_CONVERT_TO_CSV_FORMAT'
TABLES
i_tab_sap_data = <dyn_table>
CHANGING
i_tab_converted_data = lt_text
EXCEPTIONS
conversion_failed = 1
OTHERS = 2.
LOOP AT lt_text ASSIGNING FIELD-SYMBOL(<text>). “把資料存到一個單列的內表,等一下用作轉換二進位制用
APPEND VALUE #( tline = <text> ) TO lt_tab.
ENDLOOP.
CALL FUNCTION 'SCMS_TEXT_TO_BINARY' ”轉換成二進位制檔案
EXPORTING
encoding = l_encoding
IMPORTING
output_length = l_length
TABLES
text_tab = lt_tab
binary_tab = l_binary_tab
EXCEPTIONS
failed = 1
OTHERS = 2.
“剛剛已經用FTP命令開啟的資料夾,現在可以直接把二進位制檔案傳至伺服器了。
CALL FUNCTION 'FTP_R3_TO_SERVER'
EXPORTING
handle = l_handle
fname = l_filename
blob_length = l_length
character_mode = ' '
TABLES
blob = l_binary_tab
EXCEPTIONS
tcpip_error = 1
command_error = 2
data_error = 3
OTHERS = 4.
CASE sy-subrc.
WHEN 0.
MESSAGE 'Upload FTP Success' TYPE 'S'.
WHEN 1.
MESSAGE 'Upload FTP Failure (Tcpip_error)' TYPE 'S' DISPLAY LIKE 'E'.EXIT.
WHEN 2.
MESSAGE 'Upload FTP Failure (Command_error)' TYPE 'S' DISPLAY LIKE 'E'.EXIT.
WHEN 3.
MESSAGE 'Upload FTP Failure (Data_error)' TYPE 'S' DISPLAY LIKE 'E'.EXIT.
WHEN OTHERS.
MESSAGE 'Upload FTP Failure (Other)' TYPE 'S' DISPLAY LIKE 'E'.EXIT.
ENDCASE.
”關閉FTP 連線
CALL FUNCTION 'FTP_DISCONNECT'
EXPORTING
handle = p_handle.
CALL FUNCTION 'RFC_CONNECTION_CLOSE'
EXPORTING
destination = p_dest
EXCEPTIONS
destination_not_open = 1
OTHERS = 2.
現在就可以試下通過後臺跑程式了,先執行程式,然後設定後臺立即執行 ,儲存後程序將在後臺執行。
最後到SM37檢視程式執行情況,還有開啟FTP伺服器檢視檔案
SM37提示FTP執行正常,檔案也儲存到了,所以程式執行沒問題。
注意執行後臺任務時,檔名必須沒有中文,我剛開始就用了中文,後臺一直報錯,後來改了檔名才執行正常。
&n