通過自定義Gradle外掛修改編譯後的class檔案

阿新 • • 發佈：2019-02-02

或許你會覺得沒有必要這樣做，可是有一種應用場景就是，為每個編譯後的class檔案新增一行程式碼。比如：在每個Java類的建構函式中加一句System.out.println("I Love HuaChao!");（PS:莫吐槽~，莫嘲笑~），如果你每次建立一個類的時候都手動加這麼一句話，先不談容易出錯，我們說說工作量。或許你覺得，你願意手動加，那我再跟你提新需求，我現在不要這句程式碼了，我要的是System.out.println("I Love MaYun!");你給我改去吧~，這時候你會不會想罵人~。忍住！我們上一篇《在AndroidStudio中自定義Gradle外掛》不是學過自定義Gradle外掛了嗎？我們為什麼要手動寫呢？直接通過Gradle外掛來幫我們幹！

1 認識Project物件

還記得上一篇文章中，我們自定義的外掛類是通過實現Plugin介面，並將org.gradle.api.Project作為模板引數嗎？org.gradle.api.Project的例項物件將作為引數傳給void apply(Project project)函式。接下來我看看Project類。

根據Gradle官網的介紹，Project是你與Gradle互動的主介面，通過Project你可以通過程式碼使用所有的Gradle特性，Project與build.gradle是一對一的關係。簡單來說，你想要通過程式碼使用Gradle，通過Project這個入口，就可以啦~

我們先看一個簡單的通過Project訪問的使用場景：Extension。可能你對Extension不熟悉，但是，我給你看一個你熟悉的內容：

android {
    compileSdkVersion 24
    buildToolsVersion "24.0.0"

    defaultConfig {
        applicationId "com.hc.hcplugin"
        minSdkVersion 15
        targetSdkVersion 24
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            minifyEnabled false 

            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

上面的這些你是不是很熟悉呢？你有沒有想過，上面的android{}、compileSdkVersion、defaultConfig {}等等這些設定是如何被Android的Gradle外掛讀取的呢？想必你已經想到了，沒錯，就是通過Extension。下面我們自定義一個Extension，感受一下~。首先，定義兩個Groovy類：Address和HCExtension.注意：為了避免引入外掛問題，以下程式碼全部放入buildsrc模組的build.gradle檔案中:

class Address{
    String province=null
    String city=null
}
class HCExtension{
    String myName = null;

}

再新建一個Plugin(同樣也放入build.gradle中)：

class TestExtensionPlugin implements Plugin<Project> {

    @Override
    void apply(Project project) {

        project.extensions.create('hc', HCExtension);
        project.extensions.create('address', Address);


        project.task('readExtension') << {
            def address=project['address']

            println project['hc'].myName
            println address.province+" "+address.city

        }
    }
}

接下來就是把你的配置放進去啦(同樣也放入build.gradle中)：

apply plugin: TestExtensionPlugin

hc {
    address{
       province "HuBei"
        city "WuHan"
    }

    myName "huachao"

}

稍微解釋一下，apply plugin: TestExtensionPlugin這一行會導致直接執行TestExtensionPlugin類的apply方法。所以，hc{}這個塊必須放在apply plugin: TestExtensionPlugin之後，因為在沒有執行project.extensions.create('hc', HCExtension);之前，使用hc{}會報錯！address{}也是同理。另外，補充一下：project.extensions相當於project.getExtensions()即返回的是ExtensionContainer物件，而ExtensionContainer物件的create方法就是把hc{}與HCExtension對應起來。其他通過project.的方式也是同樣的道理。再看看project.task('readExtension')，這是建立一個task。相當於在build.gradle檔案中的task xxx <<{}只不過這裡是通過程式碼的方式動態建立.

此時你的buildsrc模組中的build.gradle檔案應該如下：

apply plugin: 'groovy'

dependencies {
    compile gradleApi()//gradle sdk
    compile localGroovy()//groovy sdk
    compile 'com.android.tools.build:gradle:2.1.0'
}

repositories {
    jcenter()
}
class Address{
    String province=null
    String city=null
}
class HCExtension{
    String myName = null;

}

class TestExtensionPlugin implements Plugin<Project> {

    @Override
    void apply(Project project) {

        project.extensions.create('hc', HCExtension);
        project.extensions.create('address', Address);


        project.task('readExtension') << {
            def address=project['address']

            println project['hc'].myName
            println address.province+" "+address.city

        }
    }
}

apply plugin: TestExtensionPlugin

hc {
    address{
       province "HuBei"
        city "WuHan"
    }

    myName "huachao"

}

點選buildsrc模組中的readExtension如下圖：

readExtension

看看列印資訊

···
:buildsrc:readExtension
huachao
HuBei WuHan

···

2 修改編譯後的class

接下來回到我們的主題，我們需要修改class檔案，首先我們得知道什麼時候編譯完成，並且我們要趕在class檔案被轉化為dex檔案之前去修改。從1.5.0-beta1開始，android的gradle外掛引入了com.android.build.api.transform.Transform，可以點選 http://tools.android.com/tech-docs/new-build-system/transform-api 檢視相關內容。Transform每次都是將一個輸入進行處理，然後將處理結果輸出，而輸出的結果將會作為另一個Transform的輸入，過程如下：

Transform處理過程

注意，輸出地址不是由你任意指定的。而是根據輸入的內容、作用範圍等由TransformOutputProvider生成，比如，你要獲取輸出路徑：

 String dest = outputProvider.getContentLocation(directoryInput.name,
                        directoryInput.contentTypes, directoryInput.scopes, Format.DIRECTORY)

Transform是一個抽象類，我們先自定義一個Transform，如下：

package com.hc.plugin

import com.android.build.api.transform.*
import com.android.build.gradle.internal.pipeline.TransformManager
import org.apache.commons.codec.digest.DigestUtils
import org.apache.commons.io.FileUtils
import org.gradle.api.Project

/**
 * Created by HuaChao on 2016/7/4.
 */
public class MyTransform extends Transform {

    Project project

    // 建構函式，我們將Project儲存下來備用
    public MyTransform(Project project) {
        this.project = project
    }

    // 設定我們自定義的Transform對應的Task名稱
    // 類似：TransformClassesWithPreDexForXXX
    @Override
    String getName() {
        return "MyTrans"
    }

    // 指定輸入的型別，通過這裡的設定，可以指定我們要處理的檔案型別
    //這樣確保其他型別的檔案不會傳入
    @Override
    Set<QualifiedContent.ContentType> getInputTypes() {
        return TransformManager.CONTENT_CLASS
    }

    // 指定Transform的作用範圍
    @Override
    Set<QualifiedContent.Scope> getScopes() {
        return TransformManager.SCOPE_FULL_PROJECT
    }

    @Override
    boolean isIncremental() {
        return false
    }

//具體的處理
    @Override
    void transform(Context context, Collection<TransformInput> inputs,
                   Collection<TransformInput> referencedInputs,
                   TransformOutputProvider outputProvider, boolean isIncremental)
            throws IOException, TransformException, InterruptedException {

    }
}

看到函式transform,我們還沒有具體實現這個函式。這個函式就是具體如何處理輸入和輸出。可以執行一下看看，注意，這裡的執行時直接編譯執行我們的apk，而不是像之前那樣直接rebuild，因為rebuild並沒有執行到編譯這一步。由於我們沒有實現transform這個函式，導致沒有輸出！使得整個過程中斷了！最終導致apk執行時找不到MainActivity，所以會報錯。接下來我們去實現以下這個函式，我們啥也不幹，就是把輸入內容寫入到作為輸出內容，不做任何處理，（下面程式碼參考自這裡）：

@Override
void transform(Context context, Collection<TransformInput> inputs,
               Collection<TransformInput> referencedInputs,
               TransformOutputProvider outputProvider, boolean isIncremental)
        throws IOException, TransformException, InterruptedException {
    // Transform的inputs有兩種型別，一種是目錄，一種是jar包，要分開遍歷
    inputs.each {TransformInput input ->
        //對型別為“資料夾”的input進行遍歷
            input.directoryInputs.each {DirectoryInput directoryInput->
             //資料夾裡面包含的是我們手寫的類以及R.class、BuildConfig.class以及R$XXX.class等


            // 獲取output目錄
            def dest = outputProvider.getContentLocation(directoryInput.name,
                    directoryInput.contentTypes, directoryInput.scopes, 
                    Format.DIRECTORY)

            // 將input的目錄複製到output指定目錄
            FileUtils.copyDirectory(directoryInput.file, dest)
        }
    //對型別為jar檔案的input進行遍歷
        input.jarInputs.each {JarInput jarInput->

            //jar檔案一般是第三方依賴庫jar檔案

            // 重新命名輸出檔案（同目錄copyFile會衝突）
            def jarName = jarInput.name
            def md5Name = DigestUtils.md5Hex(jarInput.file.getAbsolutePath())
            if(jarName.endsWith(".jar")) {
                jarName = jarName.substring(0,jarName.length()-4)
            }
            //生成輸出路徑
            def dest = outputProvider.getContentLocation(jarName+md5Name, 
                         jarInput.contentTypes, jarInput.scopes, Format.JAR)
            //將輸入內容複製到輸出
            FileUtils.copyFile(jarInput.file, dest)
        }
    }
}

注意input的型別，分為”資料夾”和“jar檔案”，”資料夾”裡面的就是我們寫的類對應的class檔案，jar檔案一般為第三方庫。此時，能成功執行，但是我們還沒有注入程式碼呢~，下面我們看看如何注入程式碼~

3 Javassist

要修改class位元組碼，我們要是自己手動改二進位制檔案，有點困難，好在有Javassist這個庫，可以讓我們直接修改編譯後的class二進位制程式碼。關於Javassist的使用，這裡不介紹，可以自行搜尋。要使用到Javassist，我們得在buildsrc模組下的build.gradle新增依賴包：

compile 'org.javassist:javassist:3.20.0-GA'

使用Javassist也很簡單，首先拿到ClassPool物件，通過ClassPool獲取已經編譯好的類，如：

ClassPool pool = ClassPool.getDefault();
CtClass cc = pool.get("com.hc.MyClass");
cc.setSuperclass(pool.get("com.hc.ParentClass"));
cc.writeFile();

上面程式碼就實現了修改MyClass類的父類為ParentClass.

要獲取位元組碼以及載入為Class物件，如下：

byte[] b = cc.toBytecode();
Class clazz = cc.toClass();

前面提到，我們自己建立的Java類編譯後是放入到資料夾裡面的，因此，我們只需針對這個資料夾裡面的class檔案進行修改即可，新建一個Groovy類：

package com.hc.plugin

import javassist.ClassPool
import javassist.CtClass
import javassist.CtConstructor
public class MyInject {

    private static ClassPool pool = ClassPool.getDefault()
    private static String injectStr = "System.out.println(\"I Love HuaChao\" ); ";

    public static void injectDir(String path, String packageName) {
        pool.appendClassPath(path)
        File dir = new File(path)
        if (dir.isDirectory()) {
            dir.eachFileRecurse { File file ->

                String filePath = file.absolutePath
                //確保當前檔案是class檔案，並且不是系統自動生成的class檔案
                if (filePath.endsWith(".class")
                        && !filePath.contains('R$')
                        && !filePath.contains('R.class')
                        && !filePath.contains("BuildConfig.class")) {
                    // 判斷當前目錄是否是在我們的應用包裡面
                    int index = filePath.indexOf(packageName);
                    boolean isMyPackage = index != -1;
                    if (isMyPackage) {
                        int end = filePath.length() - 6 // .class = 6
                        String className = filePath.substring(index, end)
                           .replace('\\', '.').replace('/', '.')
                        //開始修改class檔案
                        CtClass c = pool.getCtClass(className)

                        if (c.isFrozen()) {
                            c.defrost()
                        }

                        CtConstructor[] cts = c.getDeclaredConstructors() 
                        if (cts == null || cts.length == 0) {
                            //手動建立一個建構函式
                            CtConstructor constructor = new CtConstructor(new CtClass[0], c)
                            constructor.insertBeforeBody(injectStr)
                            c.addConstructor(constructor)
                        } else {
                            cts[0].insertBeforeBody(injectStr)
                        }
                        c.writeFile(path)
                        c.detach()
                    }
                }
            }
        }
    }


}

然後就是在 transform函式中，針對“資料夾”裡面的class進行注入，而jar檔案型別的input依然不做處理。transform函式如下：

 @Override
void transform(Context context, Collection<TransformInput> inputs,
               Collection<TransformInput> referencedInputs,
               TransformOutputProvider outputProvider, boolean isIncremental)
        throws IOException, TransformException, InterruptedException {
    // Transform的inputs有兩種型別，一種是目錄，一種是jar包，要分開遍歷
    inputs.each { TransformInput input ->
        //對型別為“資料夾”的input進行遍歷
        input.directoryInputs.each { DirectoryInput directoryInput ->
            //資料夾裡面包含的是我們手寫的類以及R.class、BuildConfig.class以及R$XXX.class等
            MyInject.injectDir(directoryInput.file.absolutePath,"com\\hc\\hcplugin")
            // 獲取output目錄
            def dest = outputProvider.getContentLocation(directoryInput.name,
                    directoryInput.contentTypes, directoryInput.scopes,
                    Format.DIRECTORY)

            // 將input的目錄複製到output指定目錄
            FileUtils.copyDirectory(directoryInput.file, dest)
        }
        //對型別為jar檔案的input進行遍歷
        input.jarInputs.each { JarInput jarInput ->

            //jar檔案一般是第三方依賴庫jar檔案

            // 重新命名輸出檔案（同目錄copyFile會衝突）
            def jarName = jarInput.name
            def md5Name = DigestUtils.md5Hex(jarInput.file.getAbsolutePath())
            if (jarName.endsWith(".jar")) {
                jarName = jarName.substring(0, jarName.length() - 4)
            }
            //生成輸出路徑
            def dest = outputProvider.getContentLocation(jarName + md5Name,
                    jarInput.contentTypes, jarInput.scopes, Format.JAR)
            //將輸入內容複製到輸出
            FileUtils.copyFile(jarInput.file, dest)
        }
    }
}

大功告成，接下來測試一下，在app模組中，新建一個Test類，在MainActivity中呼叫new Test()；

Test.java

package com.hc.hcplugin;

/**
 * Created by HuaChao on 2016/7/4.
 */
public class Test {
}

MainActivity.java

package com.hc.hcplugin;

import android.os.Bundle;
import android.support.v7.app.AppCompatActivity;
import android.util.Log;

public class MainActivity extends AppCompatActivity {

    @Override
    protected void onCreate(Bundle savedInstanceState) {
        super.onCreate(savedInstanceState);
        Log.e("--->", "===================");
        new Test();
        Log.e("--->", "===================");
    }

}

執行結果如下：

執行結果

第一個列印是MainActivity的建構函式列印的，第二個是Test的建構函式列印的。看到這裡，或許你想說，這有什麼用啊？難道搞半天就為了列印這麼一句話？其實，真的很有用，如果你看過關於熱補丁相關內容，你就知道，還真的需要對每個類加上System.out.println(xxx)。不信你看：

通過自定義Gradle外掛修改編譯後的class檔案

1 認識Project物件

2 修改編譯後的class

3 Javassist

通過自定義Gradle外掛修改編譯後的class檔案

安卓開發通過自定義Gradle外掛實現自動化埋點

自定義 Gradle 外掛學習記錄

自定義Gradle外掛（一）

【AndroidStudio】自定義gradle外掛：無需釋出，僅用於當前專案

自定義gradle外掛從入門到放棄

Android如何自定義Gradle外掛

自定義Gradle外掛（二）

使用AndroidStudio自定義Gradle外掛

自定義Gradle外掛和AspectJ實戰

為Android Studio編寫自定義Gradle外掛的教程

自定義TexturePacker外掛匯出自己的plist檔案

zabbix3.0.4通過自定義shell指令碼新增對關鍵日誌檔案的監控

android：如何通過自定義工程模板讓新建的工程都默認支持lambda表達式

玩轉angularJs——通過自定義ng-model，不僅僅只是input可以有雙向綁定

spring security使用自定義登錄界面後，不能返回到之前的請求界面的問題

Asp.Net Core 通過自定義中間件防止圖片盜鏈的實例（轉）

通過自定義註解與aop統一存儲操作記錄

通過自定義 @CurrentUser 獲取當前登錄用戶

excel2013如何通過自定義排序方式來進行排序

通過自定義Gradle外掛修改編譯後的class檔案

1 認識Project物件

2 修改編譯後的class

3 Javassist

相關推薦