一、彙編程式的基本格式：

1、基本格式與解析：

assume cs:codeseg   //assume假設CS暫存器與codeseg段有關聯，codeseg段本就是程式碼段

codeseg segment //段開始，codeseg為段名，可隨意命名只要不和偽指令、指令等衝突即可

    mov ax,4C00H
    int 21H

codeseg ends    //段結束

end //程式結束標誌

以上格式中assume、segment、ends、end均為偽指令，由編譯器識別翻譯。assume的關聯並非必須。

    mov ax,4C00H
    int 21H

而這兩條指令的功能就是實現程式返回，在DOS中如果是command將可執行程式載入入記憶體，command就設定CPU的CS：IP指向程式的第一條指令，及程式的入口，當程式從入口開始執行完畢以後，“mov ax,4C00H”、“int 21H”看來那個條指令執行後返回到command中，CPU則繼續執行command，如果是Debug將可執行程式載入進記憶體中，則返回後回到Debug（類似於在Shell中執行的子程序（”main(){return 0;}）執行完畢會返回shell，shell則繼續執行。只不過DOS是單程序，而Linux的Shell是時間片輪轉多程序）。

2、注意問題：

（1）不允許運算元以字母開頭：
在Debug中一行一行指令輸入時，我們可以以字母開頭，但是在編輯器編輯、MASM編譯、LINK連線時，就不能以字母開頭，否則會報未定義錯誤，如果遇到以字母開頭的，在其前面加一個0即可。
eg:

mov ax,B810H    //(×)
mov ax,47120    //(√)，B810H的十進位制
mov ax,0B810H   //(√)，十六進位制修改(修正)
mov al,E7H  //(×)
mov al,0E7H //(√)

關於以字母開頭會提示錯誤的測試如下：

（2）-g cs:ip、-g ip 快速執行多行
-g ip 省略cs，預設去ds暫存器中找。

//eg:    這是編譯過程中生成的“.lst”檔案中的一部分
                            assume cs:codeseg 

       0000                 codeseg segment 

       037F:0000  B8 1000           mov ax,1000H 
       037F:0003  8E D8             mov ds,ax 

       037F:0005  BB 0000           mov bx,0 
       037F:0008  8B 07             mov ax,ds:[bx] 
       037F
 
:000A  BB 0002           mov bx,2 
       037F:000D  8B 07             mov ax,ds:[bx] 

       037F:000F  BB 0004           mov bx,4 
       037F:0012  8B 07             mov ax,ds:[bx] 
       037F:0014  BB 0006           mov bx,6 
       037F:0017  8B 07             mov ax,ds:[bx] 

       037F:0019  BB 0008           mov bx,8 
       037F:001C  8B 07             mov ax,ds:[bx] 
       037F:001E  BB 000A           mov bx,10 
       037F:0021  8B 07             mov ax,ds:[bx] 

       037F:0023  B8 4C00           mov ax,4C00H 
       037F:0026  CD 21             int 21H 

       037F:0028                codeseg ends 

                            end 
//debug dabx.exe
//直接-g 000F
//將000F之前的執行完停到"mov bx,4"這一行等待執行

上面這段程式碼編譯執行前：

;-d 2000:1000
;00 00 00 00 00 00 00 00--00 00 00 00 00 00 00 00

編譯->連線->裝載->執行後，結果為：

;-d 2000:1000
;BE 00 EE 00 EE EE EE 00--00 00 00 00 00 00 00 00

（3）、用[bx]代替[n]：
在上面我們已經用到[bx]了。至於為什麼要用[bx]代替[n],同樣是因為在Debug中會自動識別為ds:[n]段地址+偏移地址的格式，但是在編輯器中編輯並通過masm編譯後，這種[n]形式的都會被編譯器解析為值，eg：mov ax,[2]會被解析為mov ax,2，但是並不是說必須用[bx]的形式，只是[n]的形式必須配合”段地址暫存器:[n]”的形式一起使用（“這裡的不能字母開頭”、“[bx]代替[n]”等問題都是Debug與MASM對指令的不同處理方式引起的）。

mov ax,[0]  //對MASM來說錯誤
mov ax,ds:[0]   //正確
mov ax,ds:[bx]  //正確
mov ax,[bx] //正確

3、程式載入：

編譯->連線->裝載（載入）->執行的過程，我們說說程式在記憶體中的裝載情況：

，測試如下：

二、loop指令、CX暫存器等：

1、簡介：

在C語言中，我們使用過goto語句：

loop_one:
    int x = 5;
    ...
    goto loop_one;

而在彙編中的迴圈（loop）與goto語句及其相似，其格式為：

loop_one:
    mov ax,5
    ...
    loop loop_one

我們C中goto迴圈何時結束的條件一般在if..else判斷中，而彙編則是將迴圈結束條件放在了CX暫存器中。給CX一個初始值（迴圈次數），當loop指令中標號（如：loop_one）所標識的地址被再次訪問，CX的值減去1（即loop執行一次，CX值自減1）。當CX的值為0時結束迴圈，執行loop指令的下一條指令。loop_one其實就是個地址，loop loop_one就是跳躍到loop_one所標識的地址去（IP暫存器修改為loop_one的地址），從該地址繼續解析指令並執行。loop指令的迴圈形式像do{}while();而不像while(){}，因為loop至少會執行一次。那麼CX初始化為0時，先減到FFFF再判斷，而不是直接判斷等於0退出迴圈。並且這是倒計時式的迴圈，不是計數式的迴圈。
（知識點：在用Debug的-p除錯時可以不進入迴圈/call調中去逐句執行。-p：特點是當遇到int中斷程式時，會一次性將呼叫的中斷程式執行完；而-t：的特點是當遇到int中斷程式時會追蹤到呼叫的中斷程式裡面去。像loop、call、int 21H等都屬於int中斷，所以通常會用到-p而不是-t）

2、應用：

例一：計算FFFF:0~FFFF:F的位元組型資料的和，結果儲存到DX中：

assume cs:codeseg

codeseg segment
        ;設定ds暫存器為FFFFH
        mov bx,0
        mov ax,0FFFFH
        mov ds,ax

        mov dx,0        ;初始偏移地址為0
        mov cx,16       ;FFFF:0~FFFF:F共16個位元組，迴圈16次
        mov ax,0        ;位元組型資料，需要8位暫存器，但是8位可能累加時溢位，必須用16位，所以高位必須清零，之後向AL存資料，所以只需清零一次

    addNumber:
        mov al,ds:[bx]  ;位元組型資料，需要8位暫存器
        add dx,ax       ;累加
        inc bx          ;inc指令將bx的值自加1，即偏移地址增大一個位元組
        loop addNumber  ;條件(CX)減1

        mov ax,4C00H
        int 21H

codeseg ends

end

測試結果：

2、將FFFF:0~FFFF:F的資料複製到0:200~020F中：

assume cs:codeseg

codeseg segment

        mov cx,16
        mov bx,0
    ;由於只用一個ds資料段地址暫存器，而需要在兩段資料段之間迴圈操作，就需要用中間暫存器先儲存被複制的物件，然後修改ds暫存器，最後將中間暫存器中的一個位元組mov到目標地址中
    copyNumber:
        mov ax,0FFFFH
        mov ds,ax
        mov al,ds:[bx]  ;儲存到中間暫存器

        mov ax,0020H    ;修改ds暫存器，0020*10:0==0:200
        mov ds,ax
        mov ds:[bx],al  ;中間暫存器轉移

        inc bx  ;操作下一個位元組
        loop copyNumber

        mov ax,4C00H
        int 21H

codeseg ends

end

三、ES暫存器：

由於上例題中，用一個ds暫存器在兩段地之間來回修改，使得指令數隨著迴圈次數增大而成倍增加，那麼我們是否可以借用其它段地址暫存器（cs:[bx]、ss:[bx]、es:[bx]來優化）呢？但是cs和ss都已有他用，只有ES空閒，ES暫存器也是一個段地址暫存器，我們可以用ES段地址暫存器對上例進行優化：
DS:資料從哪裡來
ES:資料到哪裡去
當然ES和DS在下例中可以替換位置，但是注意：ds可以不寫成ds:[bx]的形式，因為[bx]預設是ds:[bx]，而ES就必須寫成es:[bx]，否協會被解析為ds:[bx]。

assume cs:codeseg

codeseg segment

        mov cx,16
        mov bx,0

        mov ax,0FFFFH  ;ds暫存器儲存被複制者段地址
        mov ds,ax
        mov ax,0020H  ;es存放目標段地址
        mov es,ax

    ;用ES暫存器優化：
    copyNumber:
        mov dl,ds:[bx]
        mov es:[bx],dl  
        inc bx
        loop copyNumber

        mov ax,4C00H
        int 21H

codeseg ends

end

測試結果：

還有一點問題：由於彙編是直接對實體記憶體進行操作，所以不安全的記憶體操作很可能發生，為了避免使用已經有資料的記憶體，我們要儘量在0:200~0:2FF的256個位元組中進行程式設計（因為DOS以及其他合法程式一般會使用該段空間）。