;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
; 檔名: FullScr.asm
; 作  者：Purple Endurer（[email protected]）
; 功　能: 演示程式在視窗模式和全屏模式間切換
; Date         log

;-------------------------------------------------
;2006-07-03    利用SetTimer()和GetAsyncKeyState()增加Esc鍵
;              作為從全屏切換回視窗模式的熱鍵!
;              在全屏模式下，視窗接收不到WM_KEYDOWN訊息!
;2006-06-30    建立！可在全屏和視窗模式間切換!
;              在一個國外MASM32論壇上，看到有網友討論如何用
;              MASM32編寫全屏視窗程式。於是在
;              用VC 6.0寫flash播放器——5、全屏播放
;              (http://blog.csdn.net/purpleendurer/archive/2005/12/07/545717.aspx)
;              的程式碼基礎上改寫。
;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
.386
.model flat, stdcall
option casemap:none
include /masm32/include/windows.inc

include /masm32/include/user32.inc
include /masm32/include/gdi32.inc
include /masm32/include/kernel32.inc
include /masm32/include/shell32.inc

includelib /masm32/lib/user32.lib
includelib /masm32/lib/gdi32.lib
includelib /masm32/lib/kernel32.lib
includelib /masm32/lib/shell32.lib

WinMain proto :DWORD, :DWORD, :DWORD, :DWORD
SetFullScr PROTO :HWND
SetWinMode PROTO :HWND
SwitchMode PROTO :HWND


m_m2m MACRO d1, d2
    push d2
    pop d1
ENDM

;.const
c_ButtonID equ 1
c_TimerID equ 1

.data
g_szWinClsName db "DemoWinClass", 0
g_szAppName  db "全屏顯示演示程式 by PurpleEndurer", 0
g_szBtnClsName db "button", 0
g_szFullScr db "全屏顯示!", 0
g_szSetWinMode db "視窗顯示! 按Esc鍵返回!", 0
g_szFailWinMode db "設定為視窗模式失敗！", 0
g_szFailFullScrMode db "設定為全屏模式失敗！", 0

g_bIsFull dword FALSE

.data?
g_hInstance HINSTANCE ?
g_hwndButton HANDLE ?
g_stOriginPos WINDOWPLACEMENT <>

.code
start:
    invoke GetModuleHandle, NULL
    mov    g_hInstance, eax
    invoke WinMain, g_hInstance, NULL, NULL, SW_SHOWDEFAULT
    invoke ExitProcess, eax

WinMain proc hInst:HINSTANCE, hPrevInst:HINSTANCE, CmdLine:LPSTR, CmdShow:DWORD
    LOCAL wc:WNDCLASSEX
    LOCAL msg:MSG
    LOCAL hwnd:HWND
    m_m2m   wc.cbSize, SIZEOF WNDCLASSEX
    m_m2m   wc.style, CS_HREDRAW or CS_VREDRAW
    m_m2m   wc.lpfnWndProc, OFFSET WndProc
    m_m2m   wc.cbClsExtra, NULL
    m_m2m   wc.cbWndExtra, NULL
    m_m2m   wc.hInstance, g_hInstance
    m_m2m   wc.hbrBackground, COLOR_WINDOW+1
    m_m2m   wc.lpszMenuName, NULL
    m_m2m   wc.lpszClassName, OFFSET g_szWinClsName
    invoke LoadIcon, NULL, IDI_APPLICATION
    mov   wc.hIcon, eax
    mov   wc.hIconSm, eax
    invoke LoadCursor, NULL, IDC_ARROW
    mov   wc.hCursor, eax
    invoke RegisterClassEx, addr wc
    INVOKE CreateWindowEx, NULL, ADDR g_szWinClsName, ADDR g_szAppName, /
           WS_OVERLAPPEDWINDOW, CW_USEDEFAULT, /
           CW_USEDEFAULT, CW_USEDEFAULT, CW_USEDEFAULT, NULL, NULL, /
           hInst, NULL
    mov   hwnd, eax
    invoke ShowWindow, hwnd, SW_SHOWNORMAL
    invoke UpdateWindow, hwnd
    .WHILE TRUE
        invoke GetMessage, ADDR msg, NULL, 0, 0
        .BREAK .IF (!eax)
        invoke TranslateMessage, ADDR msg
        invoke DispatchMessage, ADDR msg
    .ENDW
    mov eax, msg.wParam
    ret
WinMain endp


WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
    .IF uMsg==WM_DESTROY
         invoke PostQuitMessage, NULL

    .ELSEIF uMsg==WM_CREATE
        ;建立按鈕
        invoke CreateWindowEx, NULL, ADDR g_szBtnClsName, ADDR g_szFullScr, /
                        WS_CHILD or WS_VISIBLE or BS_DEFPUSHBUTTON,/
                        25, 25, 560, 50, hWnd, c_ButtonID, g_hInstance, NULL
        mov  g_hwndButton, eax


    .ELSEIF uMsg==WM_COMMAND
        mov eax, wParam
        .IF lParam!=0
            .IF ax==c_ButtonID
                shr eax, 16
                .IF ax==BN_CLICKED
                        invoke SwitchMode, hWnd
                .ENDIF
            .ENDIF
        .ENDIF

    .ELSEIF uMsg==WM_TIMER
        invoke GetAsyncKeyState, VK_ESCAPE;Esc鍵
        test eax, 08000h
        jz @F
          invoke SwitchMode, hWnd

        @@:
    .ELSE
        invoke DefWindowProc, hWnd, uMsg, wParam, lParam
        ret
    .ENDIF
    xor eax, eax
    ret
WndProc endp


SwitchMode proc hWnd: HWND
    .if g_bIsFull==TRUE
        invoke KillTimer, hWnd, c_TimerID   ;清除定時器
        invoke SetWinMode, hWnd ;設定為視窗模式
        .IF eax==0
            invoke MessageBox, hWnd, ADDR g_szFailWinMode, ADDR g_szAppName, MB_ICONERROR
            ret
        .ENDIF
        m_m2m g_bIsFull, FALSE

        invoke SetWindowText, g_hwndButton, ADDR g_szFullScr    ;修改按鈕的文字
    .else
        invoke SetFullScr, hWnd ;設定為全屏模式
        .IF eax==0
            invoke MessageBox, hWnd, ADDR g_szFailFullScrMode, ADDR g_szAppName, MB_ICONERROR
            ret
        .ENDIF
        m_m2m g_bIsFull, TRUE

        invoke SetTimer, hWnd, c_TimerID, 100, NULL ;啟動定時器，以捕獲Esc鍵
        invoke SetWindowText, g_hwndButton, ADDR g_szSetWinMode ;修改按鈕的文字
    .endif

    ret
SwitchMode endp


;/////////////////////////////////////////////////////////////////////////
;功能：將hWnd指定的視窗切換到全屏模式
; 返回值:若失敗，eax=0；若成功，eax !=0
;/////////////////////////////////////////////////////////////////////////
SetFullScr PROC hWnd: HWND
    LOCAL hDC: HWND
    LOCAL dwHorzres, dwVertres: DWORD
    invoke GetWindowPlacement, hWnd, ADDR g_stOriginPos
    invoke GetWindowLong, hWnd, GWL_STYLE
    push edi
    mov edi, WS_CAPTION
    not edi
    and eax, edi
    push edi
    invoke SetWindowLong, hWnd, GWL_STYLE, eax;//去掉標題欄
    invoke GetDC, hWnd
    mov hDC, eax
    invoke GetDeviceCaps, hDC, HORZRES
    mov dwHorzres, eax
    invoke GetDeviceCaps, hDC, VERTRES
    mov dwVertres, eax
    xor eax, eax
    invoke MoveWindow, hWnd, eax, eax, dwHorzres, dwVertres, TRUE
    xor eax, eax
    invoke SetWindowPos, hWnd, HWND_TOPMOST, eax, eax, dwHorzres, dwVertres, SWP_SHOWWINDOW ;全屏顯示
    ret
SetFullScr ENDP


;/////////////////////////////////////////////////////////////////////////
; 功能：將hWnd指定的視窗切換到視窗模式
; 返回值:若失敗，eax=0；若成功，eax !=0
;/////////////////////////////////////////////////////////////////////////
SetWinMode PROC hWnd: HWND
    invoke GetWindowLong, hWnd, GWL_STYLE
    or eax, WS_CAPTION
    invoke SetWindowLong, hWnd, GWL_STYLE, eax  ;//恢復標題欄
    invoke ShowWindow, hWnd, SW_HIDE
    invoke SetWindowPlacement, hWnd, ADDR g_stOriginPos
    ret
SetWinMode ENDP

end start