本文簡述通過maven和gradle快速構建的Flink工程。建議安裝好Flink以後構建自己的Flink專案，安裝與示例執行請檢視：Flink快速入門--安裝與示例執行.

在安裝好Flink以後，只要快速構建Flink工程，並完成相關程式碼開發，就可以輕鬆入手Flink。

構建工具

Flink專案可以使用不同的構建工具進行構建。為了能夠快速入門，Flink 為以下構建工具提供了專案模版：

• Maven
• Gradle

這些模版可以幫助你搭建專案結構並建立初始構建檔案。

Maven

環境要求

唯一的要求是使用 Maven 3.0.4 （或更高版本）和安裝 Java 8.x。

建立專案

使用以下命令之一來 建立專案：

使用Maven archetypes

 $ mvn archetype:generate                               \
      -DarchetypeGroupId=org.apache.flink              \
      -DarchetypeArtifactId=flink-quickstart-java      \
      -DarchetypeVersion=1.9.0

執行quickstart指令碼

 curl https://flink.apache.org/q/quickstart.sh | bash -s 1.9.0

下載完成後，檢視專案目錄結構：

tree quickstart/
quickstart/
├── pom.xml
└── src
    └── main
        ├── java
        │   └── org
        │       └── myorg
        │           └── quickstart
        │               ├── BatchJob.java
        │               └── StreamingJob.java
        └── resources
            └── log4j.properties
 

示例專案是一個 Maven project，它包含了兩個類：StreamingJob 和 BatchJob 分別是 DataStream and DataSet 程式的基礎骨架程式。
main 方法是程式的入口，既可用於IDE測試/執行，也可用於部署。

我們建議你將 此專案匯入IDE 來開發和測試它。
IntelliJ IDEA 支援 Maven 專案開箱即用。如果你使用的是 Eclipse，使用m2e 外掛 可以
匯入 Maven 專案。
一些 Eclipse 捆綁包預設包含該外掛，其他情況需要你手動安裝。

請注意：對 Flink 來說，預設的 JVM 堆記憶體可能太小，你應當手動增加堆記憶體。
在 Eclipse 中，選擇 Run Configurations -> Arguments 並在 VM Arguments 對應的輸入框中寫入：-Xmx800m。
在 IntelliJ IDEA 中，推薦從選單 Help | Edit Custom VM Options 來修改 JVM 選項。

構建專案

如果你想要 構建/打包你的專案，請在專案目錄下執行 ‘mvn clean package’ 命令。命令執行後，你將 找到一個JAR檔案，裡面包含了你的應用程式，以及已作為依賴項新增到應用程式的聯結器和庫：target/-.jar。

注意： 如果你使用其他類而不是 StreamingJob 作為應用程式的主類/入口，我們建議你相應地修改 pom.xml 檔案中的 mainClass 配置。這樣，Flink 可以從 JAR 檔案執行應用程式，而無需另外指定主類。

Gradle

環境要求

唯一的要求是使用 Gradle 3.x (或更高版本) 和安裝 Java 8.x 。

建立專案

使用以下命令之一來 建立專案：

Gradle示例：

build.gradle

buildscript {
    repositories {
        jcenter() // this applies only to the Gradle 'Shadow' plugin
    }
    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:2.0.4'
    }
}

plugins {
    id 'java'
    id 'application'
    // shadow plugin to produce fat JARs
    id 'com.github.johnrengelman.shadow' version '2.0.4'
}


// artifact properties
group = 'org.myorg.quickstart'
version = '0.1-SNAPSHOT'
mainClassName = 'org.myorg.quickstart.StreamingJob'
description = """Flink Quickstart Job"""

ext {
    javaVersion = '1.8'
    flinkVersion = '1.9.0'
    scalaBinaryVersion = '2.11'
    slf4jVersion = '1.7.7'
    log4jVersion = '1.2.17'
}


sourceCompatibility = javaVersion
targetCompatibility = javaVersion
tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

applicationDefaultJvmArgs = ["-Dlog4j.configuration=log4j.properties"]

task wrapper(type: Wrapper) {
    gradleVersion = '3.1'
}

// declare where to find the dependencies of your project
repositories {
    mavenCentral()
    maven { url "https://repository.apache.org/content/repositories/snapshots/" }
}

// 注意：我們不能使用 "compileOnly" 或者 "shadow" 配置，這會使我們無法在 IDE 中或通過使用 "gradle run" 命令執行程式碼。
// 我們也不能從 shadowJar 中排除傳遞依賴（請檢視 https://github.com/johnrengelman/shadow/issues/159)。
// -> 顯式定義我們想要包含在 "flinkShadowJar" 配置中的類庫!
configurations {
    flinkShadowJar // dependencies which go into the shadowJar

    // 總是排除這些依賴（也來自傳遞依賴），因為 Flink 會提供這些依賴。
    flinkShadowJar.exclude group: 'org.apache.flink', module: 'force-shading'
    flinkShadowJar.exclude group: 'com.google.code.findbugs', module: 'jsr305'
    flinkShadowJar.exclude group: 'org.slf4j'
    flinkShadowJar.exclude group: 'log4j'
}

// declare the dependencies for your production and test code
dependencies {
    // --------------------------------------------------------------
    // 編譯時依賴不應該包含在 shadow jar 中，
    // 這些依賴會在 Flink 的 lib 目錄中提供。
    // --------------------------------------------------------------
    compile "org.apache.flink:flink-java:${flinkVersion}"
    compile "org.apache.flink:flink-streaming-java_${scalaBinaryVersion}:${flinkVersion}"

    // --------------------------------------------------------------
    // 應該包含在 shadow jar 中的依賴，例如：聯結器。
    // 它們必須在 flinkShadowJar 的配置中！
    // --------------------------------------------------------------
    //flinkShadowJar "org.apache.flink:flink-connector-kafka-0.11_${scalaBinaryVersion}:${flinkVersion}"

    compile "log4j:log4j:${log4jVersion}"
    compile "org.slf4j:slf4j-log4j12:${slf4jVersion}"

    // Add test dependencies here.
    // testCompile "junit:junit:4.12"
}

// make compileOnly dependencies available for tests:
sourceSets {
    main.compileClasspath += configurations.flinkShadowJar
    main.runtimeClasspath += configurations.flinkShadowJar

    test.compileClasspath += configurations.flinkShadowJar
    test.runtimeClasspath += configurations.flinkShadowJar

    javadoc.classpath += configurations.flinkShadowJar
}

run.classpath = sourceSets.main.runtimeClasspath

jar {
    manifest {
        attributes 'Built-By': System.getProperty('user.name'),
                'Build-Jdk': System.getProperty('java.version')
    }
}

shadowJar {
    configurations = [project.configurations.flinkShadowJar]
}

setting.gradle

rootProject.name = 'quickstart'

或者執行quickstart指令碼

    bash -c "$(curl https://flink.apache.org/q/gradle-quickstart.sh)" -- 1.9.0 2.11

檢視目錄結構：

tree quickstart/
quickstart/
├── README
├── build.gradle
├── settings.gradle
└── src
    └── main
        ├── java
        │   └── org
        │       └── myorg
        │           └── quickstart
        │               ├── BatchJob.java
        │               └── StreamingJob.java
        └── resources
            └── log4j.properties

示例專案是一個 Gradle 專案，它包含了兩個類：StreamingJob 和 BatchJob 是 DataStream 和 DataSet 程式的基礎骨架程式。main 方法是程式的入口，即可用於IDE測試/執行，也可用於部署。

我們建議你將 此專案匯入你的 IDE 來開發和測試它。IntelliJ IDEA 在安裝 Gradle 外掛後支援 Gradle 專案。Eclipse 則通過 Eclipse Buildship 外掛支援 Gradle 專案（鑑於 shadow 外掛對 Gradle 版本有要求，請確保在匯入嚮導的最後一步指定 Gradle 版本 >= 3.0）。你也可以使用 Gradle’s IDE integration 從 Gradle 建立專案檔案。

構建專案

如果你想要 構建/打包專案，請在專案目錄下執行 ‘gradle clean shadowJar’ 命令。命令執行後，你將 找到一個 JAR 檔案，裡面包含了你的應用程式，以及已作為依賴項新增到應用程式的聯結器和庫：build/libs/--all.jar。

注意： 如果你使用其他類而不是 StreamingJob 作為應用程式的主類/入口，我們建議你相應地修改 build.gradle 檔案中的 mainClassName 配置。這樣，Flink 可以從 JAR 檔案執行應用程式，而無需另外指定主類。

未來，我們將分別介紹：Flink流處理應用程式，Flink批處理應用程式。

更多Flink原理知識：

穿梭時空的實時計算框架——Flink對時間的處理

大資料實時處理的王者-Flink

統一批處理流處理——Flink批流一體實現原理

更多實時計算,Flink,Kafka等相關技術博文，歡迎關注實時流式計算：

相關推薦