4.4.3 約束（Pattern的一部分）

前面我們已經介紹了條件約束在Pattern中位置了，那麼什麼是條件約束呢？簡單來說就是一個返回true或者false的表示式，比如下面的5小於6，就是一個約束條件。

Person( 5 < 6 )

從本質上來講，它是JAVA表示式的一種增強版本（比如屬性訪問），同時它又有一些小的區別，比如equals方法和==的語言區別。下面我們就深入瞭解一下。

訪問JavaBean中的屬性

任何一個JavaBean中的屬性都可以訪問，不過對應的屬性要提供getter方法或isProperty方法。比如：

Person( age == 50 )

// 與上面擁有同樣的效果
 

Person( getAge() == 50 )

Drools使用java標準的類檢查，因此遵循java標準即可。同時，巢狀屬性也是支援的，比如：

Person( address.houseNumber == 50 )

// 與上面寫法相同
Person( getAddress().getHouseNumber() == 50 )

在使用有狀態session的情況下使用巢狀屬性需要注意屬性的值可能被其他地方修改。要麼認為它們是不可變的，當任何一個父引用被插入到working memory中。或者，如果要修改巢狀屬性值，則應將所有外部fact標記更新。在上面的例子中，當houseNumber屬性值改變時，任何一個包含Address的Person需要被標記更新。

Java表示式

在pattern的約束條件中，可以任何返回結果為布林型別的java表示式。當然，java表示式也可以和增強的表示式進行結合使用，比如屬性訪問。可以通過使用括號來更改計算優先順序，如在任一邏輯或數學表示式中。

Person( age > 100 && ( age % 10 == 0 ) )

也可以直接使用java提供的工具方法來進行操作計算：

Person( Math.round( weight / ( height * height ) ) < 25.0 )

在使用的過程中需要注意，在LHS中執行的方法只能是隻讀的，不能在執行方法過程中改變改變FACT物件的值，否則會影響規則的正確執行。

Person( incrementAndGetAge() == 10 ) //不要像這樣在比較的過程中更新Fact物件

另外，FACT物件的相關狀態除了被在working memory中進行更新操作，不應該每次呼叫時狀態會發生變化。

Person( System.currentTimeMillis() % 1000 == 0 ) // 不要這樣實現

標準Java運算子優先順序也適用，請參見下面的運算子優先順序列表。所有的操作符都有標準的Java語義，除了==和！=。它們的null安全的，就相當於java中比較兩個字串時把常量字串放前面呼叫equals方法的效果一樣。

約束條件的比較過程中是會進行強制型別轉換的，比如在資料計算中傳入字串“10”，則能成功轉換成數字10進行計算。但如果，此時傳入的值無法進行轉換，比如傳了“ten”，那麼將會丟擲異常。

逗號分隔符

逗號可以對約束條件進行分組，它的作用相當於“AND”。

// Person的年齡要超過50，並且重量 超過80 kg
Person( age > 50, weight > 80 )

雖然“&&”和“,”擁有相同的功能，但是它們有不同的優先順序。“&&”優先於“||”，“&&”和“||”又優先於“,”。但建議優先使用“,”分隔符，因為它更利於閱讀理解和引擎的優化操作。同時，逗號分隔符不能和其他操作符混合使用，比如：

Person( ( age > 50, weight > 80 ) || height > 2 ) // 會編譯錯誤

// 使用此種方法替代
Person( ( age > 50 && weight > 80 ) || height > 2 )

繫結變數

一個屬性可以繫結到一個變數：

// 2 person的age屬性值相同
Person( $firstAge : age ) // 繫結
Person( age == $firstAge ) // 約束表示式

字首$只是個通用慣例，在複雜規則中可以通過它來區分變數和屬性。為了向後相容，允許（但不推薦）混合使用約束繫結和約束表示式。

// 不建議這樣寫
Person( $age : age * 2 < 100 )

// 推薦（分離繫結和約束表示式）
Person( age * 2 < 100, $age : age )

使用操作符“==”來繫結變數，Drools會使用雜湊索引來提高執行效能。

內部類分組訪問

通常情況，我們訪問一個內部類的多個屬性時會有如下的寫法：

Person( name == "mark", address.city == "london", address.country == "uk" )

Drools提供的分組訪問可以更加方便進行使用：

Person( name == "mark", address.( city == "london", country == "uk") )

注意字首’.’是用來區分巢狀物件約束和方法呼叫所必需的。

內部強制轉換

在使用內部類的時候，往往需要將其轉換為父類，在規則中可以通過“#”來進行強制轉換：

Person( name == "mark", address#LongAddress.country == "uk" )

上面的例子將Address強制轉換為LongAddress.，這樣使得getter方法變得可用。如果無法強制轉換，表示式計算的結果為false。強制轉換也支援全路徑的寫法：

Person( name == "mark", address#org.domain.LongAddress.country == "uk" )

多次內部轉換語法：

Person( name == "mark", address#LongAddress.country#DetailedCountry.population > 10000000 )

也可以使用instanceof操作符進行判斷，判斷之後將進一步使用該屬性進行比較。

Person( name == "mark", address instanceof LongAddress, address.country == "uk" )

日期字元

規則語法中除了支援JAVA標準字元，同時也支援日期字元。Drools預設支援的日期格式為“dd-mmm-yyyy”，可以通過設定系統變數“drools.dateformat”的值來改變預設的日期格式。

Cheese( bestBefore < "27-Oct-2009" )

List和Map的訪問

訪問List：

// 和childList(0).getAge() == 18效果相同
Person( childList[0].age == 18 )

根據key訪問map：

// 和credentialMap.get("jsmith").isValid()相同
Person( credentialMap["jsmith"].valid )

&&和||

約束表示式可以通過&&和||來進行判斷比較，此處用法與標準Java相似，當組合使用時，可通過括號來劃分優先順序。

Person( age > 30 && < 40 )
Person( age ( (> 30 && < 40) ||(> 20 && < 25) ) )
Person( age > 30 && < 40 || location == "london" )

DRL特殊操作符

“< ⇐ > >=”操作符用於屬性的比較是按照預設的排序，比如日期屬性使用小於號標示可以按照日期排序，當使用在String字串的比較時，則按照字母順序進行排序。此操作符僅適用於可比較的屬性。

Person( firstName < $otherFirstName )
Person( birthDate < $otherBirthDate )

“!.”提供了一個預設空校驗的操作。當使用此操作符時，會先校驗當前物件是否為null，如果不為null再呼叫其方法或獲得其屬性進行判斷。一旦當前操作物件為null，則相當於結果為false。

Person( $streetName : address!.street )

// 上面的寫法相當於
Person( address != null, $streetName : address.street )

matches操作符可使用Java的正則表示式進行字串的匹配，通常情況下是對字串進行匹配，但也支援變數值為正確的表示式的方式。此操作符僅適用於字串屬性。如果屬性值為null，匹配的結果始終為false。

Cheese( type matches "(Buffalo)?\\S*Mozzarella" )

not matches方法與matches相同，唯一不同的是返回的結果與之相反。

Cheese( type not matches "(Buffalo)?\\S*Mozzarella" )

contains操作符判斷一個集合屬性或元素是否包含指定字串或變數值。僅適用於集合屬性。也可以用於替代String.contains()來檢查約束條件。not contains用法與之相同，結果取反。

CheeseCounter( cheeses contains "stilton" ) // 包含字串
CheeseCounter( cheeses contains $var ) // 包含變數

Cheese( name contains "tilto" )
Person( fullName contains "Jr" )
String( this contains "foo" )

memberOf用來檢查屬性值是否為集合，此集合的表示必須為變數。not memberOf使用方法相同，結果取反。

CheeseCounter( cheese memberOf $matureCheeses )

soundslike的效果與matches相似，但它用來檢查一個字串的發音是否與指定的字元十分相似（使用英語發音）。

// 匹配 "fubar" 或 "foobar"
Cheese( name soundslike 'foobar' )

str操作用來比較一個字串是否以指定字串開頭或結尾，有可以用於比較字串的長度。

Message( routingValue str[startsWith] "R1" )

Message( routingValue str[endsWith] "R2" )

Message( routingValue str[length] 17 )

in和notin用來匹配一組資料中是否含一個或多個匹配的字串，使用的方法與資料庫中in的使用方法相似。待匹配的資料可以是字串、變數。

Person( $cheese : favouriteCheese )
Cheese( type in ( "stilton", "cheddar", $cheese ) )

運算子優先順序

後語

此係列課程持續更新中，QQ群：593177274（可掃描左上側欄目二維碼），歡迎大家加入討論。點選連結關注《Drools部落格專欄》。由於Drools資料較少，教程編寫不易，每篇部落格都親身實踐編寫demo。如果對你有幫助也歡迎讚賞（微信）！ 也是對原創的最大支援！