在用執行緒的時候經常要啟動和掛起，原來d7的時候可以用resume和suspend(但是，建議不要用這2個方法，因為這2個方法在作業系統層面會造成死鎖)，現在版本的TThread裡已經把這2個方法宣告為deprecated(我用的是xe2,具體不知道從哪個版本起)。原來在D7的時候要掛起執行緒，也沒用suspend,也是自己實現。

參考置頂帖（現在好象沒了，只有推薦了，見 http://bbs.csdn.net/topics/360046056 ），主要是參考它的退出執行緒方法，寫了個"通用"執行緒。

注:實際也不通用，我的情況是通用於主從方式的資料採集，某些系統資源，比如串列埠什麼的，資料採集執行緒和主執行緒共用，也就是一般情況下，資料採集執行緒通過串列埠迴圈不斷採集下位機的資料，當需要時，主執行緒可以掛起資料採集執行緒，讓出資源（串列埠）供主執行緒用。

資料採集執行緒中，資源(串列埠)佔用時候時間有長有短，長的時候可能數秒，主執行緒發出掛起命令後，採集執行緒不一定馬上結束工作，因而要判斷採集執行緒是否真正完成了"工作"，主執行緒是否可以用資源(串列埠)了，這裡就有一個等待採集執行緒工作完成的問題。

程式碼用起來雖然沒發現有什麼問題，不過感覺有點彆扭，等待以後改進了

unit unHardWorkThread;

interface

uses
  Winapi.Windows, Winapi.Messages, System.Classes, System.SysUtils, System.SyncObjs,
  unGeneral;

const
  WM_QUIT_HARD_THREAD = WM_USER + 301;
  DELAY_TIME_MIN      = 10;

type
  THardWorkThread = class(TThread)
  private
    FQuitEvent:TEvent;                              //退出執行緒
    FSuspendEvent:TEvent;                           //掛起執行緒事件，有訊號表示正在工作，無訊號表示已經掛起
    FWorkEvent:TEvent;                              //正在工作事件
    FPIsInterrupt:PBoolean;                         //中斷
    FDelayTime:Word;                                //延遲
    FIsWorking:Boolean;                             //是否工作中
  protected
    SupervisorCtl:TObject;                          //管理者物件
    MsgHandle:THandle;                              //訊息目的視窗控制代碼

    ErrorCount:Integer;                             //連續錯誤次數

    procedure Execute; override;
    procedure DoWorkProc(const APIsInterrupt:PBoolean); virtual; abstract;  //實際的工作過程(虛方法，子類必須實現)
  public
    constructor Create(ASupervisorCtl:TObject; AMsgHandle:THandle; ADelayTime:Word);
    destructor Destroy; override;

    function  ExitThread(const AWaitTime:Integer):Boolean;                  //退出執行緒
    function  SuspendThread(const AWaitTime:Integer):Boolean;               //掛起執行緒
    function  ResumeThread(const AWaitTime:Integer):Boolean;                //恢復執行緒
    function  WaitForWorkCompleted(const AWaitTime:Integer):Boolean;        //等待執行緒工作完成

  end;

implementation

{ THardWorkThread }

constructor THardWorkThread.Create(ASupervisorCtl: TObject; AMsgHandle: THandle; ADelayTime:Word);
begin
  inherited Create(True);

  SupervisorCtl:=ASupervisorCtl;
  MsgHandle:=AMsgHandle;

  FQuitEvent:=TEvent.Create;
  FSuspendEvent:=TEvent.Create;
  FWorkEvent:=TEvent.Create;
  New(FPIsInterrupt);
  FPIsInterrupt^:=False;

  FIsWorking:=False;
  ErrorCount:=0;
  FDelayTime:=ADelayTime;

end;

destructor THardWorkThread.Destroy;
begin
  Dispose(FPIsInterrupt);
  FWorkEvent.Free;
  FSuspendEvent.Free;
  FQuitEvent.Free;

  inherited;
end;

{
procedure THardWorkThread.DoWorkProc;
begin

end;
}
procedure THardWorkThread.Execute;
var
  Msg:TMsg;
begin
  FreeOnTerminate:=True;

  while True do
  begin
    if PeekMessage(Msg,0,0,0,PM_REMOVE) then
    begin
      if Msg.message = WM_QUIT_HARD_THREAD then
      begin
        FQuitEvent.SetEvent;
        Break;
      end;
    end;

    if FPIsInterrupt^ then
    begin
      Continue;
    end;

    FSuspendEvent.WaitFor(INFINITE);

    if FPIsInterrupt^ then
    begin
      Continue;
    end;

    FIsWorking:=True;
    FWorkEvent.ResetEvent;
    try
      DoWorkProc(FPIsInterrupt);
    finally
      FWorkEvent.SetEvent;
      FIsWorking:=False;
    end;

    if FDelayTime > DELAY_TIME_MIN then
    begin
      if DelayCanInterrupt(FDelayTime,FPIsInterrupt) then
        Continue;
    end;
  end;

end;

function THardWorkThread.ExitThread(const AWaitTime: Integer): Boolean;
begin
  Result:=True;
  PostThreadMessage(ThreadID,WM_QUIT_HARD_THREAD,0,0);
  FPIsInterrupt^:=True;
  if FQuitEvent.WaitFor(AWaitTime) = wrTimeOut then
    Result:=False;
end;

function THardWorkThread.ResumeThread(const AWaitTime: Integer): Boolean;
begin
  FSuspendEvent.SetEvent;
  Result:=True;
end;

function THardWorkThread.SuspendThread(const AWaitTime: Integer): Boolean;
const
  Def_WaitTime = 10;
begin
  Result:=False;
  if FSuspendEvent.WaitFor(Def_WaitTime) = wrSignaled then
  begin
    if WaitForWorkCompleted(AWaitTime) then
    begin
      FSuspendEvent.ResetEvent;
      Result:=True;
    end;
  end
  else
  begin
    FSuspendEvent.ResetEvent;
    Result:=True;
  end;
end;

function THardWorkThread.WaitForWorkCompleted(const AWaitTime: Integer): Boolean;
begin
  if FIsWorking then
    Result:=FWorkEvent.WaitFor(AWaitTime) = wrSignaled
  else
    Result:=True;
end;

end.