//*******************************************code***********************************************************
//程式碼在PB9，window7 64bit 測試通過，對程式碼有疑問的可以傳送郵件進行諮詢[email protected]
//-----------------------------------------of_unicode_utf8-----------------------------------------------------------------
// 函式: n_cst_utilities::of_unicode_utf8()

//--------------------------------------------------------------------
// 描述: Unicode編碼轉換為UTF8編碼
//--------------------------------------------------------------------
// 引數: 
// reference blob ablb_unicode 
// reference blob ablb_UTF8    
//--------------------------------------------------------------------
// 返回值:  long 轉換後的位元組數

//--------------------------------------------------------------------
// 作者: xiedaolin 日期: 2012.12.13
//--------------------------------------------------------------------
// 修改歷史: 
// 
//====================================================================
long ll_Unicode_Size, ll_UTF8_Size

ll_Unicode_Size = len(ablb_unicode)

if ll_Unicode_Size < 1 then
return 0
end if
ll_Unicode_Size = ll_Unicode_Size/2
//獲取轉換需要的位元組數
ll_UTF8_Size = WideCharToMultiByte(CP_UTF8, 0, ablb_unicode, ll_Unicode_Size, ablb_utf8, 0, 0, 0)
if ll_UTF8_Size < 1 then
return 0
end if

ablb_utf8 = Blob(space(ll_UTF8_Size))
ll_UTF8_Size = WideCharToMultiByte(CP_UTF8, 0, ablb_unicode, ll_Unicode_Size, ablb_utf8, ll_UTF8_Size, 0, 0)
if ll_UTF8_Size < 1 then
return 0
end if
return ll_UTF8_Size

//------------------------------------------------of_utf8_unicode----------------------------------------------------------
//====================================================================
// 函式: n_cst_utilities::of_utf8_unicode()
//--------------------------------------------------------------------
// 描述: UTF-8 編碼轉換為 Unicode 編碼格式
//--------------------------------------------------------------------
// 引數: 
// reference blob ablb_UTF8    
// reference blob ablb_Unicode 
//--------------------------------------------------------------------
// 返回值:  integer 多少位元組被轉換
//--------------------------------------------------------------------
// 作者: xiedaolin 日期: 2012.12.13
//--------------------------------------------------------------------
// 修改歷史: 
// 
//====================================================================

long ll_UTF8_Size
long ll_Unicode_Byte_Size, ll_Unicode_WChar_Size
blob lblb_null

setnull(lblb_null)


ll_UTF8_Size = len(ablb_UTF8)

//獲取轉換後需要的記憶體空間
ll_Unicode_WChar_Size = MultiByteToWideChar(CP_UTF8, 0, ablb_UTF8, ll_UTF8_Size, lblb_null, 0)
if ll_Unicode_WChar_Size < 1 then
return 0
end if

ll_Unicode_Byte_Size = ll_Unicode_WChar_Size * 2
ablb_Unicode = blob(space(ll_Unicode_Byte_Size))

//開始轉換
ll_Unicode_WChar_Size = MultiByteToWideChar(CP_UTF8, 0, ablb_UTF8, ll_UTF8_Size, ablb_Unicode, ll_Unicode_Byte_Size)
if ll_Unicode_WChar_Size < 1 then
return 0
end if

return ll_Unicode_Byte_Size

//-----------------------------------------------of_ANSI_Unicode-----------------------------------------------------------
//====================================================================
// 函式: n_cst_utilities::of_ANSI_Unicode()
//--------------------------------------------------------------------
// 描述: ANSI 編碼轉換為 Unicode 編碼格式
//--------------------------------------------------------------------
// 引數: 
// value     string as_ANSI      
// reference blob   rblb_Unicode 
//--------------------------------------------------------------------
// 返回值:  long 多少位元組被轉換
//--------------------------------------------------------------------
// 作者: xiedaolin 日期: 2012.12.13
//--------------------------------------------------------------------
// 修改歷史: 
// 
//====================================================================

long ll_ANSI_Size
long ll_Unicode_Byte_Size, ll_Unicode_WChar_Size
blob lblb_ANSI
blob lblb_null

setnull(lblb_null)

lblb_ANSI = BLOB(as_ansi)
ll_ANSI_Size = len(lblb_ANSI)

//獲取轉換後需要的記憶體空間
ll_Unicode_WChar_Size = MultiByteToWideChar(CP_ACP, 0, lblb_ANSI, ll_ANSI_Size, lblb_null, 0)
if ll_Unicode_WChar_Size < 1 then
return 0
end if

ll_Unicode_Byte_Size = ll_Unicode_WChar_Size * 2
rblb_unicode = blob(space(ll_Unicode_Byte_Size))

//開始轉換
ll_Unicode_WChar_Size = MultiByteToWideChar(CP_ACP, 0, lblb_ANSI, ll_ANSI_Size, rblb_unicode, ll_Unicode_Byte_Size)
if ll_Unicode_WChar_Size < 1 then
return 0
end if

return ll_Unicode_Byte_Size

//---------------------------------------------------of_ANSI_UTF8-------------------------------------------------------
//====================================================================
// 函式: n_cst_utilities::of_ANSI_UTF8()
//--------------------------------------------------------------------
// 描述: ANSI 編碼 轉換為 UTF8 編碼
//--------------------------------------------------------------------
// 引數: 
// reference string as_ANSI   
// reference blob   ablb_UTF8 
//--------------------------------------------------------------------
// 返回值:  long 轉換後的位元組數
//--------------------------------------------------------------------
// 作者: xiedaolin 日期: 2012.12.13
//--------------------------------------------------------------------
// 修改歷史: 
// 
//====================================================================

blob lblb_Unicode
long ll_Unicode_Size, ll_UTF8_Size

if isnull(as_ansi) or len(as_ansi) = 0 then
return 0
end if

lblb_Unicode   = ToUnicode(as_ansi)
ll_Unicode_Size = len(lblb_Unicode)

of_ANSI_Unicode(as_ansi, lblb_Unicode)
ll_Unicode_Size = len(lblb_Unicode)

if ll_Unicode_Size < 1 then
return 0
end if
ll_UTF8_Size = of_unicode_utf8( lblb_Unicode, ablb_utf8)
return ll_UTF8_Size

//------------------------------------------------of_UTF8_ANSI----------------------------------------------------------
//====================================================================
// 函式: n_cst_utilities::of_UTF8_ANSI()
//--------------------------------------------------------------------
// 描述: 
//--------------------------------------------------------------------
// 引數: 
// reference blob   ablb_UTF8 
// reference string as_ANSI   
//--------------------------------------------------------------------
// 返回值:  integer
//--------------------------------------------------------------------
// 作者: xiedaolin 日期: 2012.12.13
//--------------------------------------------------------------------
// 修改歷史: 
// 
//====================================================================

blob lblb_Unicode, lblb_ANSI
long ll_Unicode_Size, ll_UTF8_Size

ll_Unicode_Size = of_UTF8_Unicode(ablb_utf8, lblb_Unicode)
if ll_Unicode_Size < 1 then 
return 0
end if
as_ansi = FromUnicode(lblb_Unicode)
return len(as_ansi)

//----------------------------------------------------------------------------------------------------------
//----------------------------------------------------------------------------------------------------------
//----------------------------------------------------------------------------------------------------------
//----------------------------------------------------------------------------------------------------------