1.基本介紹

Oracle和plsql都支援lob(large object) 型別，用來儲存大數量資料，如影象檔案，聲音檔案等。Oracle 9i realse2支援儲存最大為4g的資料，oracle 10g realse1支援最大8到128萬億位元組的資料儲存，依賴於你的db的block size。

在plsql中可以申明的lob型別的變數如下： 

• BFILE        二進位制檔案,儲存在資料庫外的作業系統檔案，只讀的。把此檔案當二進位制處理。 
• BLOB        二進位制大物件。儲存在資料庫裡的大物件，一般是影象聲音等檔案。 
• CLOB        字元型大物件。一般儲存大數量文字資訊。儲存單位元組，固定寬度的資料。 
• NCLOB        位元組字元大物件。儲存單位元組大塊，多位元組固定寬度，多位元組變寬度資料。

Oracle將lob分類為兩種：

1. 儲存在資料庫裡的，參與資料庫的事務。BLOB,CLOB,NCCLOB。
    
2. 儲存在資料庫外的BFILE，不參與資料庫的事務，也就是不能rollback或commit等，它依賴於檔案系統的資料完整性。

LONG和LONG
RAW這兩種資料型別也是儲存字元的，但是有系列的問題，不建議使用，這裡也就不討論了。 

2.LOB的使用 

本部分不討論lob的所有細節，只討論lob的基本原理和在plsql中的基本使用，為plsql開發使用lob提供一個基礎性指導。 

本部分使用的表是：

/** 
table script 
**/ 
CREATE TABLE waterfalls ( 
       falls_name VARCHAR2(80),--name 
       falls_photo BLOB,--照片 
       falls_directions CLOB,--文字 
       falls_description NCLOB,--文字 
       falls_web_page BFILE);--指向外部的html頁面 
/
 

這個表我們並不需要clob和nclob兩個，只取一就可以，這裡全部定義只是為了演示使用。

1. 理解LOB的Locator

表中的Lob型別的列中儲存的只是儲存指向資料庫中實際儲存lob資料的一個指標。 

在plsql中申明瞭一個lob型別的變數，然後從資料庫中查詢一個lob型別的值分配給變數，也只是將指標複製給了它，那麼這個變數也會指向資料庫中實際存放lob資料的地方。如：

--understanding lob locators 
  DECLARE 
       photo BLOB; 
    BEGIN 
       SELECT falls_photo 
         INTO photo 
         FROM waterfalls 
        WHERE falls_name='Dryer Hose'; 

Lob工作原理圖解 

       從上面的圖可以看出，要處理lob資料，必須先獲得lob locators。我們可以通過一個select語句獲取，當賦值給lob變數的時候，它也獲得同樣的lob locators。我們在plsql中處理可以使用dbms_lob包，裡面內建了很多過程和函式來讀取和修改我們的lob資料。下面給出處理lob資料的一般方法。 

1.        通過select語句獲取一個lob locator。 

2.        通過呼叫dbms_lob.open開啟lob。 

3.        呼叫dbms_lob.getchunksize獲得最佳讀寫lob值。 

4.        呼叫dbms_lob.getlength獲取lob資料的位元組值。 

5.        呼叫dbms_lob.read獲取lob資料。 

6.        呼叫dbms_lob.close關閉lob。 

2.Empty
lob and Null lob

Empty的意思是我們已經獲取了一個lob
locator，但是沒有指向任何lob資料。Null是定義了一個變數，但是沒有獲得lob locator。對lob型別的處理和其他型別不一樣。如下面的例子：

/* null lob example*/
DECLARE
  directions CLOB; --定義了，但是沒有分配值，為null 
BEGIN
  IF directions IS NULL THEN
    dbms_output.put_line('directions is null');
  ELSE
    dbms_output.put_line('directions is not null');
  END IF;
END;
/
DECLARE
  directions CLOB; --定義一個，並且分配值 
BEGIN
  --刪除一行 
  DELETE FROM waterfalls WHERE falls_name = 'Munising Falls';
  --插入一行通過使用 EMPTY_CLOB(  ) to 建立一個lob locator 
  INSERT INTO waterfalls
    (falls_name, falls_directions)
  VALUES
    ('Munising Falls', empty_clob());
  --獲得lob locator，上面插入的資料，因為我們插入的是一個empty_clob(),那麼lob locator不指向任何資料，雖然給變數分配了只 
  SELECT falls_directions
    INTO directions
    FROM waterfalls
   WHERE falls_name = 'Munising Falls';
  IF directions IS NULL THEN
    dbms_output.put_line('directions is NULL');
  ELSE
    dbms_output.put_line('directions is not NULL'); --列印此句 
  END IF;
  dbms_output.put_line('Length = ' || dbms_lob.getlength(directions)); --結果為o 
END;

注意： 

1. 上面例子中的empty_clob()是oracle的內建函式，建立了一個lob locator。但是我們沒有讓它指向任何資料，所以是empty。而且通過select語句給變數directions分配了lob locator，所以不是null,但是length為0，故為empty。 
2. 在基本型別中，我們判斷一個變數是不是有資料，只要is null就可以了。但是在lob型別中我們從以上的例子看出來是不正確的。Lob首先必須判斷is null看是否分配lob locator，如果分配了還需要進一步檢查length是否為0，看是否是empty，所以完整的是下面這樣：

IF some_clob IS NULL THEN
    --如果is null為true表示未分配，肯定沒有資料 
  ELSIF dbms_lob.getlength(some_clob) = 0 THEN
    --分配了length為0，也沒有資料 
  ELSE
    --有資料 
  END IF;

3.建立LOB

在上面我們使用empty_clob()建立了一個空的clob，lob
locator只是一個指標，真正的資料是儲存在磁碟中或資料庫檔案中。我 們先建立一個空的clob，然後我們可以update來讓變數真正指向有資料的lob。Empty_clob()可以用來處理clob和nclob。在oracle 8i中可以使用temporary lob達到同樣的效果。


4. 向LOB裡寫入資料

當獲得一個有效的lob
locator之後，就可以使用dbms_lob包的下列procedure向lob中寫入資料。 

       DBMS_LOB.WRITE:允許自動寫入資料到lob中。 

       DBMS_LOB.WRITEAPPEND:向lob的末尾寫入資料。

--write lob 
DECLARE
  directions      CLOB;
  amount          BINARY_INTEGER;
  offset          INTEGER;
  first_direction VARCHAR2(100);
  more_directions VARCHAR2(500);
BEGIN
  --Delete any existing rows for 'Munising Falls' so that this 
  --example can be executed multiple times 
  DELETE FROM waterfalls WHERE falls_name = 'Munising Falls';
  --Insert a new row using EMPTY_CLOB(  ) to create a LOB locator 
  INSERT INTO waterfalls
    (falls_name, falls_directions)
  VALUES
    ('Munising Falls', empty_clob());
  --Retrieve the LOB locator created by the previous INSERT statement 
  SELECT falls_directions
    INTO directions
    FROM waterfalls
   WHERE falls_name = 'Munising Falls';
  --Open the LOB; not strictly necessary, but best to open/close LOBs. 
  dbms_lob.open(directions, dbms_lob.lob_readwrite);
  --Use DBMS_LOB.WRITE to begin 
  first_direction := 'Follow I-75 across the Mackinac Bridge.';
  amount          := length(first_direction); --number of characters to write 
  offset          := 1; --begin writing to the first character of the CLOB 
  dbms_lob.write(directions, amount, offset, first_direction);
  --Add some more directions using DBMS_LOB.WRITEAPPEND 
  more_directions := ' Take US-2 west from St. Ignace to Blaney Park.' ||
                     ' Turn north on M-77 and drive to Seney.' ||
                     ' From Seney, take M-28 west to Munising.';
  dbms_lob.writeappend(directions,
                       length(more_directions),
                       more_directions);
  --Add yet more directions 
  more_directions := ' In front of the paper mill, turn right on H-58.' ||
                     ' Follow H-58 to Washington Street. Veer left onto' ||
                     ' Washington Street. You''ll find the Munising' ||
                     ' Falls visitor center across from the hospital at' ||
                     ' the point where Washington Street becomes' ||
                     ' Sand Point Road.';
  dbms_lob.writeappend(directions,
                       length(more_directions),
                       more_directions);
  --Close the LOB, and we are done. 
  dbms_lob.close(directions);
END;

在這個例子裡，我們使用了write 和writeappend這兩個過程來插入資料到lob中。因為開始的時候，我們插入了一個空的lob locator。要注意一點，我們最後使用了dbms_lob.close方法關閉lob。這是一個好的方法，特別是在處理oracle text的時候，任何oracle text domain和function-based indexes被update是在wirte和writeappend的時候呼叫的，而不是在close的時候被update的。        
我們向lob中寫入資料的時候，沒有必要更新表中的列。因為它儲存的只是一個locator，我們的變數也獲得同樣的locator，當我們寫入資料去lob的時候，locator並沒有改變。改變的只是locator指向的物理資料。

5. 從lob中讀取資料

步驟：a.通過select查詢獲得lob locator初始化lob變數。2.呼叫dbms_lob.read過程讀取lob資料。 
下面是dbms_lob.read過程的定義，注意引數.  

PROCEDURE READ(lob_loc IN BLOB, --初始化後的lob變數lob locator 
               amount  IN OUT NOCOPY INTEGER, --讀取的數量(clob為字元數,blob,bfile是位元組數) 
               offset  IN INTEGER, --開始讀取位置 
               buffer  OUT RAW); --讀到的資料,raw要顯示用轉換函式，見bfile 
PROCEDURE READ(lob_loc IN CLOB CHARACTER SET any_cs,
               amount  IN OUT NOCOPY INTEGER,
               offset  IN INTEGER,
               buffer  OUT VARCHAR2 CHARACTER SET lob_loc%charset);
PROCEDURE READ(file_loc IN BFILE,
               amount   IN OUT NOCOPY INTEGER,
               offset   IN INTEGER,
               buffer   OUT RAW);

--從lob中讀取資料 
DECLARE
  directions   CLOB;
  directions_1 VARCHAR2(300);
  directions_2 VARCHAR2(300);
  chars_read_1 BINARY_INTEGER;
  chars_read_2 BINARY_INTEGER;
  offset       INTEGER;
BEGIN
  --首先獲得一個lob locator 
  SELECT falls_directions
    INTO directions
    FROM waterfalls
   WHERE falls_name = 'Munising Falls';
  --記錄開始讀取位置 
  offset := 1;
  --嘗試讀取229個字元，chars_read_1將被實際讀取的字元數更新 
  chars_read_1 := 229;
  dbms_lob.read(directions, chars_read_1, offset, directions_1);
  --當讀取229個字元之後，更新offset，再讀取225個字元 
  IF chars_read_1 = 229 THEN
    offset       := offset + chars_read_1; --offset變為offset+chars_read_1，也就是從300開始 
    chars_read_2 := 255;
    dbms_lob.read(directions, chars_read_2, offset, directions_2);
  ELSE
    chars_read_2 := 0; --否則後面不在讀取 
    directions_2 := '';
  END IF;
  --顯示讀取的字元數 
  dbms_output.put_line('Characters read = ' ||
                       to_char(chars_read_1 + chars_read_2));
  --顯示結果 
  dbms_output.put_line(directions_1);
  dbms_output.put_line(length(directions_1));
  dbms_output.put_line(directions_2);
  dbms_output.put_line(length(directions_2));
END;

Dbms_lob.read的第2個引數是傳遞要讀取的數量。對於clob是字元數，blob和bfile都是位元組數。它是隨著讀取的數目自動更新的，offset不會更新。所以分佈讀取需要手動更新offset，下個offset是上一個offset+讀取的數量。我們可以通過dbms_lob.get_length(lob_locator)獲得這個lob的長度，結果clob是字元數，blob和bfile是位元組數，然後分佈讀取。