注：對於ESP8266開源技術感興趣的可以加群，我們一起探索交流學習，群號：579932824。群名：ESP8266開源技術交流群。

介紹

MQTT是基於輕量級的基於釋出 - 訂閱的訊息傳遞協議。

• 它比其他基於請求響應的API（如HTTP）更快（更快）。
• 它是基於TCP / IP協議開發的。
• 它允許遠端定位裝置在訊息代理的幫助下連線，訂閱，釋出等到伺服器上的特定主題。
• MQTT Broker / Message Broker是發件人和收件人之間的一個模組。這是訊息驗證，轉換和路由的一個元素。
• 經紀人負責將訊息分發給感興趣的客戶（訂閱客戶）。

例如，如果溫度感測器釋出“溫度”主題的溫度資料（訊息），那麼訂購了“溫度”主題的感興趣的客戶就可以獲得如上所示的公佈的溫度資料。

MQTT廣泛應用於物聯網（IoT）嵌入式應用，每個感測器都連線到伺服器，並且可以通過網際網路進行控制。

NodeMCU是一個開源的物聯網平臺。這是一個執行在Espressif Systems的ESP8266 Wi-Fi SoC上的韌體。它具有可用的物聯網應用程式易於構建的無線網路。

NodeMCU的MQTT客戶端模組與MQTT協議版本3.1.1相同。確保您的代理支援3.1.1版，並且已正確配置。讓我們來看NodeMCU上用於MQTT的功能。

MQTT資料包形成

MQTT使用許多資料包格式來連線伺服器，並訂閱或釋出到伺服器上的主題。

請參閱下面的連結獲取MQTT OASIS標準。這將有助於理解MQTT資料包的形成。

例

編寫Arduino程式將NodeMCU配置為MQTT客戶端

1. 控制來自遠端位置的LED亮度
2. 通過POT（電位器）以數字形式傳送電壓到Adafruit儀表板的遠端位置。

這裡我們使用Adafruit伺服器來進行MQTT客戶端演示。

只需註冊並建立儀表板。成功建立儀表板後，我們將獲得AIO金鑰，稍後用於訪問饋送資料。

POT和LED連線到NodeMCU

安裝所需的庫

如果您未在Arduino IDE中安裝NodeMCU板卡包，請先參考先前的博文。

這裡我們使用Adafruit庫作為上面的例子。我們將需要使用Arduino庫管理器來安裝Adafruit IO，Adafruit MQTT

開啟Arduino IDE並導航到Sketch - > Include Library - > Manage Libraries ...

庫管理器視窗將彈出。現在在搜尋框中輸入Adafruit IO Arduino，然後點選Adafruit IO Arduino庫選項上的安裝來安裝版本2.6.0或更高版本。

現在，在搜尋框中輸入Adafruit MQTT，然後在Adafruit MQTT庫選項上單擊Install ，安裝版本0.17.0或更高版本。

現在，在搜尋框中輸入Arduino Http客戶端，在ArduinoHttpClient庫選項中點選Install ，安裝0.3.0或更高版本。

現在開啟Adafruit mqtt io儀表板的例子。要開啟它，請導航到檔案 - >示例 - > Adafruit MQTT庫 - > mqtt_esp8266

現在用正確的例子資訊編輯wifi和Adafruit io證書，如下圖所示。

我們修改了mqtt_esp8266的例子，如下面的例子

針對MQTT客戶端的Arduino Sketch

#include <ESP8266WiFi.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       "...your SSID..."
#define WLAN_PASS       "...your password..."

/************************* Adafruit.io Setup *********************************/

#define AIO_SERVER      "io.adafruit.com"
#define AIO_SERVERPORT  1883                   // use 8883 for SSL
#define AIO_USERNAME    "...your AIO username (see https://accounts.adafruit.com)..."
#define AIO_KEY         "...your AIO key..."

/************ Global State (you don't need to change this!) ******************/

// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;
// or... use WiFiFlientSecure for SSL
//WiFiClientSecure client;

// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
Adafruit_MQTT_Client mqtt(&client, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_KEY);

/****************************** Feeds ***************************************/

// Setup a feed called 'potValue' for publishing.
// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
Adafruit_MQTT_Publish potValue = Adafruit_MQTT_Publish(&mqtt, AIO_USERNAME "/feeds/potValue");

// Setup a feed called 'ledBrightness' for subscribing to changes.
Adafruit_MQTT_Subscribe ledBrightness = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/ledBrightness");

/*************************** Sketch Code ************************************/

// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
// for some reason (only affects ESP8266, likely an arduino-builder bug).
void MQTT_connect();

uint8_t ledPin = D6;
uint16_t potAdcValue = 0;
uint16_t ledBrightValue = 0;

void setup() {
  Serial.begin(9600);
  delay(10);

  Serial.println(F("Adafruit MQTT demo"));

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: "); Serial.println(WiFi.localIP());

  // Setup MQTT subscription for ledBrightness feed.
  mqtt.subscribe(&ledBrightness);
}

void loop() {
  // Ensure the connection to the MQTT server is alive (this will make the first
  // connection and automatically reconnect when disconnected).  See the MQTT_connect
  // function definition further below.
  MQTT_connect();

  // this is our 'wait for incoming subscription packets' busy subloop
  // try to spend your time here

  Adafruit_MQTT_Subscribe *subscription;
  while ((subscription = mqtt.readSubscription(200))) {
    if (subscription == &ledBrightness) {
      Serial.print(F("Got LED Brightness : "));
      ledBrightValue = atoi((char *)ledBrightness.lastread);
      Serial.println(ledBrightValue);
      analogWrite(ledPin, ledBrightValue);
    }
  }

  // Now we can publish stuff!
  uint16_t AdcValue = analogRead(A0);
  if((AdcValue > (potAdcValue + 7)) || (AdcValue < (potAdcValue - 7))){
    potAdcValue = AdcValue;
    Serial.print(F("Sending pot val "));
    Serial.print(potAdcValue);
    Serial.print("...");
    if (! potValue.publish(potAdcValue)) {
      Serial.println(F("Failed"));
    } else {
      Serial.println(F("OK!"));
    }
  }
  // ping the server to keep the mqtt connection alive
  // NOT required if you are publishing once every KEEPALIVE seconds
  /*
  if(! mqtt.ping()) {
    mqtt.disconnect();
  }
  */
}

// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
  int8_t ret;

  // Stop if already connected.
  if (mqtt.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  uint8_t retries = 3;
  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
       Serial.println(mqtt.connectErrorString(ret));
       Serial.println("Retrying MQTT connection in 5 seconds...");
       mqtt.disconnect();
       delay(5000);  // wait 5 seconds
       retries--;
       if (retries == 0) {
         // basically die and wait for WDT to reset me
         while (1);
       }
  }
  Serial.println("MQTT Connected!");
}

支援檔案

原始碼

• NodeMCU MQTT客戶端 下載  

    119