這次打算寫幾篇關於腳本方面的博客，主要是記錄一下 Gradle 腳本和批處理腳本的一些寫法，方便後續查閱。

前言

平常開發過程中，一些較為重復的手工性工作，如果能讓腳本來幫忙處理，自然是最好的，剛好之前有些工作有點過於重復且都是手工性去完成，所以就想著能否寫個腳本來處理。

因為我還是用的 windows 開發，所以最開始想到的就是批處理腳本，但寫完後發現，重復性工作是可以交給腳本去處理了，但每次要執行這個腳本文件還得打開腳本所在的文件夾找到腳本點擊去執行。

emmm，因為我是開發 Android 的，電腦開機時 Android Stuido 就沒關閉過，然後又想到 Gradle 的腳本可以直接通過 AS 來點擊執行，這樣一來，執行腳本，也就是敲代碼過程中隨手一個快捷鍵就搞定，簡單、方便。

所以，這篇就稍微來記錄下批處理腳本和 Gradle 腳本的一些寫法，很基礎簡單，因為我的需求就是執行 java 命令來對某個文件夾下的 apk 文件分別進行簽名，而後輸出新的命名方式的 apk 文件。

所以，腳本涉及到的操作也就只是文件夾的遍歷、字符串的處理、命令的執行這幾個方面而已，後續有新接觸再慢慢補充。

批處理腳本

1. 遍歷指定文件夾下的文件

1.1 命令解釋

命令： for [參數] %%變量名 in （匹配符） do （執行的命令）

切記：每個指令之間必須以空格隔開，in 與 ( 之間有空格，do 與 （ 間也有空格，否則命令會無法成功執行

ps：本節只講用批處理腳本執行 for 命令遍歷文件夾的場景，因此以下分析每個指令意義時，不介紹其他含義

[]：表示此項指令為可選

[參數]：參數取值一共有四種： /d, /r, /l, /f，加上無參數，所以一共五種場景

• 無參：遍歷當前路徑的文件夾下的文件，但也可在(匹配符)中指定路徑
• /d：遍歷當前路徑的文件夾下的文件夾，但也可在(匹配符)中指定路徑
  
• /r [路徑]：深度遍歷指定路徑下的所有文件，子目錄中的文件也會被遍歷到，如果沒指定路徑，默認當前路徑
• /l ：當使用參數 /l 時，需結合(匹配符)一起使用，此時 () 括號內部的用法規則為：(start, step, end)，此時的 for 命令作用等同於 java 語言中的 for 語句
  
• /f ：用於解析文件中的內容，本節不做介紹

%%變量名：作用類似於 for(int i = 0; ; )

（匹配符）：在 in 指令之後 () 括號裏的內容可表示為通配符，用於按照指定的規則過濾文件夾下的文件，如 (*.txt) 表示遍歷文件夾內所有以 .txt 結尾的文件

(執行的命令)：前面的指令就可以取到文件夾內指定的每個子項了，那麽接下去要對每個子項如何操作，就在這裏寫，類似於 java 的 for 命令後的 {} 大括號的作用

1.2 使用示例

以下示例基於上圖中的文件路徑，批處理腳本為 test.bat

• 無參：for %%i in (*) do ( echo %%i )

效果：遍歷當前目錄下的所有文件

• 無參指定路徑：for %%i in (c:\softwares\VisualBat\*.url) do ( echo %%i )

效果：遍歷在(匹配符)中指定路徑下的以 .url 結尾的文件

• 帶參數 /d：for /d %%i in (*) do ( echo %%i )

效果：遍歷當前目錄下所有的文件夾

• 帶參數 /d 指定路徑：for /d %%i in (c:\softwares\VisualBat\*) do ( echo %%i )

效果：遍歷指定目錄下的所有文件夾，%%i 指向每個子文件夾的絕對路徑

• 帶參數 /r ：for /r %%i in (*.url) do ( echo %%i )

效果：深度遍歷當前路徑下所有以 .url 結尾的文件，因為是深度遍歷，因此 %%i 指向文件的絕對路徑

• 帶參數 /r 指定路徑：for /r c:\softwares\VisualBat\ %%i in (*.url) do ( echo %%i )

效果：同上圖

• 帶參數 /l ：for /l %%i in (1, 1, 5) do ( echo %%i )

效果：等效於 java 中的 for (int i = 1; i <= 5; i++)語句，起始值，遞增或遞減，終止值都可自行設置

• 帶參數 /d /r：for /d /r %%i in (*) do ( echo %%i )

效果：參數可結合使用，/d 表示遍歷文件夾，/r 表示深度遍歷，因此以上命令作用為深度遍歷當前目錄下的所有文件夾，包括子目錄中的文件夾

2. 臨時變量的使用

2.1 變量的基本用法

命令：set key=value

切記：key=value 三者之間絕對不能出現空格，不能為了像遵守 java 風格擅自給添加上空格，這與 java 的 int a = 1 聲明變量不同，切記

變量使用：%key%

示例：

@echo off
set name=dasuAndroidTv
echo %name%

效果：name 可當做臨時變量使用，使用時需用 %% 將變量名括起來使用

局限：不允許在 for 命令中類似上步中聲明變量並直接使用，如下：

@echo off
for /l %%i in (0,1,5) do (
    set name=dasuAndroidTv
    echo %name%
)

效果：在 for 命令中聲明臨時變量，並直接通過 %key% 方式使用時會出現上圖中的錯誤：ECHO 處於關閉狀態，但如果 set key=value 臨時變量的聲明是放在 for 命令外部，for 命令內部只是使用的話，是可以的，如下：

@echo off
set name=dasuAndroidTv
for /l %%i in (0,1,5) do (
    echo %name%
)

效果：在 for 命令外部聲明臨時變量，for 命令內部只是使用，這種方式是允許的

2.2 變量在 for 命令中的用法

提問：那麽如果要在 for 命令中才聲明臨時變量，並使用的話，該如何做？

for 命令中臨時變量的使用：

1. 需啟用變量延遲功能，命令：setlocal enabledelayedexpansion
2. for 命令中的臨時變量使用時用 !key! 感漢號括起來的形式代替 %key%
3. 理由：不清楚，google 來的解決方案，感興趣想深入研究的自行搜索

示例：

@echo off
setlocal enabledelayedexpansion
set name=dasu
for /l %%i in (0, 1, 5) do (
    set name=dasuAndroidTv 
    echo !name!
    echo %name%
)

效果：說得白一點，在 for 命令中通過 %name% 方式使用的臨時變量，取的 name 這個臨時變量的值會一直是它在 for 命令外賦值的內容，即使在 for 命令中通過 set 命令對這個變量又重新賦值，也不會生效。

那麽，如果需要在 for 命令中通過 set 命令賦值後的臨時變量能夠馬上拿來使用，需要兩個步驟，一在文件開頭啟用變量延遲功能，命令：setlocal enabledelayedexpansion，二在 for 命令中通過 !name!方式來使用臨時變量。

3. 字符串處理

3.1 截取

命令：%key:~[start,num]%

解釋：當 %key% 中出現了 :~，則表示要對 key 指向的這個字符串做截取操作，截取操作支持以下幾種形式：

• 截取指定位置開始的 n 個字符串：%key:~0,4%，表示截取從下標 0 開始的之後 4 個字符
• 截取從指定位置開始的整個字符串：%key:~4%，表示截取從下標為 4 開始的整個字符串
• 截取通過倒數方式指定開始位置的整個字符串：%key:~-2%，表示截取從倒數第 2 個字符開始的整個字符串
• 截取通過倒數方式指定位置開始之後的 n 個字符串：%key:-4,2%，表示截取從倒數第 4 個字符開始的 2 個字符
• 正數倒數方式相結合：%key:~2,-2%，表示截取從下標 2 開始到倒數第 2 個之間的字符串

示例：

@echo off
rem (rem表示後面是註釋的內容，類似於 java //)原始字符串
set name=dasuAndroidTv

rem 註釋內容：表示截取從下標 0 開始的之後 4 個字符，輸出 dasu
echo %name:~0,4%

rem 註釋內容：表示截取從下標為 4 開始的整個字符串，輸出 AndroidTv
echo %name:~4%  

rem 註釋內容：表示截取從倒數第 2 個字符開始的整個字符串，輸出 Tv
echo %name:~-2%

rem 註釋內容：表示截取從倒數第 4 個字符開始的 2 個字符，輸出 Android
echo %name:~4,-2%

rem 註釋內容：表示截取從下標 2 開始到倒數第 2 個之間的字符串，輸出 id
echo %name:~-4,2%

3.2 拼接

命令：%key1%%key2%

解釋：將要拼接的那個字符串直接跟在被拼接的後面即可，不需要任何拼接操作符

示例：

@echo off
set name1=dasu
set name2=AndroidTv
echo %name1%%name2%  
rem 這裏是註釋內容：輸出 dasuAndroidTv

3.3 替換

命令：%key:被替換字符串=替換的字符串%

解釋：不解釋了，直接看示例，很容易明白

示例：

@echo off
set name=whoAndroidTv
echo %name:who=dasu%
rem 這裏是註釋內容：輸出 dasuAndroid

3.4 文件特殊操作

如果是在 for 命令中遍歷了某個文件夾下的文件，那麽此時可以通過一些特殊命令來獲取這個文件的各種信息，直接看示例：

@echo off
for %%i in (*.txt) do (
   echo %%i
   echo %%~fi
   echo %%~di
   echo %%~pi
   echo %%~ni
   echo %%~xi
   
   echo %%~ti
   echo %%~zi
)

解釋： 在通過 for 命令遍歷文件時，%%i 根據不同的 for 使用方式，內容也有所不同，具體見第 1 節。在上述這種用法下，%%i 指向了當前目錄下每個文件名，完整的文件名。

那麽，此時就可以通過一些特殊命令來取得文件的相關信息，比如：

• %%~fi：表示獲取該文件的絕對路徑信息
• %%~di：表示獲取該文件所在的盤符
• %%~pi：表示獲取該文件的路徑，不包含盤符的信息
• %%~ni：表示獲取該文件的文件名，不包含擴展名信息
• %%~xi：表示獲取該文件的擴展名
• %%~ti：表示獲取該文件的上次修改時間
• %%~zi：表示獲取該文件的大小

4. 完整示例

最後，我們來個具體場景，將本篇所學的知識用上一遍，鞏固一下。

場景：遍歷指定路徑目錄下的所有 apk 文件，並通過一個 sign.jar 文件，分別對每個 apk 文件執行 java 命令來進行簽名工作，sign.jar 接收兩個參數，一個是需要簽名的 apk，另外一個為輸出的 apk，要求簽名後的 apk 命名方式為將原文件名中的 unsign 替換成 google，並輸出在跟 apk 同一個目錄內即可。

apk 路徑：c:\users\suxq\desktop\outputs

sign.jar 路徑：c:\users\suxq\desktop

java 簽名命令示例(要求 sign.jar 和 apk 文件都在同一路徑下，即可用如下命令)：

java -jar sign.jar meizi_1_3_0_debug_unsign.apk meizi_1_3_0_debug_google.apk

批處理腳本代碼：

@echo off
setlocal enabledelayedexpansion

set sign=c:\users\suxq\desktop\sign.jar
set apkPath=c:\users\suxq\desktop\outputs
for %%i in (%apkPath%*.apk) do (
    set oldApk=%%~nxi
    set outApk=!oldApk:unsign=google!
    echo java -jar %sign% !oldApk! !outApk!
    rem 這裏是註釋內容：由於 apk 文件 和 sign.jar 文件都是虛擬的，因此真正執行時會報錯，這裏就只是將 java 整句命令輸出，從整句命令就可以確認是否會正確執行，如果這些文件都是真的話。真的腳本應該將 echo 去掉
)

效果：完美~

首先，遍歷指定目錄下的文件達到了，而且可以對文件名字符串進行處理，替換其中一些值，最後，可以根據指定位置的 sign.jar 文件，通過 java 命令來執行簽名工作。

這個場景，剛好把我們今天學的關於批處理的遍歷文件夾操作、臨時變量使用、字符串的處理三者都包括在內，感興趣的也去試試看吧~

最近（2018-03）剛開通了公眾號，想激勵自己堅持寫作下去，初期主要分享原創的Android或Android-Tv方面的小知識，準備可能還有點不足，感興趣的可以先點一波關註，謝謝支持~~

寫個批處理腳本來幫忙幹活--遍歷文件夾&字符串處理