由於不想被認為三心二意不努力，所以最好這周把ahoi2014做完。。。
【故事背景】
宅男JYY非常喜歡玩RPG遊戲，比如仙劍，軒轅劍等等。不過JYY喜歡的並不是戰鬥場景，而是類似電視劇一般的充滿恩怨情仇的劇情。這些遊戲往往
都有很多的支線劇情，現在JYY想花費最少的時間看完所有的支線劇情。
【問題描述】
JYY現在所玩的RPG遊戲中，一共有N個劇情點，由1到N編號，第i個劇情點可以根據JYY的不同的選擇，而經過不同的支線劇情，前往Ki種不同的新的劇情點。當然如果為0，則說明i號劇情點是遊戲的一個結局了。
JYY觀看一個支線劇情需要一定的時間。JYY一開始處在1號劇情點，也就是遊戲的開始。顯然任何一個劇情點都是從1號劇情點可達的。此外，隨著遊戲的進行，劇情是不可逆的。所以遊戲保證從任意劇情點出發，都不能再回到這個劇情點。由於JYY過度使用修改器，導致遊戲的“存檔”和“讀檔”功能損壞了，
所以JYY要想回到之前的劇情點，唯一的方法就是退出當前遊戲，並開始新的遊戲，也就是回到1號劇情點。JYY可以在任何時刻退出遊戲並重新開始。不斷開始新的遊戲重複觀看已經看過的劇情是很痛苦，JYY希望花費最少的時間，看完所有不同的支線劇情。
Input

輸入一行包含一個正整數N。
接下來N行，第i行為i號劇情點的資訊；
第一個整數為，接下來個整數對，Bij和Tij，表示從劇情點i可以前往劇
情點，並且觀看這段支線劇情需要花費的時間。
Output

輸出一行包含一個整數，表示JYY看完所有支線劇情所需要的最少時間。

Sample Input

6

2 2 1 3 2

2 4 3 5 4

2 5 5 6 6

0

0

0
Sample Output

24
HINT

JYY需要重新開始3次遊戲，加上一開始的一次遊戲，4次遊戲的程序是

1->2->4，1->2->5，1->3->5和1->3->6。

對於100%的資料滿足N<=300,0<=Ki<=50,1<=Tij<=300,Sigma(Ki)<=5000

分析：每次從劇情點1開始，用最少的時間花費，走完所有的邊，每條邊至少走一次，所以是下界為1的費用流。
構圖：
先建立超級源點s（0），超級匯點t（n+1）
t–>s 花費為0，流量為INF
對於邊u–>v，花費為c，流量下界為1，上界為正無窮
改成：s–>v 花費為c，流量為1（表示下界為1）
u–>v 花費為c，流量為INF（表示可以走很多次）
對於每個點u
u–>t 花費為0，流量為u的出度（等價於每連一條u–>v的邊，增加一條u向t的邊流量為u–>v的下界1最後效果累加）
u–>1（原圖的源點） 花費為0，流量為INF（去掉這個源點）
注意的是迴圈中如果i=1，不要連1–>1的邊，否則有的資料會死迴圈。

program bzoj3876;
type point=record
      u,v,f,c,next,o:longint;
     end;
var edge:array[1..90000]of point;
    min,l,n,i,j,cost,key,u,c,s,t,top,tail,p:longint;
    flag:array[0..330]of boolean;
    head,dis,pre,re:array[0..330]of longint;
    b:array[1..3000000]of longint;

procedure add(u,v,f,c:longint);
begin
 l:=l+1;
 edge[l].v:=v;
 edge[l].u:=u;
 edge[l].f:=f;
 edge[l].c:=c;
 edge[l].next:=head[u];
 head[u]:=l;
 edge[l].o:=l+1;
 l:=l+1;
 edge[l].v:=u;
 edge[l].u:=v;
 edge[l].f:=0;
 edge[l].c:=-c;
 edge[l].next:=head[v];
 head[v]:=l;
 edge[l].o:=l-1;
end;
begin
 read(n);
 s:=0;t:=n+1;
 for i:=0 to n+1 do head[i]:=-1;
 for i:=1 to n do
  begin
   read(key);
   for j:=1 to key do
    begin
     read(u,c);
     add(s,u,1,c);
     add(i,u,maxlongint,c);
    end;
   add(i,t,key,0);
   if i<>1 then //**很重要，否則有的點會超時**
    add(i,1,maxlongint,0);
  end;
 add(t,s,maxlongint,0);
 //網路流
 while true do
  begin
   top:=1;tail:=1;
   b[1]:=0;
   for i:=0 to n+1 do dis[i]:=maxlongint;
   dis[0]:=0;
   fillchar(pre,sizeof(pre),0);
   pre[0]:=-1;
   fillchar(flag,sizeof(flag),true);
   flag[0]:=false;
   repeat
    p:=head[b[top]];
    while p<>-1 do
     begin
      if (edge[p].f>0)and(dis[b[top]]+edge[p].c<dis[edge[p].v]) then
       begin
        dis[edge[p].v]:=dis[b[top]]+edge[p].c;
        pre[edge[p].v]:=b[top];
        re[edge[p].v]:=p;
        if flag[edge[p].v] then
         begin
          flag[edge[p].v]:=false;
          tail:=tail+1;
          b[tail]:=edge[p].v;
         end;
       end;
      p:=edge[p].next;
     end;
    flag[b[top]]:=true;
    top:=top+1;
   until top>tail;
   if dis[n+1]=maxlongint then break;
   i:=n+1;
   min:=maxlongint;
   while pre[i]<>-1 do
    begin
     if min>edge[re[i]].f then min:=edge[re[i]].f;
     i:=pre[i];
    end;
   i:=n+1;
   while pre[i]<>-1 do
    begin
     edge[re[i]].f:=edge[re[i]].f-min;
     inc(edge[edge[re[i]].o].f,min);
     cost:=cost+min*edge[re[i]].c;
     i:=pre[i];
    end;
   end;
 writeln(cost);
end.