1、在Word文件中插入表格，給單元格賦值，訪問單元格內容，拆分及合併單元格

'先引用Microsoft Word 11.0 Object Library
Option Explicit

Dim WordApp As Word.Application '建立Word應用程式

Private Sub Command1_Click()
    
    Set WordApp = New Word.Application '例項化
    WordApp.Visible = True '顯示 Office Word 介面
    '或者Application.Visible = True
    WordApp.DisplayAlerts = False '不提示儲存對話方塊
    WordApp.Documents.Add '建立新的空白Word文件
    WordApp.Selection.EndKey unit:=wdStory  '將游標移到文件末尾，在文字後面插入表格
    Selection.TypeText Text:="我的Word表格" '表格的標題名稱
    Call WordApp.ActiveDocument.Tables.Add(WordApp.Application.Selection.Range, 10, 5, 1, 0) '插入一個10行5列的表格
    Selection.Tables(1).Columns.Width = 80 '定義表格的列寬
    
    '給單元格賦值
    WordApp.ActiveDocument.Tables(1).Cell(1, 1).Range.InsertAfter "序號"
    WordApp.ActiveDocument.Tables(1).Cell(1, 2).Range.InsertAfter "專案1"
    WordApp.ActiveDocument.Tables(1).Cell(1, 3).Range.InsertAfter "專案2"
    WordApp.ActiveDocument.Tables(1).Cell(1, 4).Range.InsertAfter "專案3"
    WordApp.ActiveDocument.Tables(1).Cell(1, 5).Range.InsertAfter "專案4"
    
    '合併單元格
    WordApp.ActiveDocument.Tables(1).Cell(2, 2).Select '選中表格的第2行第2列
    Call WordApp.Application.Selection.MoveDown(5, 3, 1) '向下移動3格
    WordApp.Application.Selection.Cells.Merge '合併4個格子
    
    '拆分單元格
    WordApp.ActiveDocument.Tables(1).Cell(10, 2).Select '選中表格的第10行第2列
    Call WordApp.Application.Selection.Cells.Split(7, 2, True) '拆分成7行2列    
    
    '訪問單元格內容
    Debug.Print WordApp.ActiveDocument.Tables(1).Cell(1, 1).Range.Text '第1行第1列的內容
    
    ActiveDocument.SaveAs "c:\MyWord.doc" '儲存最後生成的word文件

End Sub

Private Sub Form_Unload(Cancel As Integer)
    On Error Resume Next
    WordApp.Quit
    Set WordApp = Nothing
End Sub
 

        生成的表格如下圖所示：

        2、在Word文件中插入和匯出圖片物件

'先引用Microsoft Word 11.0 Object Library
Option Explicit

Dim WordApp As Word.Application '建立Word應用程式

Private Sub Command1_Click()
    On Error GoTo Errhandler
    CommonDialog1.Filter = "Word(*.Doc)|*.Doc|AllFile(*.*)|*.*"
    CommonDialog1.FilterIndex = 1
    CommonDialog1.ShowOpen
    Set WordApp = New Word.Application '例項化
    WordApp.Documents.Open CommonDialog1.FileName '開啟Word檔案
    WordApp.Visible = True '顯示 Office Word 介面
    '或者Application.Visible = True
    WordApp.DisplayAlerts = False '不提示儲存對話方塊
    WordApp.Selection.EndKey Unit:=wdStory  '將游標移到文件末尾，在文字後面插入圖片物件
    Selection.TypeText Text:="我的圖片" '圖片的標題名稱
    
    '插入圖片物件
    Selection.InlineShapes.AddPicture FileName:="C:\CommandPicture.jpg", LinkToFile:=False, SaveWithDocument:=True
    Selection.MoveLeft Unit:=wdCharacter, Count:=1, Extend:=wdExtend
    Selection.InlineShapes(1).ConvertToShape.Select
    Selection.ShapeRange.Fill.Visible = msoFalse
    Selection.ShapeRange.Fill.Transparency = 0#
    Selection.ShapeRange.Line.Weight = 0.75
    Selection.ShapeRange.Line.DashStyle = msoLineSolid
    Selection.ShapeRange.Line.Style = msoLineSingle
    Selection.ShapeRange.Line.Transparency = 0#
    Selection.ShapeRange.Line.Visible = msoFalse
    Selection.ShapeRange.LockAspectRatio = msoTrue
    Selection.ShapeRange.Height = 361.4
    Selection.ShapeRange.Width = 481.6
    Selection.ShapeRange.PictureFormat.Brightness = 0.5
    Selection.ShapeRange.PictureFormat.Contrast = 0.5
    Selection.ShapeRange.PictureFormat.ColorType = msoPictureAutomatic
    Selection.ShapeRange.PictureFormat.CropLeft = 0#
    Selection.ShapeRange.PictureFormat.CropRight = 0#
    Selection.ShapeRange.PictureFormat.CropTop = 0#
    Selection.ShapeRange.PictureFormat.CropBottom = 0#
    Selection.ShapeRange.RelativeHorizontalPosition = wdRelativeHorizontalPositionColumn
    Selection.ShapeRange.RelativeVerticalPosition = wdRelativeVerticalPositionPage
    Selection.ShapeRange.Left = wdShapeCenter
    Selection.ShapeRange.Top = wdShapeCenter
    Selection.ShapeRange.LockAnchor = False
    Selection.ShapeRange.WrapFormat.AllowOverlap = True
    Selection.ShapeRange.WrapFormat.Side = wdWrapBoth
    Selection.ShapeRange.WrapFormat.DistanceTop = CentimetersToPoints(0)
    Selection.ShapeRange.WrapFormat.DistanceBottom = CentimetersToPoints(0)
    Selection.ShapeRange.WrapFormat.DistanceLeft = CentimetersToPoints(0.32)
    Selection.ShapeRange.WrapFormat.DistanceRight = CentimetersToPoints(0.32)
    Selection.ShapeRange.WrapFormat.Type = 3
    Selection.ShapeRange.ZOrder msoSendBehindText  '設定圖片為襯托於文字下方

    '判斷文件中是否存在圖片物件
    If ActiveDocument.Shapes.Count + ActiveDocument.InlineShapes.Count > 0 Then
       '取得圖片的2種方法
       
       '第1種方法：用下面命令將檔案另存為網頁格式的檔案，資料夾“MyWord.files”將儲存Word文件中所有的圖片
       '這種方法對所有的Word版本均適用
       ActiveDocument.SaveAs "c:\MyWord.htm", wdFormatHTML '儲存為網頁格式
       
       '第2種方法：引用ADO物件庫，將所有的圖片儲存在資料庫中，然後可以一張一張地顯示出來
       
       '另外：
       '如果Word文件是docx格式的，那可以按這個辦法解決：
       '.docx 格式的檔案本質上是一個ZIP壓縮檔案，.docx 格式檔案的主要內容是儲存為XML格式的，但檔案並非直接保存於磁碟。
       '它是儲存在一個ZIP檔案中，然後取副檔名為.docx。我們只需要用解壓軟體比如：WinZIP、WinRAR或者7ZIP等軟體進行解壓就可以了。
       '方法有兩種，一種是將.docx字尾名修改為.zip字尾名；另一個方法就是開啟WinZIP然後，選擇此文件即可。
       '圖片資原始檔都被儲存在word\media資料夾中。           
       
    Else
       Debug.Print "Word文件中不存在圖片物件！"
    End If

Errhandler:
    Exit Sub
End Sub

Private Sub Form_Unload(Cancel As Integer)
    On Error Resume Next
    WordApp.Quit
    Set WordApp = Nothing
End Sub
 

        3、統計Word文件頁數、字數

'先引用Microsoft Word 11.0 Object Library
Option Explicit

Dim WordApp As Word.Application '建立Word應用程式

Private Sub Command1_Click()
    On Error GoTo Errhandler
    CommonDialog1.Filter = "Word(*.Doc)|*.Doc|AllFile(*.*)|*.*"
    CommonDialog1.FilterIndex = 1
    CommonDialog1.ShowOpen
    Set WordApp = New Word.Application '例項化
    WordApp.Documents.Open CommonDialog1.FileName '開啟Word檔案
    WordApp.Visible = False '不顯示 Office Word 介面
    '或者Application.Visible = True
    'WordApp.DisplayAlerts = False '不提示儲存對話方塊
    
    Debug.Print WordApp.ActiveDocument.ComputeStatistics(Word.WdStatistic.wdStatisticPages) '頁數
    Debug.Print WordApp.ActiveDocument.Characters.Count '字數
    
Errhandler:
    Exit Sub
End Sub

Private Sub Form_Unload(Cancel As Integer)
    On Error Resume Next
    WordApp.Quit
    Set WordApp = Nothing
End Sub