android studio build.gradle中配置實現自動簽名打包，重新命名apk，拷貝apk到指定目錄

序言

目前android開發基本上都是在android studio上進行的，而android studio是使用的gradle進行專案構建的，不同於之前使用eclipse時使用的ant指令碼構建，gradle的語法更加的靈活強大，gradle可以使用groovy進行編寫，但是本文的目的不是為了介紹groovy語法，這方面的資料網上有很多，推薦一篇http://www.infoq.com/cn/articles/android-in-depth-gradle/，這篇文章介紹的非常的詳細，有需要的同學可以先看下這篇文章。

學習gradle，需要從如下三個方面進行學習：

名詞解釋： DSL：domain special language（領域特定語言）

背景

使用android studio正常建立專案後，AS會自動給我們配置好專案根目錄和各個module的build.gradle檔案，正常我們只需要在各個gradle檔案中新增我們想要的依賴和混淆等資訊即可，
但這時打包時，就需要使用AS的圖形化操作build–>generate signed apk等來生成apk，並且生成的apk的名稱預設是”module名-debug/release.apk”，通常apk的名稱在每個公司中都是有相應的規範的，所以打包後的apk就需要手動去重新命名，想想這些操作是不是就覺得相當的繁瑣，作為一個超級懶的程式猿怎能容忍。因此才有瞭如下的解決方案。

本文內容

本文只是針對如下具體內容進行展開，其他更高階的gradle配置後續會再更新。也希望這篇文章能起到拋磚引玉的效果。

1. 配置自動簽名
2. 重新命名apk檔案
3. 拷貝apk檔案到指定目錄

配置自動簽名

1. 在專案的根目錄下建立一個名為 keystore.properties 的檔案。此檔案應當包含您的簽署資訊，如下：

   storePassword=123456
   
   keyPassword=123456
   
   keyAlias=zhang
   
   storeFile=../keystore/xxx.keystore
   

2. 在模組的build.gradle檔案中，android{} block的前面新增載入上面的配置檔案的程式碼， 如下：

   def keystorePropertiesFile = rootProject.file("keystore.properties")
   
   def keystoreProperties = new Properties()
   
   keystoreProperties.load(new FileInputStream(keystorePropertiesFile))
   
   android{
       ...
   }
   

3. 然後在模組的build.gradle的android{} block中的signingConfigs{} block中配置簽名信息， 如下：

   signingConfigs{
   
       release{
           keyAlias keystoreProperties['keyAlias']
           keyPassword keystoreProperties['keyPassword']
           storeFile file(new File(keystoreProperties['storeFile']))
           storePassword keystoreProperties['storePassword']
       }
       debug{
           keyAlias keystoreProperties['keyAlias']
           keyPassword keystoreProperties['keyPassword']
           storeFile file(new File(keystoreProperties['storeFile']))
           storePassword keystoreProperties['storePassword']
       }
       my_test{
           keyAlias keystoreProperties['keyAlias']
           keyPassword keystoreProperties['keyPassword']
           storeFile file(new File(keystoreProperties['storeFile']))
           storePassword keystoreProperties['storePassword']
       }
   }
   

4. 在模組的build.gradle的buildTypes{} block中配置使用上面的簽名設定， 如下：

   buildTypes {
       release {
           //設定使用簽名配置
           signingConfig signingConfigs.release
           ...
       }
       debug {
           //設定使用簽名配置
           signingConfig signingConfigs.debug
           ...
       }
   
       my_test{
           //設定使用簽名配置
           signingConfig signingConfigs.my_test
           ...
       }
   }
   

5. 最後就可以在命令列中進行打包了，開啟android studio中的Terminal，輸入如下：

   //release版本
   gradlew assembleRelease //windows系統中使用gradlew
   
   //debug版本
   gradlew assembleDebug
   
   //my_test版本
   gradlew assembleMy_test
   

經過上面幾步，就完成apk的自動簽名打包，生成的apk在模組的”/build/outputs/apk/”目錄下。

這裡我偷了一個懶，沒有使用上面這種通過程式碼載入外部檔案的方式，而是採用定義額外變數的方式設定簽名檔案的密碼等資訊，如下：

1. 首先在專案的根目錄建立一個config.gradle檔案，在這個檔案中配置專案中的相關配置資訊（android的編譯版本，minSdk、targetSdk版本或者依賴項版本）等配置資訊，方便管理，如下：

   //ext定義project的額外屬性，通過匯入這個gradle檔案，在專案的所有模組的build.gradle檔案中都可以使用這些屬性。
   ext{
       androidConfig = [ // 這就是一個數組
               majorVersion : 1, //陣列中的每個元素都是一個key：value對
               minorFeatures : 1,
               revisionNum : 0,
               compileSdkVersion : 25,
               buildToolsVersion : "25.0.3",
               minSdkVersion : 9,
               targetSdkVersion : 21,
               versionCode : 1,
       ]
   
       signConfig = [
               storePassword : "123456",
               keyPassword : "123456",
               keyAlias : "zhang",
               storeFile : "../keystore/xxx.keystore",
       ]
   }
   

這裡要使用這個配置檔案， 需要在專案根目錄的build.gradle檔案的中匯入這個檔案， 如下：

    apply from: rootProject.getRootDir().getAbsolutePath() + "/config.gradle"

    buildscript {
        repositories {
            jcenter()
        }
        dependencies {
            classpath 'com.android.tools.build:gradle:2.3.1'

            // NOTE: Do not place your application dependencies here; they belong
            // in the individual module build.gradle files
        }
    }

    ...

1. 在模組的build.gradle的android{} block中的signingConfigs{} block中配置簽名信息， 如下：

    signingConfigs{
       release{
           keyAlias signConfig.keyAlias
           keyPassword signConfig.keyPassword
           storeFile file(new File(signConfig.storeFile))
           storePassword signConfig.storePassword
       }
       debug{
           keyAlias signConfig.keyAlias
           keyPassword signConfig.keyPassword
           storeFile file(new File(signConfig.storeFile))
           storePassword signConfig.storePassword
       }
   }
   

後面的步驟就和上面的那種方式一樣了。

重新命名apk檔名

預設情況下， android studio打包後的apk的名字就是”module名-release/debug.apk”，通常我們都需要重新命名這個apk，例如公司的apk的名稱規範如下： AIOTAssistantUI-版本號-git分支-debug/release.apk

這裡我們先說如何重新命名apk，後面再說如何獲取git分支和當前提交id，如下：

在module的build.gradle的android{} block中進行如下配置：

    android{

     buildTypes {
            ...
        }

        applicationVariants.all{
            variant ->variant.outputs.each {output ->

                // 輸出檔案的名稱
                def outputFile = output.outputFile
                def newName

                //若輸出檔案為apk檔案
                if(outputFile != null && outputFile.name.endsWith('.apk')) {
                    if (variant.buildType.name == 'release') {
                        newName = "AIOTService-V${defaultConfig.versionName}-${getGitBranch()}.apk"
                    }else{
                        newName = "AIOTService-V${defaultConfig.versionName}-${getGitBranch()}-debug.apk"
                    }
                    output.outputFile = new File(outputFile.parent, newName)
                }
            }
        }
    }

這樣就能將生成的apk進行重新命名了。

• 在build.gradle中動態獲取git分支和版本號

我這裡是通過讀取專案根目錄的.git檔案中的資訊獲取到的，如下：

    def file = new File(".git/HEAD")//HEAD檔案中包含了當前所在分支資訊
    if (file.exists()) {
        def strings = file.getText("UTF-8").split(" ")

        println "gitConfig = ${strings}"
        if (strings.size() > 1) {
            def branch = strings[1] // 這裡獲取到分支名稱
            String refFilePath = ".git/${branch}" 
            //注意這裡獲取到的路徑的最後面有一個換行符，需要去掉，否則後面拼接到apk檔名中時會包檔案路徑不合法（坑！！！）
            def refFile = new File(refFilePath.replace("\n", "")) 
            if (refFile.exists()) {
                def commitId = refFile.getText('UTF-8')
                println "git commit id = $commitId"
                //取提交id前六位
                commitId.substring(0,6)
            }
        }
    }

這裡由於每個module中都需要獲取到這些資訊，所以就將這些公共的方法抽取到一個專門的工具檔案中，為utils.gradle，放置在專案的根目錄下，如下是我的utils.gradle中的內容：

    // 獲取最新提交id
    def getGitCommitId() {
        def file = new File(".git/HEAD")
        if (file.exists()) {
            def strings = file.getText("UTF-8").split(" ")

            println "gitConfig = ${strings}"
            if (strings.size() > 1) {
                def branch = strings[1]
                String refFilePath = ".git/${branch}"
                def refFile = new File(refFilePath.replace("\n", ""))
                if (refFile.exists()) {
                    def commitId = refFile.getText('UTF-8')
                    println "git commit id = $commitId"
                    //取提交id前六位
                    return commitId.substring(0,6)
                }
            }
        }
    }

    //git的分支
    def getGitBranch() {
        def file = new File(".git/HEAD")
        if (file.exists()) {
            def strings = file.getText("UTF-8").split(" ")

            println "gitConfig = ${strings}"
            if (strings.size() > 1) {
                def branch = strings[1].replace("\n","")
                println "branch = $branch"
                return branch.substring(branch.lastIndexOf("/") + 1)
            }
        }
    }

    //為了能使其他的gradle檔案中能夠呼叫這些方法，定義額外屬性
    //使用時直接呼叫這個額外屬性就可以了
    ext{
        getGitCommitId = this.&getGitCommitId //呼叫方法需要使用&符號
        getGitBranch = this.&getGitBranch
    }

接下來不要忘記在專案的build.gradle檔案中apply這個檔案， 如下：

    apply from: rootProject.getRootDir().getAbsolutePath() + "/utils.gradle"

此時，所有的配置基本上都已經完成了。

注意：
這個地方可能會有個坑：當我們有了新的程式碼提交時，此時點選執行程式時，會發現有時候apk安裝失敗，這裡的一個很可能的原因是你生成的apk的名字中的git版本號和AS要安裝的apk的名字中的git版本號不一致造成的，這是由於AS中gradle標記的git記錄沒有及時更新的原因，此時只需要點選如下按鈕重新整理一下就可以了。

拷貝apk檔案到指定目錄

但此時會發現每次通過命令列（如生成release版本）gradlew assembleRelease命令生成apk後，拷貝這些apk時就很麻煩，要到每個module的build/outputs/apk/目錄下去取，這時就想到需要在生成這些apk後將這些apk拷貝到指定的目錄。

看到這裡，你可能會想到，這很簡單啊，只需要在上面重新命名apk的地方的如下程式碼中配置新的檔案路徑就可以了，如下：

    android{

     buildTypes {
            ...
        }

        applicationVariants.all{
            variant ->variant.outputs.each {output ->

                // 輸出檔案的名稱
                def outputFile = output.outputFile
                def newName

                //若輸出檔案為apk檔案
                if(outputFile != null && outputFile.name.endsWith('.apk')) {
                    if (variant.buildType.name == 'release') {
                        newName = "AIOTService-V${defaultConfig.versionName}-${getGitBranch()}.apk"
                    }else{
                        newName = "AIOTService-V${defaultConfig.versionName}-${getGitBranch()}-debug.apk"
                    }

                    //這裡不使用outputFile.parent，而是配置自己指定的目錄
                    //如可以將其替換為"../outputs/apk/"
                    output.outputFile = new File(outputFile.parent, newName)
                }
            }
        }
    }

但是這樣做的話，當需要改變輸出路徑時，就需要到每個module下修改這些配置，並且可讀性也沒那麼好，因此我是採用瞭如下的方式，當apk生成後將這些apk都拷貝到指定的目錄下，如下：

在專案的根目錄下的build.gradle檔案中新增如下配置：

    //這個block 表示為每個子module進行相關配置。
    subprojects(){

        // 這裡獲取到assembleRelease和assembleDebug的task任務
        //注意這裡使用tasks.getByName("assembleRelease")會報錯，找不到這個task
        def releaseTasks = project.getTasksByName("assembleRelease",false)
        def debugTasks = project.getTasksByName("assembleDebug",false)
        copyApkFile(releaseTasks, project)
        copyApkFile(debugTasks, project)
    }

    def copyApkFile(Set<Task> tasks , Project project) {
        for (task in tasks) {
            def dir = project.getProjectDir().getAbsolutePath()
            println "assemble release dir = $dir"
            def file = new File(dir + "/build/outputs/apk")

            //在生成此apk之前，先將之前生成的apk刪除
            if (file.exists()) {
                def var = delete(dir + "/build/outputs/apk")
                def var1 = delete(rootProject.getRootDir().getAbsolutePath() + "/outputs/" + project.getName())
                println "clear before create $var , $var1------------------"
            }

            task.doLast {
                if (file.exists()) {
                    //將生成的apk拷貝出來
                    copy{ //copy是gradle中的project提供的方法，用於拷貝，裡面有兩個特定的屬性
                            //from srcDir ， into desDir （當這個目錄不存在的時候會嘗試建立這個資料夾）
                        println "copy file -------------------"
                        from dir + "/build/outputs/apk"
                        into rootProject.getRootDir().getAbsolutePath() + "/outputs/" + project.getName()
                    }
                }
            }
        }
    }