hive表的原始檔儲存格式有幾類：

1、TEXTFILE
預設格式，建表時不指定預設為這個格式，匯入資料時會直接把資料檔案拷貝到hdfs上不進行處理。原始檔可以直接通過hadoop fs -cat 檢視

2、SEQUENCEFILE
一種Hadoop API提供的二進位制檔案，使用方便、可分割、可壓縮等特點。
SEQUENCEFILE將資料以< key,value>的形式序列化到檔案中。序列化和反序列化使用Hadoop 的標準的Writable 介面實現。key為空，用value 存放實際的值， 這樣可以避免map 階段的排序過程。

三種壓縮選擇：NONE, RECORD, BLOCK。 Record壓縮率低，一般建議使用BLOCK壓縮。使用時設定引數，
SET hive.exec.compress.output=true;
SET io.seqfile.compression.type=BLOCK; – NONE/RECORD/BLOCK
create table test2(str STRING) STORED AS SEQUENCEFILE;

3、RCFILE
一種行列儲存相結合的儲存方式。首先，其將資料按行分塊，保證同一個record在一個塊上，避免讀一個記錄需要讀取多個block。其次，塊資料列式儲存，有利於資料壓縮和快速的列存取。
理論上具有高查詢效率（但hive官方說效果不明顯，只有儲存上能省10%的空間，所以不好用，可以不用）。
RCFile結合行儲存查詢的快速和列儲存節省空間的特點
1）同一行的資料位於同一節點，因此元組重構的開銷很低；
2) 塊內列儲存，可以進行列維度的資料壓縮，跳過不必要的列讀取。

查詢過程中，在IO上跳過不關心的列。實際過程是，在map階段從遠端拷貝仍然拷貝整個資料塊到本地目錄，也並不是真正直接跳過列，而是通過掃描每一個row group的頭部定義來實現的。
但是在整個HDFS Block 級別的頭部並沒有定義每個列從哪個row group起始到哪個row group結束。所以在讀取所有列的情況下，RCFile的效能反而沒有SequenceFile高。

4、ORC hive給出的新格式，屬於RCFILE的升級版。
ORC是RCfile的升級版，效能有大幅度提升，而且資料可以壓縮儲存，壓縮比和Lzo壓縮差不多，比text檔案壓縮比可以達到70%的空間。而且讀效能非常高，可以實現高效查詢。
具體介紹https://cwiki.apache.org/confluence/display/Hive/LanguageManual+ORC

注意：

只有TEXTFILE表能直接載入資料，必須，本地load資料，和external外部表直接載入運路徑資料，都只能用TEXTFILE表。

更深一步，hive預設支援的壓縮檔案（hadoop預設支援的壓縮格式），也只能用TEXTFILE表直接讀取。其他格式不行。可以通過TEXTFILE表載入後insert到其他表中。

換句話說，SequenceFile、RCFile表不能直接載入資料，資料要先匯入到textfile表，再從textfile表通過insert select from 匯入到SequenceFile,RCFile表。

SequenceFile、RCFile表的原始檔不能直接檢視，在hive中用select看。

RCFile原始檔可以用 hive –service rcfilecat /xxx/000000_0檢視，但是格式不同，很亂。
ORCFile原始檔可以用 hive –orcfiledump來進行分析ORC儲存檔案，就可以看到這些資訊：
hive –orcfiledump < path_to_file>

建表語句如下：
同時，將ORC的表中的NULL取值，由預設的\N改為”,

ORC三種建立/使用方式:
1, STORED AS ORC;
2, ROW FORMAT SERDE ‘org.apache.hadoop.hive.ql.io.orc.OrcSerde’ with serdeproperties(‘serialization.null.format’ = ”) STORED AS ORC;
3, ROW FORMAT DELIMITED NULL DEFINED AS ” STORED AS ORC;

方式一

create table if not exists test_orc(
  advertiser_id string,
  ad_plan_id string,
  cnt BIGINT
) partitioned by (day string, type TINYINT COMMENT '0 as bid, 1 as win, 2 as ck', hour TINYINT)
STORED AS ORC;

alter table test_orc set serdeproperties('serialization.null.format' = '');

方式二

drop table test_orc;
create table if not exists test_orc(
  advertiser_id string,
  ad_plan_id string,
  cnt BIGINT
) partitioned by (day string, type TINYINT COMMENT '0 as bid, 1 as win, 2 as ck', hour TINYINT)
ROW FORMAT SERDE 
  'org.apache.hadoop.hive.ql.io.orc.OrcSerde' 
with serdeproperties('serialization.null.format' = '')
STORED AS ORC;

方式三

drop table test_orc;
create table if not exists test_orc(
  advertiser_id string,
  ad_plan_id string,
  cnt BIGINT
) partitioned by (day string, type TINYINT COMMENT '0 as bid, 1 as win, 2 as ck', hour TINYINT)
ROW FORMAT DELIMITED 
  NULL DEFINED AS '' 
STORED AS ORC;

檢視結果

hive> show create table test_orc;
CREATE  TABLE `test_orc`(
  `advertiser_id` string, 
  `ad_plan_id` string, 
  `cnt` bigint)
PARTITIONED BY ( 
  `day` string, 
  `type` tinyint COMMENT '0 as bid, 1 as win, 2 as ck', 
  `hour` tinyint)
ROW FORMAT DELIMITED 
  NULL DEFINED AS '' 
STORED AS INPUTFORMAT 
  'org.apache.hadoop.hive.ql.io.orc.OrcInputFormat' 
OUTPUTFORMAT 
  'org.apache.hadoop.hive.ql.io.orc.OrcOutputFormat'
LOCATION
  'hdfs://namenode/hivedata/warehouse/pmp.db/test_orc'
TBLPROPERTIES (
  'transient_lastDdlTime'='1465992916')