列表控制元件ListView是窗體中核心元件之一，在各種窗體程式得到廣泛應用。在《【mfc】學生資訊管理，實現List控制元件節點的增刪改查》（點選開啟連結）中極其難以實現列表控制元件ListView的增刪改查，在vb中可以輕鬆實現，下面舉一個列子來說明這個問題。

如上圖的一個ListView控制元件，點選“新增”按鈕，在彈出的模態視窗，可以為ListView控制元件新增相應的項。

通過“刪除”按鈕可以刪除選中的項。通過“修改”按鈕，選中的項的值將會傳遞到模態視窗，通過修改模態視窗的值。能夠修改相應列的內容。

製作過程：

一、控制元件佈局與屬性設定

1、新建一個vb工程，裡面已經自帶一個Form1窗體，在於裡面新增一個Form2窗體

2、如下圖所示佈局，在Form1中拖入3個按鈕，與一個ListView控制元件。點選Form1窗體，禁用Form1的最大化按鈕。同時記下此時Form1的Size，一會要寫入指令碼。

3、對於Form1的ListView1屬性，將其Modifiers從預設的Friends改為Public，以便於Form2的指令碼能操控它。否則只能在Form1的指令碼中操控此控制元件。

4、在Form2中，如下圖所示佈局，拖入三個標籤文字Label，三個文字框Textbox，一個Button1按鈕。將三個文字框Textbox的Modifiers從預設的Friends改為Public，以便於Form1的指令碼能夠操控這三個文字框。同時，對於Form2這個窗體，與Form1同樣設定，禁用最大化按鈕，同時記錄下Form2的Size

二、指令碼程式設計

1、雙擊Form1窗體、三個按鈕，編寫如下的指令碼。

其核心思想是，

（1）禁止Form1被調節大小，一旦Form1的大小被調整，則馬上回復我們設定好的Size

（2）Form1窗體載入的時候，設定好ListView與三個Button的基本屬性。

（3）“新增”按鈕Button1點選的時候，將Form2的全域性變數selectItemIndex設定為“新增”狀態。此處的selectItemIndex=-1以為沒有選擇的項。區別於“修改”按鈕Button3被點選的時候，將選擇項的索引值通過修改全域性變數的方式，送到Form2

（4）對於“刪除”按鈕，就是找出被選擇的項，將其刪除。

Public Class Form1
    '禁止調整窗體大小指令碼
    '此處無法通過Me.Width與Me.Height來取出當前窗體的寬，在窗體未完成載入之前，此值固定為系統的窗體預設值，win7為300
    '因此，手動設定好當前窗體的寬與高，就是窗體編輯區的Form1中的Size屬性
    Dim form_width As Integer = 275
    Dim form_height As Integer = 226
    Private Sub Form1_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Resize
        If Me.Width <> form_width Then
            Me.Width = form_width
        End If
        If Me.Height <> form_height Then
            Me.Height = form_height
        End If
    End Sub
    '程式開始的指令碼
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Me.Text = "ListView控制元件的增刪改查"
        ListView1.View = View.Details '設定ListView1的樣式
        ListView1.FullRowSelect = True '選擇的時候，整行都被塗黑
        ListView1.MultiSelect = False '禁止選擇多項
        '設定各列的列名、寬度，因為這裡有3項，因此，寬度為當前ListView的寬度的三分之一。各減3畫素是放置出現橫向滾動條不美觀
        ListView1.Columns.Add("列1", CInt(ListView1.Width / 3) - 3)
        ListView1.Columns.Add("列2", CInt(ListView1.Width / 3) - 3)
        ListView1.Columns.Add("列3", CInt(ListView1.Width / 3) - 3)
        '按鈕的設定
        Button1.Text = "新增"
        Button2.Text = "刪除"
        Button3.Text = "修改"
    End Sub
    '“新增”按鈕指令碼
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Form2.selectItemIndex = -1 '標示當前行為：“新增”
        Form2.ShowDialog() '窗體Form2以模態對話方塊的方式所開啟
    End Sub
    '“刪除”按鈕指令碼
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        If ListView1.SelectedItems.Count > 0 Then
            '求出當前選擇的項，並刪除
            Dim selectItemIndex As Integer = ListView1.SelectedItems.Item(ListView1.SelectedItems.Count - 1).Index
            ListView1.Items.Item(selectItemIndex).Remove()
        Else
            MsgBox("請選擇其中的一項！")
        End If
    End Sub
    '“修改”按鈕指令碼
    Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        If ListView1.SelectedItems.Count > 0 Then
            '求出當前選擇的項
            Dim selectItemIndex As Integer = ListView1.SelectedItems.Item(ListView1.SelectedItems.Count - 1).Index
            Form2.selectItemIndex = selectItemIndex
            '將其值賦予Form2的各個對話方塊
            Form2.TextBox1.Text = ListView1.Items.Item(selectItemIndex).SubItems(0).Text
            Form2.TextBox2.Text = ListView1.Items.Item(selectItemIndex).SubItems(1).Text
            Form2.TextBox3.Text = ListView1.Items.Item(selectItemIndex).SubItems(2).Text
            Form2.ShowDialog() '窗體Form2以模態對話方塊的方式所開啟
        Else
            MsgBox("請選擇其中的一項！")
        End If
    End Sub

End Class

基本思想是：

（1）與Form1同樣，禁止使用者調整此窗體Form2的大小

（2）在Form2被開啟的時候，根據Form1使用者點選的按鈕時，所定義selectItemIndex全域性變數的值，設定Button1是顯示“新增”還是"修改"

（3）Form2的Button1被點選的時候，根據selectItemIndex的值，實行“新增”與“修改”動作。

Public Class Form2
    '禁止調整窗體大小指令碼
    '此處無法通過Me.Width與Me.Height來取出當前窗體的寬，在窗體未完成載入之前，此值固定為系統的窗體預設值，win7為300
    '因此，手動設定好當前窗體的寬與高，就是窗體編輯區的Form2中的Size屬性
    Dim form_width As Integer = 195
    Dim form_height As Integer = 176
    Private Sub Form1_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Resize
        If Me.Width <> form_width Then
            Me.Width = form_width
        End If
        If Me.Height <> form_height Then
            Me.Height = form_height
        End If
    End Sub

    Public selectItemIndex As Integer '供Form1所控制的全域性變數，用於判斷是修改，還是新增項
    '此模態對話方塊載入的動作
    Private Sub Form2_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Label1.Text = "列1："
        Label2.Text = "列2："
        Label3.Text = "列3："
        If selectItemIndex = -1 Then
            Button1.Text = "新增"
        Else
            Button1.Text = "修改"
        End If
    End Sub
    'Button1被點選的時候動作
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        If selectItemIndex = -1 Then '新增
            If TextBox1.Text = "" Or TextBox2.Text = "" Or TextBox3.Text = "" Then
                MsgBox("列1、列2、列3任意一項不能為空！")
            Else
                Dim item As ListViewItem = Form1.ListView1.Items.Add(TextBox1.Text)
                Dim tStrings(2) As String
                tStrings(0) = TextBox2.Text
                tStrings(1) = TextBox3.Text
                item.SubItems.AddRange(tStrings)
                Me.Close()
            End If
        Else '修改
            If TextBox1.Text = "" Or TextBox2.Text = "" Or TextBox3.Text = "" Then
                MsgBox("列1、列2、列3任意一項不能為空！")
            Else
                Form1.ListView1.Items.Item(Me.selectItemIndex).SubItems(0).Text = TextBox1.Text
                Form1.ListView1.Items.Item(Me.selectItemIndex).SubItems(1).Text = TextBox2.Text
                Form1.ListView1.Items.Item(Me.selectItemIndex).SubItems(2).Text = TextBox3.Text
                Me.Close()
            End If
        End If
    End Sub


End Class