Oracle Procedure




一、塊
塊是pl/sql組成的基本單元，本篇講述儲存過程，鑑於2者有很高的相似性，且是其中一種塊，所以在此做一個簡單的塊講述


1、塊的結構
declare
  定義部分(可選)
begin
  可執行部分(必選)
exception
  異常處理部分(可選)
end;


2、塊的分類
(1)、無名塊(也叫匿名塊)：動態構造並只能執行一次，常用來測試或執行儲存過程。
(2)、命名塊：加了用<<>>括起了帶標號的無名塊。
(3)、子程式：包括儲存過程【本篇要講述的內容】、函式和包等。這些塊一旦被定義便會儲存在資料庫中，可隨時呼叫。
(4)、觸發器：根據觸發的事件呼叫。


3、舉例
(1)、無名塊
declare
  v_name varchar2(8):='CC';
  v_name2 constant varchar2(8):='CC';  --常量，constant關鍵字用於指定常量
  v_name3 varchar2(8) default 'CC';  --和:=等價
  v_name4 varchar2(8) not null :='CC';  --為not null的必須被賦值
  v_name4 varchar2(8);  --預設情況下，變數被初始化為null
  v_name5 boolean not null default false;
begin
  sp_flux_user_list();
end;


(2)、命名塊
說明：主要用於不同作用域同名變數間的引用
<<insertype1>>
declare
  v_name number:=1;
begin
  insert into t_type values(v_name);
  <<insertype2>>
  declare
    v_name number:=2;
  begin
    dbms_output.put_line(v_name);
  end;
  <<insertype3>>
  declare
    v_name number:=2;
  begin
    dbms_output.put_line(v_name);
  end;
  <<insertype4>>
  declare
    v_salary number:=2;
  begin
    dbms_output.put_line(v_salary);
  end;
end;


如上面的例子，現在引入2個概念
變數的作用域：指變數在程式中的有效範圍。對於一個plsql變數，它的作用域是從該變數被宣告開始到變數所在塊結束。
變數的可視域：指變數前不加以限定就能直接訪該變數的那一段程式。
上面例子中，insertype1塊的變數v_name在到所在塊結束前都是其作用域，並且在insertype4塊內可視，但在insertype2和insertype3內不可視，因為insertype2和insertype3內有同名變數。
當在塊中宣告一個變數時，如果在子塊中也聲明瞭同名的變數，則它們的作用域沒變。但在子塊中，只有子塊中宣告的變數時可視的，這時要引用父塊中的變數名時，必須加以限定。
這時要在insertype2內引用insertype1的變數就需要這樣寫“insertype1.v_name:=v_name”，但insertype2與insertype3的變數無法互相引用，因為作用域互不相同。


(3)、儲存過程
create or replace procedure sp_flux_user_list
is
  v_em emp.empno%TYPE; --表示以emp表中的empno欄位的型別定義變數
  v_de dept%rowtype; --表示v_de是一行資料
begin
  dbms_session.set_nls('nls_date_format','"yyyy-mm-dd hh24:mi:ss"');
  dbms_output.put_line(sysdate);
end sp_flux_user_list;


(4)、觸發器
create or replace trigger tri_tse
before insert or update or delete on emp
begin
  if to_char(sysdate,'DY','nls_date_language=american') in ('SAT','SUN') then
    raise_application_error(-20001,'不能在休息日改變僱員資訊');
  end if;
end;


4、注意
(1)、定義部分的識別符號必須以字母開頭；一個或多個字母、數字、或特殊符號組成；長度不超過30；不能有空格；非保留字
plsql不區分大小寫，如要區分大小寫或空格或保留字等，則使用""，例如"aAt code" number;
(2)、plsql將長度為0的字串當做null來處理。
(3)、在PLSQL裡，select、DML語句可以直接寫，而DDL、DCL語句不能直接寫。




二、儲存過程概述，儲存過程大體分為這麼幾個部分: 
  1.建立語句：create or replace procedure 儲存過程名 
    如果沒有or replace語句，則僅僅是新建一個儲存過程。如果系統存在該儲存過程，則會報錯。Create or replace procedure 如果系統中沒有此儲存過程就新建一個，如果系統中有此儲存過程則把原來刪除掉，重新建立一個儲存過程。 
  2.儲存過程名定義：包括儲存過程名和引數列表。引數名和引數型別。引數名不能重複， 引數傳遞方式:IN, OUT, IN OUT 
    IN 表示輸入引數，按值傳遞方式，並且它不允許在儲存過程中被重新賦值(in相當於JAVA的final)。如果儲存過程的引數沒有指定存引數傳遞型別，預設為IN。
    OUT 表示輸出引數，可以理解為按引用傳遞方式，可以作為儲存過程的輸出結果，供外部呼叫者使用。需要注意，當一個引數被指定為OUT型別時，就算在呼叫儲存過程之前對該引數進行了賦值，在儲存過程中該引數的值仍然是null。 
    IN OUT 即可作輸入引數，也可作輸出引數，屬於真正的按引用傳遞引數。
    引數的資料型別只需要指明型別名即可，不能指定寬度，引數的寬度由外部呼叫者決定。過程可以有引數，也可以沒有引數。
  3.變數宣告塊：緊跟著的as (is)關鍵字，可以理解為pl/sql的declare關鍵字，用於宣告變數。 
    變數宣告塊用於宣告該儲存過程需要用到的變數，它的作用域為該儲存過程。另外這裡宣告的變數必須指定寬度。遵循PL/SQL的變數宣告規範。且最大長度為30. 
    變數名[CONSTANT] 型別識別符號[NOT NULL][:=值|DEFAULT 值]；
  4.過程語句塊：從begin 關鍵字開始為過程的語句塊。儲存過程的具體邏輯在這裡來實現。 
  5.異常處理塊：關鍵字為exception ，為處理語句產生的異常。該部分為可選 
  6.結束塊：由end關鍵字結果。




三、儲存過程引數的傳遞方式
1.無參過程
create or replace procedure pro_time
is
  v_em emp.empno%TYPE; --欄位變數，表示以emp表中的empno欄位的型別定義變數
  v_de dept%rowtype; --記錄變數，表示v_de是一行資料
begin
  dbms_session.set_nls('nls_date_format','"yyyy-mm-dd hh24:mi:ss"');
  dbms_output.put_line(sysdate);
  dbms_output.put_line(v_de.id);--輸出記錄變數的某個欄位
end pro_time;


2.帶輸入輸出引數的過程
create or replace procedure pro_emp(
  i_eno emp.empno%type, --預設in
  i_sal in emp.sal%type,
  o_name out varchar2,
  num1 in out number) is
begin
  update emp set sal=i_sal where empno=i_eno return ename into o_name;
  num1:=i_sal*10;
  commit;
end pro_emp;


呼叫
declare
  v_eno number:=1111;
  v_salary:=2500;
  vn emp.ename%type;
  n1 number:=30;
begin
  pro_sal(v_eno,v_salary,vn,n1);
  dbms_output.put_line('姓名:' || vn || '升至10倍後的工資:' || n1);
end;


說明：
我們無法在儲存過程的定義中指定儲存引數的寬度，也就導致了我們無法在儲存過程中控制傳入變數的寬度。這個寬度是完全由外部傳入時決定的。
對於IN引數，其寬度是由儲存過程外部決定。 
對於OUT 和IN OUT 引數，其寬度是由儲存過程內部決定。 
比較明智的方法就是引數的資料型別使用%type，這樣雙方就達成了一致。但注意，使用%type為引數定義型別，該引數具有定義在形參上而不是通過實參傳遞的資料長度。




四、儲存過程引數的預設值
說明：
可以通過default 關鍵字為儲存過程的引數指定預設值。在對儲存過程呼叫時，就可以省略預設值。 
需要注意的是，預設值僅僅支援IN傳輸型別的引數，OUT 和 IN OUT不能指定預設值。。


例一：
create or replace procedure pro_test(i1 in number,
                                     i2 in date default sysdate) is
begin
  dbms_output.put_line(to_char(add_months(i2, i1),'yyyy-mm-dd'));
end pro_test;
呼叫
exec pro_test(1) --輸出 2012-09-17(今天是2012-08-17)
exec pro_test(1,to_date('2012-01-01','yyyy-mm-dd')) --輸出 2012-02-01


例二：當預設值不在最後一位怎麼呼叫
create or replace procedure pro_test(i2 in date default sysdate,
                                     i1 in number) is
begin
  dbms_output.put_line(to_char(add_months(i2, i1),'yyyy-mm-dd'));
end pro_test;
呼叫
exec pro_test(i1=>1) --輸出 2012-09-17(今天是2012-08-17)




五、儲存過程引數的傳參形式
由上面預設值不在第一位的情況可見，傳參的形式有2種
第一種是位置表示法，按照引數順序傳參，例如exec pro_test(1,to_date('2012-01-01','yyyy-mm-dd'))，這種形式不需要知道過程的形參名稱，但必須按照引數順序傳參。
第二種是名稱表示法，指定引數名稱傳參，例如exec pro_test(i1=>1)，這種形式不需要按照引數的順序傳參，但必須知道過程形參的名稱，且如果使用預設值的引數不是儲存過程最後一個引數，則只能用名稱表示法。
另外，位置表示法和名稱表示法在一些呼叫中也可以混合使用。但是，當在呼叫儲存過程中出現了第一個名稱表示法的引數時，後面的引數也必須使用名稱表示法傳值。


例一：
declare
  v_bir varchar2(10):='1999';
  v_sex varchar2(10):='1';
begin
  pro_tb_flux_user_list(v_code,v_name,p_bir=>v_bir,p_sex =>v_sex);
end;




六、儲存過程的結構
1.儲存過程的結構：
CREATE OR REPLACE PROCEDURE myproc AS --這裡寫as和is是等價
/*宣告變數部分*/
  v_name varchar2(10);  --變數
  c_male constant int :=1;  --常量
  type au_record is record(name varchar2(10),sex number);
  v_Author au_record;  --記錄型別
Begin
/*執行部分，必須且最重要的部分，至少包含一條可執行語句*/
Exception
/*異常處理*/
End myproc;




七、儲存過程的選擇語句


1、IF語句的三種形式：
IF-THEN-END IF
IF-THEN-ELSE-END IF
IF-THEN-ELSIF-ELSE-END IF


IF…ELSIF…ELSE語句
例子：
CREATE OR REPLACE PROCEDURE myproc AS
  cou NUMBER;
BEGIN 
  cou:= 1;
  IF cou>10 THEN DBMS_OUTPUT.put_line('cou = '||cou);
  ELSIF cou<5 THEN DBMS_OUTPUT.put_line('值小於5');
  ELSE DBMS_OUTPUT.put_line('條件不滿足');
  END IF;
END myproc;


2、case語句的三種形式


基本CASE 結構
CASE 選擇變數名
WHEN 表示式1 THEN 語句序列1
WHEN 表示式2 THEN 語句序列2
WHEN 表示式n THEN 語句序列n
ELSE 語句序列n+l
END CASE;


表示式CASE 結構
變數:=CASE 選擇變數名
WHEN 表示式1 THEN 值1
WHEN 表示式2 THEN 值2
WHEN 表示式n THEN 值n
ELSE 值n+l
END CASE；


搜尋CASE 結構
CASE 
WHEN 條件表示式1 THEN 語句序列1
WHEN 條件表示式2 THEN 語句序列2
WHEN 條件表示式n THEN 語句序列n
ELSE 語句序列n+1
END CASE;




八、儲存過程的迴圈語句


1、Loop迴圈(do...while)
說明：此迴圈是先執行一次之後再進行判斷
格式：
LOOP 
迴圈的語句;
EXIT WHEN 終止條件,true則終止;
迴圈條件必須更改;
END LOOP;
--如果沒有WHEN 條件，遇到EXIT 語句則無條件退出迴圈。


例子(迴圈輸出1~10)：
DECLARE
  cou NUMBER;
BEGIN -- 必須給一個初始值
  cou := 1;
  LOOP 
    DBMS_OUTPUT.put_line('cou = '||cou);
    cou := cou + 1;
    EXIT WHEN cou>10;
  END LOOP;
END;


2、While迴圈
說明：此迴圈是先判斷，之後如果條件滿足則執行
格式：
while(判斷迴圈的條件,true則執行) loop 
  迴圈的語句;
  迴圈條件的改變;
End loop;


例子：
DECLARE cou NUMBER;
BEGIN -- 必須給一個初始值
  cou := 1;
  WHILE(cou<10) LOOP 
    DBMS_OUTPUT.put_line('cou = '||cou);
    cou := cou + 1;
  END LOOP;
END;


3、For迴圈
說明：迴圈變數被隱式定義為integer型別的區域性變數，預設情況下，迴圈變數從初始值以1的增量遞增到結束值，如果使用關鍵字reverse，則迴圈從結束值以1的減量遞減到初始值。
格式：
FOR 控制變數 in [REVERSE] 下限..上限LOOP
語句1；
語句2；
……
END LOOP；


迴圈控制變數是隱含定義的，不需要要宣告。
下限和上限用於指明迴圈次數。正常情況下迴圈控制變數的取值由下限到上限遞增，
REVERSE 關鍵字表示迴圈控制變數的取值由上限到下限遞減。


例子：
declare
  v_l binary_integer:=1;
begin
  for v_loop in 1..10 loop
    dbms_output.put_line(v_loop);
--exit when (v_loop=8),加上這句則當v_loop=8時退出;exit則直接退出。
  end loop;
end;


declare
  v_l binary_integer:=1;
begin
  for v_loop in reverse 1..10 loop
    dbms_output.put_line(v_loop);
  end loop;
end;




九、儲存過程的終止迴圈跳轉語句（EXIT和EXIT WHEN）


1、關於EXIT和EXIT WHEN的區別：
EXIT：無條件終止語句，當遇到一個exit語句，則立即終止當前的迴圈。
EXIT WHEN：有條件終止語句，當遇到exit when語句時，首先檢測when子句中的條件，為true則終止。


2、主要作用
提前退出當前迴圈
提前退出巢狀迴圈


帶標號的loop迴圈語句，主要用於供內層的exit語句終止外層的迴圈
例如：


declare
  v_l binary_integer:=1;
begin
<<outer>>
  for i in 1..100 loop
    <<inter>>
    for v_loop in 1..10 loop
      dbms_output.put_line(v_loop);
      exit outer when outer.i*v_loop>=20;  --終止外層迴圈
      exit when v_loop=5;  --終止本層(內層)迴圈，等同於exit inter when v_loop=5
    end loop inter;
  end loop outer;
end;




十、儲存過程的無條件跳轉語句（GOTO語句）與NULL語句


1.GOTO語句概述
說明：GOTO為非結構化語句，跳轉到某個標號，標號必須唯一，且標號後必須是一個可執行的語句或PLSQL塊
限制：不能跳轉到IF語句、loop語句、或子塊中；不能從子程式中挑出；不能從異常處理跳轉到可執行部分。


2.NULL語句概述
NULL語句不會執行任何操作，相當於一個佔位符，並且會直接連線控制傳遞到下一條語句，使用NULL語句的好處是可以提高PL/SQL程式的可讀性，使語句變得有意思合法。


例一：
DECLARE 
  eno emp.empno%TYPE; 
  sal emp.sal%TYPE; 
BEGIN 
  eno := &en;
  SELECT sal INTO sal FROM emp WHERE empno=eno;
  IF sal>3500 THEN goto po1;
  ELSIF sal>2000 THEN goto po2;
  ELSE goto po3;END IF;
<<po1>> DBMS_OUTPUT.put_line('高工資。。。'); 
<<po2>> DBMS_OUTPUT.put_line('中等工資。。'); 
<<po3>> DBMS_OUTPUT.put_line('底工資。。。');  --標號<<po3>>後面必須要跟著可執行的語句或PLSQL塊
END ;


例二：如果跳轉的後面沒有什麼需要執行的語句了怎麼辦？用null語句。
DECLARE 
  eno emp.empno%TYPE;
  sal emp.sal%TYPE; 
BEGIN 
  eno := &en; 
  SELECT sal INTO sal FROM emp WHERE empno=eno ; 
  IF sal>3500 THEN goto po1 ; 
  ELSIF sal>2000 THEN goto po2 ; 
  ELSE goto po3 ; END IF ; 
<<po1>> DBMS_OUTPUT.put_line('高工資。。。') ; 
<<po2>> DBMS_OUTPUT.put_line('中等工資。。') ; 
<<po3>> null;  --沒有null則語法錯誤，null顯式指定一個什麼也不做的操作，相當於一個佔位符，使語句變得有意義合法。
END ;




十一、儲存過程細節
1、刪除儲存過程
drop procedure procedure_name;


2、有關存錯過程中使用到的集合資料型別(PL/SQL表、索引表、巢狀表、可變陣列)、遊標（普通遊標、引數遊標、遊標變數、迴圈選擇）、異常處理等在本部落格的其他文章做專題詳述。