多專案 函式庫、類庫 統一為一個版本的方法 – one.asp
摘要：
前幾天 寫的部落格 多專案 函式庫、類庫 統一為一個版本的方法 （http://www.miaoqiyuan.cn/p/one-php）中提到 使用 one.php 將整個專案打包成 一個 php 檔案，有網友 讓我 整個asp版本的，今天下午抽空寫了個 one.asp，使用方式基本一致，這...
前幾天 寫的部落格 ofollow,noindex" target="_blank">多專案 函式庫、類庫 統一為一個版本的方法 （http://www.miaoqiyuan.cn/p/one-php）中提到 使用 one.php 將整個專案打包成 一個 php 檔案，有網友 讓我 整個asp版本的，今天下午抽空寫了個 one.asp，使用方式基本一致，這次 增加了路徑計算的功能，可以引用不同路徑。
舉個簡單的應用場景，開發一個小的API系統，支援 XML、JSON輸出。區別是 基礎版（dev/dev.asp）只支援 Access，VIP版本（dev/vip.asp）支援 Access + SQL Server。這樣VIP版本就需要在現在的基礎上 增加 sqlserver的支援，增加額外的 配置項。開發過程只需要 按正常開發即可。
開發完畢後，通過 one.asp 打包成 index.asp 和 vip.asp 兩個版本，整套程式都是一個獨立的檔案。
完整的測試程式碼 可以 訪問： http://www.miaoqiyuan.cn/products/oneasp.rar 下載
核心程式碼 如下：
' ====================================================
'類名：One
'作者：mqycn
'部落格：http://www.miaoqiyuan.cn
'原始碼：http://www.miaoqiyuan.cn/p/one-php
'說明：多專案 函式庫、類庫 統一為一個版本的方法
' ====================================================
Class OneAsp
Private FSO
Private Root
Private Sub Class_Initialize()
Set FSO = Server.CreateObject("Scripting.FileSystemObject")
End Sub
Private Sub Class_Terminate()
Set FSO = Nothing
End Sub
Public Function Run(ByVal sourceFile, ByVal saveFile)
Run = "<hr><b>Input:</b>" & sourceFile & "<br><b>Result:</b>" & Save(saveFile, Include(sourceFile))
End Function
Public Function Include(ByVal path)
Dim tmpPath, tmpItem, arrPath, index
tmpPath = ""
arrPath = Split(path, "/")
For index = 0 To UBound(arrPath) - 1
tmpItem = arrPath(index)
tmpPath = tmpPath & tmpItem & "/"
Next
Include = Parse(tmpPath, arrPath(UBound(arrPath)))
End Function
Private Function Parse(ByVal root, ByVal fileName)
Call SetRoot(root)
Dim html
html = OpenRead(fileName)
Dim preg, pregResult
Set preg = New Regexp
preg.pattern = "<!--#include file=""([^""]*)""-->"
preg.global = True
preg.ignorecase = True
Dim htmlInclude
Set pregResult = preg.execute(html)
For Each htmlInclude In pregResult
html = Replace(html, htmlInclude, Include(root & htmlInclude.submatches(0)))
Next
Parse = "<%'" & root & fileName & " Start %" & ">" & vbCrLf & html & vbCrLf & "<%'" & root & fileName & " End %" & ">" & vbCrLf
End Function
Private Function SetRoot(ByVal rootPath)
If Right(rootPath, 1) <> "/" Then rootPath = rootPath & "/"
Root = rootPath
End Function
Private Function RealPath(ByVal path)
RealPath = Server.Mappath(Root & path)
End Function
Private Function OpenRead(ByVal path)
Dim txtFile
Set txtFile = FSO.OpenTextFile(RealPath(path))
OpenRead = txtFile.ReadAll()
txtFile.close
On Error GoTo 0
End Function
Public Function Save(ByVal path, ByVal body)
Dim txtFile
Set txtFile = FSO.CreateTextFile(Server.Mappath(path))
txtFile.write body
txtFile.close
Set txtFile = Nothing
Save = path
End Function
End Class
使用也非常簡單，使用 Call new OneAsp.run(開發版, 打包版)，可以 dev.asp 中的所有包含的程式碼 打包到 index.asp，如果只想獲取解析的內容，可以使用 Response.Write Server.Htmlencode(Call new OneAsp.include(開發版))