Linux進階篇–文字處理三劍客之AWK

本章概要

• awk介紹
• awk基本用法
• awk變數
• awk格式化
• awk操作符
• awk條件判斷
• awk迴圈
• awk陣列
• awk函式
• 呼叫系統命令

一、 awk介紹

• awk：Aho, Weinberger, Kernighan，報告生成器，格式化文字輸出
• 有多種版本：New awk（nawk），GNU awk（ gawk）
• 目前centos系統使用的版本為GNU awk，即gawk

[[email protected] ~]#ll /usr/bin/awk   軟連結指向gawk
lrwxrwxrwx. 1 root root 4 Jul 18 17:17 /usr/bin/awk -> gawk
 

• gawk：模式掃描和處理語言
• 基本用法：
    awk [options] ‘program’ var=value file…
    awk [options] -f programfile var=value file…
    awk [options] ‘BEGIN{action;… }pattern{action;… }END{action;… }’ file …
    awk 程式可由：BEGIN語句塊、能夠使用模式匹配的通用語句塊、END語句塊，共3部分組成
    program 通常是被放在單引號中
• 選項：
    -F “分隔符” 指明輸入時用到的欄位分隔符
    -v var=value 變數賦值

awk語言

• 基本格式：awk [options] ‘program’ file…
• Program：pattern{action statements;…}
• pattern和action
    pattern部分決定動作語句何時觸發及觸發事件
     BEGIN,END
    action statements對資料進行處理，放在{}內指明
     print, printf
• 分割符、欄位(field)和記錄(record)
    awk執行時，讀取檔案內容的每一行與命令進行匹配(類似於sed)，根據指定的分隔符把每一行進行分割，分隔開的每一段內容稱為欄位(field)，標記為$1,$2…$n，$0為所有欄位，即整行內容，注意：此時和shell中變數$符含義不同
    而檔案內容的每一行稱為記錄(record)
    省略action，則預設執行 print $0 的操作
  示例：

root:x:0:0:root:/root:/bin/bash
如果指定分隔符為冒號":"，那麼":"分割開的每一段內容即為一個欄位；而該內容整行即為一條記錄

awk工作原理

• 第一步：執行BEGIN{action;… }語句塊中的語句
• 第二步：從檔案或標準輸入(stdin)讀取一行，然後執行pattern{ action;… }語句塊，它逐行掃描檔案，從第一行到最後一行重複這個過程，直到檔案全部被讀取完畢。
• 第三步：當讀至輸入流末尾時，執行END{action;…}語句塊
• BEGIN語句塊在awk開始從輸入流中讀取行之前被執行，這是一個可選的語句塊，比如變數初始化、列印輸出表格的表頭等語句通常可以寫在BEGIN語句塊中
• END語句塊在awk從輸入流中讀取完所有的行之後即被執行，比如列印所有行的分析結果這類資訊彙總都是在END語句塊中完成，它也是一個可選語句塊
• pattern語句塊中的通用命令是最重要的部分，也是可選的。如果沒有提供pattern語句塊，則預設執行{ print }，即列印每一個讀取到的行，awk讀取的每一行都會執行該語句塊

awk print格式

• print格式：print item1, item2, …
• 要點：
  (1) 逗號分隔符
  (2) 輸出item可以字串，也可是數值；當前記錄的欄位、變數或awk的表示式
  (3) 如省略item，相當於print $0
  示例：

[[email protected] ~]#awk '{print "hello awk"}'
aaa
hello awk
bbb
hello awk
vvv
hello awk
^C
[[email protected] ~]#awk  -F: '{print}' /etc/passwd    {print}預設列印全部，這裡只貼出部分內容
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
adm:x:3:4:adm:/var/adm:/sbin/nologin
lp:x:4:7:lp:/var/spool/lpd:/sbin/nologin
[[email protected] ~]#awk -F: '{print "yuan"}' /etc/passwd   /etc/passwd有多少行，就顯示多少行yuan；空間原因，只貼出部分內容
yuan
yuan
yuan
yuan
yuan
yuan
yuan
[[email protected] ~]#awk -F: '{print $1}' /etc/passwd 列印/etc/passwd每一條記錄的第一個欄位
root
bin
daemon
adm
lp
sync
[[email protected] ~]#awk -F: '{print $0}' /etc/passwd  列印/etc/passwd每一行記錄，這裡只貼出部分 
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
adm:x:3:4:adm:/var/adm:/sbin/nologin
lp:x:4:7:lp:/var/spool/lpd:/sbin/nologin 
[[email protected] ~]#awk -F: '{print $1"\t"$3}' /etc/passwd  列印/etc/passwd每一條記錄的第一個欄位，第三個欄位，中間以tab鍵分開
root	0
bin	1
daemon	2
adm	3
lp	4
sync	5
shutdown	6
注意：\t在變數之間要用""，在普通字串之間則不用""
如：[[email protected] ~]#awk -F: '{print  "hello\twak"}'  /etc/passwd
hello	wak
hello	wak
hello	wak
hello	wak
hello	wak
hello	wak
[[email protected] ~]#grep "^UUID" /etc/fstab |awk '{print $2,$4}'
/ defaults
/boot defaults
/data defaults
swap defaults

二、 awk變數

• 變數：內建變數和自定義變數

內建變數

• FS：輸入欄位分隔符，預設為空白字元

[[email protected] ~]#awk -v FS=':' '{print $1,FS,$3}' /etc/passwd  
root : 0
bin : 1
daemon : 2
adm : 3
lp : 4
sync : 5
[[email protected] ~]#awk -F: '{print $1,$3,$7}' /etc/passwd  
root 0 /bin/bash
bin 1 /sbin/nologin
daemon 2 /sbin/nologin
adm 3 /sbin/nologin

• OFS：輸出欄位分隔符，預設為空白字元

[[email protected] ~]#awk -v FS=':' -v OFS=':' '{print $1,$3,$7}' /etc/passwd  
root:0:/bin/bash
bin:1:/sbin/nologin
daemon:2:/sbin/nologin
adm:3:/sbin/nologin

• RS：輸入記錄分隔符，指定輸入時的換行符

[[email protected] ~]#awk -v RS=' '  '{print }' /etc/passwd
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
adm:x:3:4:adm:/var/adm:/sbin/nologin

• ORS：輸出記錄分隔符，輸出時用指定符號代替換行符

[[email protected] ~]#awk -v RS=' ' -v ORS='###' '{print }' /etc/passwd
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
adm:x:3:4:adm:/var/adm:/sbin/nologin
lp:x:4:7:lp:/var/spool/lpd:/sbin/nologi

• NF：欄位數量

[[email protected] ~]#awk -F: '{print NF}' /etc/passwd  引用變數時，變數前不需加$
7
7
7
7
[[email protected] ~]#awk -F: '{print $(NF-1)}' /etc/passwd
/root
/bin
/sbin
/var/adm
/var/spool/lpd

• NR：記錄號

[[email protected] ~]#awk '{print NR}' /etc/passwd  列印所有記錄號，這裡只貼出部分
1
2
3
4
...
43
44
45
[[email protected] ~]#awk '{print NR}' /etc/passwd /etc/group  會把兩個檔案內容疊加起來顯示
1
2
3
4
...
119
120
121

• FNR：各檔案分別計數,記錄號

[[email protected] ~]#awk '{print FNR}' /etc/passwd /etc/group
1
2
3
4
...
44
45
1
2
3
4
...
74
75

• FILENAME：當前檔名

[[email protected] ~]#awk '{print FILENAME}' /etc/passwd
/etc/passwd
/etc/passwd
/etc/passwd
/etc/passwd
/etc/passwd

• ARGC：命令列引數的個數

[[email protected] ~]#awk '{print ARGC}'  /etc/fstab  /etc/passwd /etc/group
4
4
4
4
4
注意：除了/etc/fstab  /etc/passwd /etc/group，awk本身也算是一個引數，因此引數個數為4

• ARGV：陣列，儲存的是命令列所給定的各引數

[[email protected] ~]#awk 'BEGIN{print ARGV[0]}' /etc/fstab /etc/passwd
awk
[[email protected] ~]#awk 'BEGIN{print ARGV[1]}' /etc/fstab /etc/passwd
/etc/fstab
[[email protected] ~]#awk 'BEGIN{print ARGV[2]}' /etc/fstab /etc/passwd
/etc/passwd

自定義變數

• 自定義變數(區分字元大小寫)
    (1) -v var=value
    (2) 在program中直接定義
• 示例：

awk -v test='hello gawk' '{print test}' /etc/fstab
awk -v test='hello gawk' 'BEGIN{print test}'
awk 'BEGIN{test="hello,gawk";print test}'
awk -F: '{sex="male";print $1,sex,age;age=18}'  /etc/passwd
[[email protected] ~]#cat awkscript 
{print script,$1,$3}
[[email protected] ~]#awk -F: -f awkscript  /etc/passwd
 root 0
 bin 1
 daemon 2
 adm 3
 lp 4
 sync 5

三、 awk格式化

printf命令

• 格式化輸出：printf “FORMAT”, item1, item2, …
    (1) 必須指定FORMAT
    (2) 不會自動換行，需要顯式給出換行控制符，\n
    (3) FORMAT中需要分別為後面每個item指定格式符
• 格式符：與item一一對應
    c：顯示字元的ASCII碼
    %d, %i：顯示十進位制整數
    %e, %E：顯示科學計數法數值
    %f：顯示為浮點數
    %g, %G：以科學計數法或浮點形式顯示數值
    %s：顯示字串
    %u：無符號整數
    %%：顯示%自身
• 修飾符
    #[.#] 第一個數字控制顯示的寬度；第二個#表示小數點後精度，%3.1f，多餘的小數位採用五舍六入進行取捨
    - 左對齊（預設右對齊） %-15s
    + 顯示數值的正負符號 %+d
  示例：

[[email protected] ~]#awk -F: '{printf "%-20s %10d\n",$1,$3}' /etc/passwd
root                          0
bin                           1
daemon                        2
adm                           3
lp                            4
sync                          5
[[email protected] ~]#awk -F: '{printf "username: %s\n",$1}' /etc/passwd
username: root
username: bin
username: daemon
username: adm
username: lp
username: sync
[[email protected] ~]#awk -F: '{printf "username: %s   UID:%d\n",$1,$3}' /etc/passwd
username: root   UID:0
username: bin   UID:1
username: daemon   UID:2
username: adm   UID:3
username: lp   UID:4
username: sync   UID:5
[[email protected] ~]#awk -F: '{printf "username: %25s   UID:%d\n",$1,$3}' /etc/passwd
username:                      root   UID:0
username:                       bin   UID:1
username:                    daemon   UID:2
username:                       adm   UID:3
username:                        lp   UID:4
[[email protected] ~]#awk -F: '{printf "username: %-25s   UID:%d\n",$1,$3}' /etc/passwd
username: root                        UID:0
username: bin                         UID:1
username: daemon                      UID:2
username: adm                         UID:3
username: lp                          UID:4
username: sync                        UID:5

知識擴充套件：

使用awk製作表格：
awk -F: 'BEGIN{print "|username                     |userid    |\n------------------------------------------"}{printf "%-30s|%-10d|\n------------------------------------------\n",$1,$3}' /etc/passwd > userlist
[[email protected] ~]#cat userlist 
|username                     |userid    |
------------------------------------------
root                          |0         |
------------------------------------------
bin                           |1         |
------------------------------------------
daemon                        |2         |
------------------------------------------
adm                           |3         |
------------------------------------------
lp                            |4         |
------------------------------------------
sync                          |5         |
------------------------------------------
shutdown                      |6         |
------------------------------------------

四、 awk操作符

• 算術操作符：
    x+y, x-y, x*y, x/y, x^y, x%y
    -x：轉換為負數
    +x：將字串轉換為數值
• 字串操作符：沒有符號的操作符，字串連線
• 賦值操作符：
  =, +=, -=, *=, /=, %=, ^=，++, --
    下面兩語句有何不同

[[email protected] ~]#awk 'BEGIN{i=0;print ++i,i}'   先做++運算，再列印i
1 1
[[email protected] ~]#awk 'BEGIN{i=0;print i++,i}'   先列印i，再做++運算
0 1

• 比較操作符：
    ==, !=, >, >=, <, <=
• 模式匹配符：
    ~：左邊是否和右邊匹配包含
    !~：是否不匹配
  示例：

[[email protected] ~]#awk -F: '$0 ~ /root/{print $1}' /etc/passwd
root
[[email protected] ~]#awk '$0~"^root"' /etc/passwd
root:x:0:0:root:/root:/bin/bash
[[email protected] ~]#awk '$0 !~ /root/' /etc/passwd   列印不包含root的行，這裡只貼出部分內容
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
adm:x:3:4:adm:/var/adm:/sbin/nologin
lp:x:4:7:lp:/var/spool/lpd:/sbin/nologin
[[email protected]-1 ~]#awk -F: '$3==0' /etc/passwd
root:x:0:0:root:/root:/bin/bash

• 邏輯操作符：與&&，或||，非!
  示例：

[[email protected] ~]#awk -F: '$0 ~ /root/{print $1}' /etc/passwd
root
[[email protected] ~]#awk '$0~"^root"' /etc/passwd
root:x:0:0:root:/root:/bin/bash
[[email protected] ~]#awk '$0 !~ /root/' /etc/passwd  列印所有內容，這裡只貼出部分內容
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
adm:x:3:4:adm:/var/adm:/sbin/nologin
lp:x:4:7:lp:/var/spool/lpd:/sbin/nologin
[[email protected] ~]#awk -F: '$3==0' /etc/passwd
root:x:0:0:root:/root:/bin/bash

• 條件表示式（三目表示式）
  selector?if-true-expression:if-false-expression
  示例：

[[email protected] ~]#awk -F: '{$3>=1000?usertype="Common User":usertype=" SysUser";printf "%15s:%-s\n",$1,usertype}' /etc/passwd
           root: SysUser
            bin: SysUser
         daemon: SysUser
            adm: SysUser
             lp: SysUser

awk PATTERN

• PATTERN:根據pattern條件，過濾匹配的行，再做處理
  (1)如果未指定：空模式，匹配每一行
  (2) /regular expression/：僅處理能夠模式匹配到的行，需要用/ /括起來

[[email protected] ~]#awk '/^UUID/{print $1}' /etc/fstab
UUID=2f1bda24-d0a0-4498-84b2-76ecad8602b8
UUID=da6027b7-04a8-412e-b54d-0a3cbe7a9e0d
UUID=13feb009-a4b1-4521-b6fe-2596f033f6a5
UUID=bbbfb1b0-b076-4203-a4d3-0b7cd755019d
[[email protected] ~]#awk '!/^UUID/{print $1}' /etc/fstab  預設以空格為分隔符，列印第一列為#

#
#
#
#
#
#
#

(3) relational expression: 關係表示式，結果為“真”才會被處理
  真：結果為非0值，非空字串
  假：結果為空字串或0值

• 示例：

[[email protected] ~]#awk -F: 'i=1;j=1{print i,j}' /etc/passwd  這裡只貼出部分內容
root:x:0:0:root:/root:/bin/bash
1 1
bin:x:1:1:bin:/bin:/sbin/nologin
1 1
daemon:x:2:2:daemon:/sbin:/sbin/nologin
1 1
adm:x:3:4:adm:/var/adm:/sbin/nologin
awk ‘!0’ /etc/passwd ; awk ‘!1’ /etc/passwd  
Awk -F: '$3>=1000{print $1,$3}' /etc/passwd  
awk -F: '$3<1000{print $1,$3}' /etc/passwd
awk -F: '$NF=="/bin/bash"{print $1,$NF}' /etc/passwd
awk -F: '$NF ~ /bash$/{print $1,$NF}' /etc/passwd

• (4) line ranges：行範圍
  startline,endline：/pat1/,/pat2/ 不支援直接給出數字格式

[[email protected] ~]#awk -F: '/^root\>/,/^nobody\>/{print $1}' /etc/passwd
root
bin
daemon
adm
lp
sync
shutdown
halt
mail
operator
games
ftp
nobody
[[email protected] ~]#awk -F: '(NR>=10&&NR<=20){print NR,$1}'  /etc/passwd
10 operator
11 games
12 ftp
13 nobody
14 systemd-network
15 dbus
16 polkitd
17 sssd
18 libstoragemgmt
19 rpc
20 colord

• (5) BEGIN/END模式
  BEGIN{}: 僅在開始處理檔案中的文字之前執行一次
  END{}：僅在文字處理完成之後執行一次
  示例：

awk -F : 'BEGIN {print "USER USERID"} {print $1":"$3} END{print "end file"}' /etc/passwd
awk -F : '{print "USER USERID“;print $1":"$3} END{print "end file"}' /etc/passwd
awk -F: 'BEGIN{print " USER UID \n--------------- "}{print $1,$3}' /etc/passwd
awk -F: 'BEGIN{print " USER UID \n--------------- "}{print $1,$3}'END{print "=============="} /etc/passwd
seq 10 |awk 'i=0'
seq 10 |awk 'i=1'
seq 10 | awk 'i=!i'
seq 10 | awk '{i=!i;print i}''
seq 10 | awk '!(i=!i)'
seq 10 |awk -v i=1 'i=!i'

知識擴充套件：

取分割槽利用率
df|awk -F" +|%" '/^\/dev\/sd/{print $1,$5}'
檢視fstab中檔案系統類別
cat /etc/fstab |awk '/^UUID/{print $3}'|sort|uniq -c|sort -nr
統計連線數，並且從大到小排序
netstat -nt|awk -F" +|:" '/^tcp/{print $6}'|sort|uniq -c|sort -nr

awk action

• 常用的action分類
  (1) Expressions:算術，比較表示式等
  (2) Control statements：if, while等
  (3) Compound statements：組合語句
  (4) input statements
  (5) output statements：print等

五、 awk控制語句

• { statements;… } 組合語句
• if(condition) {statements;…}
• if(condition) {statements;…} else {statements;…}
• while(conditon) {statments;…}
• do {statements;…} while(condition)
• for(expr1;expr2;expr3) {statements;…}
• break
• continue
• delete array[index]
• delete array
• exit

5.1 條件判斷

awk控制語句if-else

• 語法：
    if(condition){statement;…}[else statement]
    if(condition1){statement1}else if(condition2){statement2}else{statement3}
• 使用場景：對awk取得的整行或某個欄位做條件判斷
  示例：

[[email protected] ~]#awk -F: '{if($3>=1000)print $1,$3}' /etc/passwd
nfsnobody 65534
yuan 1000
wang 1001
[[email protected] ~]#awk -F: '{if($NF=="/bin/bash") print $1}' /etc/passwd
root
wang
awk '{if(NF>5) print $0}' /etc/fstab
awk -F: '{if($3>=1000) {printf "Common user: %s\n",$1} else {printf "root or Sysuser: %s\n",$1}}' /etc/passwd
awk -F: '{if($3>=1000) printf "Common user: %s\n",$1; else printf "root or Sysuser: %s\n",$1}' /etc/passwd
df -h|awk -F% '/^\/dev/{print $1}'|awk '$NF>=80{print $1,$5}'
awk 'BEGIN{ test=100;if(test>90){print "very good"}
else if(test>60){ print "good"}else{print "no pass"}}'

知識擴充套件：

找出訪問次數超過10000次的ip地址，並放入防火牆
cat access_log | awk '{print $1}'|sort|uniq -c|sort -nr|awk '{if($1>10000)print $2}'|while read ip ;do iptables -A -s $ip -j REJECT;done

5.2 迴圈

awk控制語句while迴圈

• while迴圈
• 語法：while(condition){statement;…}
• 條件“真”，進入迴圈；條件“假”，退出迴圈
• 使用場景：
    對一行內的多個欄位逐一類似處理時使用
    對陣列中的各元素逐一處理時使用
  示例：

列出linux16這一行每個單詞出現的次數
[[email protected] ~]#awk '/^[[:space:]]*linux16/{i=1;while(i<=NF){print $i,length($i); i++}}' /etc/grub2.cfg  
linux16 7
/vmlinuz-3.10.0-862.el7.x86_64 30
root=UUID=2f1bda24-d0a0-4498-84b2-76ecad8602b8 46
ro 2
rhgb 4
quiet 5
net.ifnames=0 13
linux16 7
/vmlinuz-0-rescue-7eab25876df747da952cee5f5a6dbc5f 50
root=UUID=2f1bda24-d0a0-4498-84b2-76ecad8602b8 46
ro 2
rhgb 4
quiet 5
net.ifnames=0 13
構建100個隨機數，取出最大值和最小值
[[email protected] ~]#awk -F"," '{max=$1;min=$1;i=2;while(i<=NF){if($i>max){max=$i}else if($9<min){min=$i};i++;}}END{print "max="max,"min="min}' f1.txt
max=32369 min=9181

awk控制語句do-while迴圈

• do-while迴圈
• 語法：do {statement;…}while(condition)
• 意義：無論真假，至少執行一次迴圈體
  示例：

[[email protected] ~]#awk 'BEGIN{ total=0;i=0;do{ total+=i;i++;}while(i<=100);print total}'
5050

awk控制語句for迴圈

• for迴圈
• 語法：for(expr1;expr2;expr3) {statement;…}
• 常見用法：
  for(variable assignment;condition;iteration process){for-body}
• 特殊用法：能夠遍歷陣列中的元素
  語法：for(var in array) {for-body}
  示例：

[[email protected] ~]#awk '/^[[:space:]]*linux16/{for(i=1;i<=NF;i++) {print $i,length($i)}}' /etc/grub2.cfg  
linux16 7
/vmlinuz-3.10.0-862.el7.x86_64 30
root=UUID=2f1bda24-d0a0-4498-84b2-76ecad8602b8 46
ro 2
rhgb 4
quiet 5
net.ifnames=0 13
linux16 7
/vmlinuz-0-rescue-7eab25876df747da952cee5f5a6dbc5f 50
root=UUID=2f1bda24-d0a0-4498-84b2-76ecad8602b8 46
ro 2
rhgb 4
quiet 5
net.ifnames=0 13

效能比較

[[email protected] ~]#time (awk 'BEGIN{ total=0;for(i=0;i<=10000;i++){total+=i;};print total;}') 
50005000

real	0m0.004s
user	0m0.003s
sys	0m0.001s
[[email protected] ~]#time(total=0;for i in {1..10000};do total=$(($total+i));done;echo $total)  
50005000

real	0m0.059s
user	0m0.044s
sys	0m0.015s
[[email protected] ~]#time(for ((i=0;i<=10000;i++));do let total+=i;done;echo $total) 
50005000

real	0m0.081s
user	0m0.070s
sys	0m0.011s
[[email protected] ~]#time(seq –s ”+” 10000|bc)  
seq: invalid floating point argument: –s
Try 'seq --help' for more information.

real	0m0.344s
user	0m0.000s
sys	0m0.009s

awk控制語句switch語句、break、continue、next

• switch語句
• 語法：switch(expression) {case VALUE1 or /REGEXP/: statement1; case VALUE2 or /REGEXP2/: statement2; …; default: statementn}
• break和continue

awk 'BEGIN{sum=0;for(i=1;i<=100;i++){if(i%2==0)continue;sum+=i}print sum}''
awk 'BEGIN{sum=0;for(i=1;i<=100;i++){if(i==66)break;sum+=i}print sum}''

擴充套件用法：
break [n]
continue [n]

• next:
  提前結束對本行處理而直接進入下一行處理（awk自身迴圈）

[[email protected] ~]#awk -F: '{if($3%2!=0) next; print NR,$1,$3}' /etc/passwd   列印奇數行，這裡只貼出部分內容
1 root 0
3 daemon 2
5 lp 4
7 shutdown 6
9 mail 8
11 games 12
12 ftp 14
14 systemd-network 192
17 sssd 998

1到100之間的偶數相加
[[email protected] ~]#awk 'BEGIN{sum=0;for(i=1;i<=100;i++){if(i%2==1)continue; sum+=i};print sum}'
2550

六、 awk陣列

• 關聯陣列：array[index-expression]
• index-expression:
  (1) 可使用任意字串；字串要使用雙引號括起來
  (2) 如果某陣列元素事先不存在，在引用時，awk會自動建立此元素，並將其值初始化為“空串”
  (3) 若要判斷陣列中是否存在某元素，要使用“index in array”格式進行遍歷
  示例：

weekdays["mon"]="Monday"  
awk 'BEGIN{weekdays["mon"]="Monday";  
weekdays["tue"]="Tuesday";print weekdays["mon"]}'  
[[email protected] ~]#cat f2.txt 
aaa
bbb
aaa
ccc
ddd
aaa
ccc
[[email protected] ~]#awk '!arr[$0]++' f2.txt    給檔案“去重”
aaa
bbb
ccc
ddd
[[email protected] ~]#awk '{!arr[$0]++;print $0, arr[$0]}' f2.txt 
aaa 1
bbb 1
aaa 2
ccc 1
ddd 1
aaa 3
ccc 2

• 若要遍歷陣列中的每個元素，要使用for迴圈
• for(var in array) {for-body}
• 注意：var會遍歷array的每個索引
  示例：

[[email protected] ~]#awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"]="Tuesday";for(i in weekdays) {print weekdays[i]}}'
Tuesday
Monday
[[email protected] ~]#netstat -tan | awk '/^tcp/{state[$NF]++}END{for(i in state) { print i,state[i]}}'
LISTEN 18
ESTABLISHED 2
[[email protected] ~]#awk '{ip[$1]++}END{for(i in ip) {print i,ip[i]}}' access_log
172.20.129.234 407
172.20.120.185 195
172.20.130.5 1206
172.20.59.26 55
172.20.32.7 100
172.20.129.253 40
172.20.0.7 20
172.20.112.128 33
172.20.12.14 10
172.20.129.178 20
172.20.129.246 220

取出fqdn，並排序；fqdn即域名(mail.magedu.com)
[[email protected] ~]#cat f3.txt 
http://mail.magedu.com/index.html
http://www.magedu.com/test.html
http://study.magedu.com/index.html
http://blog.magedu.com/index.html
http://www.magedu.com/images/logo.jpg
http://blog.magedu.com/20080102.html
[[email protected] ~]#cat f3.txt |awk -F"/" '{url[$3]++}END{for(i in url){print url[i],i}}'|sort -nr
2 www.magedu.com
2 blog.magedu.com
1 study.magedu.com
1 mail.magedu.com

綜合用法：

1、求男生(性別為m)，女生(性別f)的平均成績
[[email protected] ~]#cat score.txt 
name  score  sex
mage  100    m
zhang 99     f
li    99     f
zhao  98     f
wang  90     m
方法1：用四個變數
男生成績score_m  
女生成績score_f
男生數量num_m
女生數量num_f
[[email protected] ~]#cat score.txt|awk '!/^name/{if($3=="m"){score_m+=$2;num_m++}else{score_f+=$2;num_f++}}END{print "avg_m="score_m/num_m,"avg_f="score_f/num_f}' 
avg_m=96.3333 avg_f=98.5
方法2：陣列
[[email protected] ~]#awk 'NR!=1{score[$3]+=$2;num[$3]++}END{for(sex in num){print sex":avg="score[sex]/num[sex]}}' score.txt
m:avg=96.3333
f:avg=98.5

2、求/etc/fstab每個單詞出現的個數
cat /etc/fstab |awk '{for(i=1;i<=NF;i++)word[$i]++}END{for (i in word){print i,word[i]}}'

七、 awk函式

• 數值處理：
    rand()：返回0和1之間一個隨機數

[[email protected] ~]#awk 'BEGIN{srand(); for (i=1;i<=10;i++)print int(rand()*100) }'
65
87
65
59
12
59
52
51
22
28

• 字串處理：
  length([s])：返回指定字串的長度
  sub(r,s,[t])：對t字串搜尋r表示模式匹配的內容，並將第一個匹配內容替換為s

[[email protected] ~]#echo "2008:08:08 08:08:08" |awk 'sub(/:/,"-",$1)'
2008-08:08 08:08:08

gsub(r,s,[t])：對t字串進行搜尋r表示的模式匹配的內容，並全部替換為s所表示的內容

[[email protected] ~]#echo "2008:08:08 08:08:08" |awk 'gsub(/:/,"-",$1)'
2008-08-08 08:08:08

split(s,array,[r])：以r為分隔符，切割字串s，並將切割後的結果儲存至array所表示的陣列中，第一個索引值為1,第二個索引值為2,…

[[email protected] ~]#netstat -tn | awk '/^tcp\>/{split($5,ip,":");count[ip[1]]++}END{for (i in count) {print i,count[i]}}'
192.168.32.1 2

• 自定義函式格式
    function name ( parameter, parameter, … ) {
      statements
      return expression
    }
  示例：

[[email protected] ~]#cat fun.awk   
function max(x,y) {   
         x>y?var=x:var=y    
         return var  
}  
BEGIN{a=3;b=2;print max(a,b)}  
[[email protected] ~]#awk -f f1
3

八、 呼叫系統命令

awk中呼叫shell命令

• system命令
• 空格是awk中的字串連線符，如果system中需要使用awk中的變數可以使用空格分隔，或者說除了awk的變數外其他一律用""引用起來
    awk’BEGIN’{system(“hostname”) }’
    awk’BEGIN{score=100; system("echo your score is " score) }’

awk指令碼

• 將awk程式寫成指令碼，直接呼叫或執行
  示例：

cat f1.awk
{if($3>=1000)print $1,$3}
awk -F: -f f1.awk /etc/passwd

cat f2.awk
#!/bin/awk –f
#this is a awk script
{if($3>=1000)print $1,$3}
chmod +x f2.awk
f2.awk –F: /etc/passwd

向awk指令碼傳遞引數

• 格式：
    awkfile var=value var2=value2… Inputfile
• 注意：在BEGIN過程中不可用。直到首行輸入完成以後，變數才可用。可以通過-v 引數，讓awk在執行BEGIN之前得到變數的值。命令列中每一個指定的變數都需要一個-v引數
  示例：

cat test.awk
#!/bin/awk –f
{if($3 >=min && $3<=max)print $1,$3}
chmod +x test.awk
test.awk -F: min=100 max=200 /etc/passwd