2. 程式人生 > >Unity Shader入門精要學習筆記 - 第14章非真實感渲染

Unity Shader入門精要學習筆記 - 第14章非真實感渲染

阿新 • • 發佈：2017-10-01
只需要 遮擋 本質 lar 屏幕 準備 dot smo try

轉載自 馮樂樂的 《Unity Shader 入門精要》

盡管遊戲渲染一般都是以照相寫實主義作為主要目標，但也有許多遊戲使用了非真實感渲染（NPR）的方法來渲染遊戲畫面。非真實感渲染的一個主要目標是，使用一些渲染方法使得畫面達到和某些特殊的繪畫風格相似的效果，例如卡通、水彩風格等。

卡通風格的渲染

卡通風格是遊戲中常見的一種渲染風格。使用這種風格的遊戲畫面通常有一些共有的特點，例如物體都被黑色的線條描邊，以及分明的明暗變化等。如下圖所示。

技術分享

要實現卡通渲染有很多方法，其中之一就是使用基於色調的著色技術。在實現中，我們往往會使用漫反射系數對一張一維紋理進行采樣，以控制漫反射的色調。卡通風格的高光效果也和我們之前學習的光照不同。在卡通風格總，模型的高光往往是一塊塊分界明顯的純色風格。

除了光照模型不同外，卡通風格通常還需要在物體邊緣部分繪制輪廓。之前我們已經介紹過使用屏幕後處理結束對屏幕圖像進行描邊。在這裏，我們將介紹基於模型的描邊方法，這種方法的實現更加簡單，而且很多情況下也能得到不錯的效果。效果如下圖。技術分享

在實時渲染中，輪廓線的渲染是應用非常廣泛的一種效果。在《Real Time Rendering, third edition》中，作者把繪制模型輪廓線的方法分為5種。

1）基於觀察角度和表面法線的輪廓線渲染。（這種方法使用視角方向和表面法線的點乘結果來得到輪廓線的信息。這種方法簡單快速，可以在一個Pass中就得到渲染結果，但局限性很大，很多模型渲染出來的描邊效果都不盡如人意）

2）過程式幾何輪廓線渲染。這種方法的核心是使用兩個Pass渲染。第一個Pass渲染背面的面片，並使用某些技術讓它的輪廓可見；第二個Pass再正常渲染正面的面片。這種方法的有點在於快速有效，並且適用於絕大多數表面平滑的模型，但它的缺點是不適合類似於立方體這樣平整的模型。

3）基於圖像處理的輪廓線渲染。有點在於，可以適用於任何種類的模型。局限在於，一些深度和法線變化很小的輪廓無法被檢測出來，例如桌子上的紙張。

4）基於輪廓邊檢測的輪廓線渲染。上面提到的方法，一個最大的問題是，無法控制輪廓線的風格渲染。對於一些情況，我們希望可以渲染出獨特風格的輪廓線，例如水墨風格等。為此，我們希望可以檢測出精確的輪廓邊，然後直接渲染它們。檢測一條邊是否是輪廓邊的公式很簡單，我們只需要檢查和這條邊相鄰的兩個三角面片是否滿足以下條件

技術分享

其中，n(0)和n(1)分別表示兩個相鄰三角面片的法向，v 是從視角到該邊上任意頂點的方向。上述公式的本質在於檢查兩個相鄰三角面片是否一個朝正面，一個朝背面。我們可以在幾何著色器的幫助下實現上面的檢測過程。當然，這種方法也有缺點，除了實現相對復雜外，它還會有動畫連貫性的問題。也就是說，由於是逐幀單獨提取輪廓，所以在幀與幀之間會出現跳躍性。

5）最後一種就是混合了上述的幾種渲染方法。例如，首先找到精確的輪廓邊，把模型和輪廓邊渲染到紋理中，再使用圖像處理的方法識別輪廓線，並在圖像空間下進行風格化渲染。

我們使用過程幾何輪廓線渲染的方法來對模型進行輪廓描邊。我們將使用兩個Pass渲染模型：在第一個Pass中，我們會使用輪廓線顏色渲染整個背面的面片，並在視角空間下把模型頂點沿法線方向向外擴張一段距離，以此來讓背部輪廓線可見。代碼如下：

  1. viewPos = viewPos + viewNormal * _Outline;

但是，如果直接使用頂點法線進行擴展，對於一些內凹的模型，就可能法線背面面片遮擋正面面片的情況。為了盡可能防止出現這樣的情況，在擴張背面頂點之前，我們首先對頂點法線的z分量進行處理，使它們等於一個定值，然後把法線歸一化後再對頂點進行擴張。這樣的好處在於，擴展後的背面更加扁平化，從而降低了遮擋正面面片的可能性。代碼如下：

  1. viewNormal.z = -0.5;
  2. viewNormal = normalize(viewNormal);
  3. viewPos = viewPos + viewNormal * _Outline;

之前提到過，卡通風格的高光往往是模型上一塊塊分界明顯的純色區域。為了實現這種效果，我們就不能再使用之前學習的光照模型。在之前實現Blinn-Phong模型的過程中，我們使用法線點乘光照方向以及視角方向的一半，再和另一個參數進行指數操作得到高光反射系數。代碼如下：

  1. float spec = pow(max(0,dot(normal,halfDir)),_Gloss)

對於卡通渲染需要的高光反射光照模型，我們同樣需要計算normal 和 halfDir 的點乘結果，但不同的是，我們把該值和一個閾值進行比較，如果小於該閾值，則高光反射系數為0，否則返回1。

  1. float spec = dot(worldNormal, worldHalfDir);
  2. spec = step(threshold, spec)

在上面的代碼中，我們使用CG的step函數來實現和閾值比較的目的。step函數接受兩個參數，第一個參數是參考值，第二個參數是待比較的數值。如果第二個參數大於等於第一個參數，則返回1，否則返回0.

但是這種粗暴的判斷會在高光區域的邊界造成鋸齒，如下圖左圖所示。

技術分享
出現這種問題的原因在於，高光區域的邊緣不是平滑漸變的，而是由0突變到1。要想對其進行抗鋸齒處理，我們可以在邊界處很小的一塊區域內，進行平滑處理，代碼如下：

  1. float spec = dot(worldNormal, worldHalfDir);
  2. spec = lerp(0,1,smoothstep(-w,w,spec-threshold));

上面的代碼中，我們沒有像之前一樣直接使用step函數返回0或1，而是首先使用了CG的smoothstep 函數。其中，w是一個很小的值，當 spec - threshold 小於 -w 時，返回0，大於w時，返回1，否則在0到1之間進行插值。這樣的效果是，我們可以在[-w,w]區間內，即高光區域的邊界處，得到一個從0到1平滑變化的spec 值，從而實現抗鋸齒的目的。盡管我們可以把w設為一個很小的定值，但在本例中，我們選擇使用鄰域像素之間的近似導數值，這可以通過CG 的 fwidth 函數來得到。

當然，卡通渲染的高光往往有更多個性化的需要。例如很多卡通高光特效希望可以隨意伸縮、方塊話光照區域等。

為了實現上述效果，我們做如下準備工作。

1）新建一個場景，去掉天空盒子

2）新建一個材質，新建一個Shader ，賦給材質

3）場景中新建一個Suzanne 模型，材質賦給模型。

我們修改Shader 代碼。

  1. Shader "Unity Shaders Book/Chapter 14/Toon Shading" {
  2. Properties {
  3. _Color ("Color Tint", Color) = (1, 1, 1, 1)
  4. _MainTex ("Main Tex", 2D) = "white" {}
  5. //控制漫反射色調的漸變紋理
  6. _Ramp ("Ramp Texture", 2D) = "white" {}
  7. //用於控制輪廓線寬度
  8. _Outline ("Outline", Range(0, 1)) = 0.1
  9. //輪廓線顏色
  10. _OutlineColor ("Outline Color", Color) = (0, 0, 0, 1)
  11. //高光反射顏色
  12. _Specular ("Specular", Color) = (1, 1, 1, 1)
  13. //高光反射閾值
  14. _SpecularScale ("Specular Scale", Range(0, 0.1)) = 0.01
  15. }
  16. SubShader {
  17. Tags { "RenderType"="Opaque" "Queue"="Geometry"}
  18. //這個Pass只渲染背面的三角面片
  19. Pass {
  20. NAME "OUTLINE"
  21. //剔除正面
  22. Cull Front
  24. CGPROGRAM
  26. #pragma vertex vert
  27. #pragma fragment frag
  29. #include "UnityCG.cginc"
  31. float _Outline;
  32. fixed4 _OutlineColor;
  34. struct a2v {
  35. float4 vertex : POSITION;
  36. float3 normal : NORMAL;
  37. };
  39. struct v2f {
  40. float4 pos : SV_POSITION;
  41. };
  43. v2f vert (a2v v) {
  44. v2f o;
  46. float4 pos = mul(UNITY_MATRIX_MV, v.vertex);
  47. float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);
  48. normal.z = -0.5;
  49. pos = pos + float4(normalize(normal), 0) * _Outline;
  50. o.pos = mul(UNITY_MATRIX_P, pos);
  52. return o;
  53. }
  55. float4 frag(v2f i) : SV_Target {
  56. return float4(_OutlineColor.rgb, 1);
  57. }
  59. ENDCG
  60. }
  61. //只渲染正面
  62. Pass {
  63. Tags { "LightMode"="ForwardBase" }
  65. Cull Back
  67. CGPROGRAM
  69. #pragma vertex vert
  70. #pragma fragment frag
  72. #pragma multi_compile_fwdbase
  74. #include "UnityCG.cginc"
  75. #include "Lighting.cginc"
  76. #include "AutoLight.cginc"
  77. #include "UnityShaderVariables.cginc"
  79. fixed4 _Color;
  80. sampler2D _MainTex;
  81. float4 _MainTex_ST;
  82. sampler2D _Ramp;
  83. fixed4 _Specular;
  84. fixed _SpecularScale;
  86. struct a2v {
  87. float4 vertex : POSITION;
  88. float3 normal : NORMAL;
  89. float4 texcoord : TEXCOORD0;
  90. float4 tangent : TANGENT;
  91. };
  93. struct v2f {
  94. float4 pos : POSITION;
  95. float2 uv : TEXCOORD0;
  96. float3 worldNormal : TEXCOORD1;
  97. float3 worldPos : TEXCOORD2;
  98. SHADOW_COORDS(3)
  99. };
  101. v2f vert (a2v v) {
  102. v2f o;
  104. o.pos = mul( UNITY_MATRIX_MVP, v.vertex);
  105. o.uv = TRANSFORM_TEX (v.texcoord, _MainTex);
  106. o.worldNormal = UnityObjectToWorldNormal(v.normal);
  107. o.worldPos = mul(_Object2World, v.vertex).xyz;
  109. TRANSFER_SHADOW(o);
  111. return o;
  112. }
  114. float4 frag(v2f i) : SV_Target {
  115. fixed3 worldNormal = normalize(i.worldNormal);
  116. fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
  117. fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
  118. fixed3 worldHalfDir = normalize(worldLightDir + worldViewDir);
  120. fixed4 c = tex2D (_MainTex, i.uv);
  121. fixed3 albedo = c.rgb * _Color.rgb;
  123. fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
  125. UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
  127. fixed diff = dot(worldNormal, worldLightDir);
  128. diff = (diff * 0.5 + 0.5) * atten;
  130. fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;
  132. fixed spec = dot(worldNormal, worldHalfDir);
  133. fixed w = fwidth(spec) * 2.0;
  134. fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) * step(0.0001, _SpecularScale);
  136. return fixed4(ambient + diffuse + specular, 1.0);
  137. }
  139. ENDCG
  140. }
  141. }
  142. FallBack "Diffuse"
  143. }


素描風格的渲染

另一個非常流行的非真實感渲染是素描風格的渲染。微軟研究院的Praun等人在2001年發表了一篇非常著名的論文。在這篇文章中，它們使用了提前生成的素描紋理來實現實時的素描風格渲染，這些紋理組成了一個色調藝術映射（TAM）。如下圖所示，從左到右紋理匯總的筆逐漸增多，用於模擬不同光照下的漫反射效果，從上到下則對應了每張紋理的多級漸遠紋理。這些多級漸遠紋理的生成並不是簡單的對上一層紋理進行降采樣，而是需要保持筆觸之間的間隔，以便更真實地模擬素描效果。

技術分享

我們將實現一個簡化版算法，先不考慮多級漸遠紋理的生成，而直接使用6張素描紋理進行渲染。在渲染階段，我們首先在頂點著色器階段計算逐頂點的光照，根據光照結果來決定6張紋理的混合權重，並傳遞給片元著色器。然後在片元著色器中根據這些權重來混合6張紋理的采樣結果。效果如下。

技術分享

我們新建一個Shader實現上述效果。

    1. Shader "Unity Shaders Book/Chapter 14/Hatching" {
    2. Properties {
    3. _Color ("Color Tint", Color) = (1, 1, 1, 1)
    4. //紋理的平鋪系數，越大則素描線條越密
    5. _TileFactor ("Tile Factor", Float) = 1
    6. _Outline ("Outline", Range(0, 1)) = 0.1
    7. //渲染使用的6張素描紋理
    8. _Hatch0 ("Hatch 0", 2D) = "white" {}
    9. _Hatch1 ("Hatch 1", 2D) = "white" {}
    10. _Hatch2 ("Hatch 2", 2D) = "white" {}
    11. _Hatch3 ("Hatch 3", 2D) = "white" {}
    12. _Hatch4 ("Hatch 4", 2D) = "white" {}
    13. _Hatch5 ("Hatch 5", 2D) = "white" {}
    14. }
    16. SubShader {
    17. Tags { "RenderType"="Opaque" "Queue"="Geometry"}
    18. //使用之前輪廓線的Pass
    19. UsePass "Unity Shaders Book/Chapter 14/Toon Shading/OUTLINE"
    21. Pass {
    22. Tags { "LightMode"="ForwardBase" }
    24. CGPROGRAM
    26. #pragma vertex vert
    27. #pragma fragment frag
    29. #pragma multi_compile_fwdbase
    31. #include "UnityCG.cginc"
    32. #include "Lighting.cginc"
    33. #include "AutoLight.cginc"
    34. #include "UnityShaderVariables.cginc"
    36. fixed4 _Color;
    37. float _TileFactor;
    38. sampler2D _Hatch0;
    39. sampler2D _Hatch1;
    40. sampler2D _Hatch2;
    41. sampler2D _Hatch3;
    42. sampler2D _Hatch4;
    43. sampler2D _Hatch5;
    45. struct a2v {
    46. float4 vertex : POSITION;
    47. float4 tangent : TANGENT;
    48. float3 normal : NORMAL;
    49. float2 texcoord : TEXCOORD0;
    50. };
    52. struct v2f {
    53. float4 pos : SV_POSITION;
    54. float2 uv : TEXCOORD0;
    55. fixed3 hatchWeights0 : TEXCOORD1;
    56. fixed3 hatchWeights1 : TEXCOORD2;
    57. float3 worldPos : TEXCOORD3;
    58. SHADOW_COORDS(4)
    59. };
    61. v2f vert(a2v v) {
    62. v2f o;
    64. o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
    65. //使用_TileFactor得到采樣坐標
    66. o.uv = v.texcoord.xy * _TileFactor;
    67. //逐頂點光照
    68. fixed3 worldLightDir = normalize(WorldSpaceLightDir(v.vertex));
    69. fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
    70. fixed diff = max(0, dot(worldLightDir, worldNormal));
    72. o.hatchWeights0 = fixed3(0, 0, 0);
    73. o.hatchWeights1 = fixed3(0, 0, 0);
    75. float hatchFactor = diff * 7.0;
    76. //計算紋理的權重
    77. if (hatchFactor > 6.0) {
    78. // Pure white, do nothing
    79. } else if (hatchFactor > 5.0) {
    80. o.hatchWeights0.x = hatchFactor - 5.0;
    81. } else if (hatchFactor > 4.0) {
    82. o.hatchWeights0.x = hatchFactor - 4.0;
    83. o.hatchWeights0.y = 1.0 - o.hatchWeights0.x;
    84. } else if (hatchFactor > 3.0) {
    85. o.hatchWeights0.y = hatchFactor - 3.0;
    86. o.hatchWeights0.z = 1.0 - o.hatchWeights0.y;
    87. } else if (hatchFactor > 2.0) {
    88. o.hatchWeights0.z = hatchFactor - 2.0;
    89. o.hatchWeights1.x = 1.0 - o.hatchWeights0.z;
    90. } else if (hatchFactor > 1.0) {
    91. o.hatchWeights1.x = hatchFactor - 1.0;
    92. o.hatchWeights1.y = 1.0 - o.hatchWeights1.x;
    93. } else {
    94. o.hatchWeights1.y = hatchFactor;
    95. o.hatchWeights1.z = 1.0 - o.hatchWeights1.y;
    96. }
    98. o.worldPos = mul(_Object2World, v.vertex).xyz;
    100. TRANSFER_SHADOW(o);
    102. return o;
    103. }
    105. fixed4 frag(v2f i) : SV_Target {
    106. //根據權重采樣取色
    107. fixed4 hatchTex0 = tex2D(_Hatch0, i.uv) * i.hatchWeights0.x;
    108. fixed4 hatchTex1 = tex2D(_Hatch1, i.uv) * i.hatchWeights0.y;
    109. fixed4 hatchTex2 = tex2D(_Hatch2, i.uv) * i.hatchWeights0.z;
    110. fixed4 hatchTex3 = tex2D(_Hatch3, i.uv) * i.hatchWeights1.x;
    111. fixed4 hatchTex4 = tex2D(_Hatch4, i.uv) * i.hatchWeights1.y;
    112. fixed4 hatchTex5 = tex2D(_Hatch5, i.uv) * i.hatchWeights1.z;
    113. fixed4 whiteColor = fixed4(1, 1, 1, 1) * (1 - i.hatchWeights0.x - i.hatchWeights0.y - i.hatchWeights0.z -
    114. i.hatchWeights1.x - i.hatchWeights1.y - i.hatchWeights1.z);
    116. fixed4 hatchColor = hatchTex0 + hatchTex1 + hatchTex2 + hatchTex3 + hatchTex4 + hatchTex5 + whiteColor;
    118. UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
    120. return fixed4(hatchColor.rgb * _Color.rgb * atten, 1.0);
    121. }
    123. ENDCG
    124. }
    125. }
    126. FallBack "Diffuse"
    127. }

Unity Shader入門精要學習筆記 - 第14章非真實感渲染

相關推薦

Unity Shader入門精要學習筆記 - 第14章非真實感渲染

只需要 遮擋 本質 lar 屏幕 準備 dot smo try 轉載自 馮樂樂的 《Unity Shader 入門精要》 盡管遊戲渲染一般都是以照相寫實主義作為主要目標，但也有許多遊戲使用了非真實感渲染（NPR）的方法來渲染遊戲畫面。非真實感渲染的一個主要目標是，使用一些渲

Unity Shader入門精要學習筆記 - 第4章 學習 Shader 所需的數學基礎

旋轉矩陣 即使 模擬 能夠 一點 空間使用 虛擬 地板 金字塔 摘錄自 馮樂樂的《Unity Shader入門精要》 笛卡爾坐標系 1）二維笛卡爾坐標系 在遊戲制作中，我們使用的數學絕大部分都是計算位置、距離、角度等變量。而這些計算大部分都是在笛卡爾坐標系下進行的。 一個二

Unity Shader入門精要學習筆記 - 第3章 Unity Shader 基礎

但是 detail spa net 表示 part 文件 人的 text 來源作者：candycat http://blog.csdn.net/candycat1992/article/ 概述 總體來說，在Unity中我們需要配合使用材質和Unity Shader才能達

Unity Shader入門精要學習筆記 - 第11章 讓畫面動起來

位置 視覺效果 想要 朝向 系列 圖像 顏色 offset star 轉自 馮樂樂的 《Unity Shader入門精要》 Unity Shader 中的內置變量 動畫效果往往都是把時間添加到一些變量的計算中，以便在時間變化時畫面也可以隨之變化。Unity Shader 提

Unity Shader入門精要學習筆記 - 第16章 Unity中的渲染優化技術

也會 檢測 特點 著色器 版本 切換 代碼優化 學習 順序 轉自馮樂樂的 《Unity Shader 入門精要》 移動平臺的特點 為了盡可能一處那些隱藏的表面，減少overdraw（即一個像素被繪制多次），PowerVR芯片（通常用於ios設備和某些Android設備）使用

Unity Shader入門精要學習筆記 - 第10章 高級紋理

unp string math 計算 圖像繪制 兩種方法 內存 對象 交叉 轉載自 馮樂樂的 《Unity Shader入門精要》 立方體紋理 在圖形學中，立方體紋理是環境映射的一種實現方法。環境映射可以模擬物體周圍的環境，而使用了環境映射的物體可以看起來像鍍了層金屬一樣反

《Unity Shader入門精要》筆記 #第四章 學習Shader所需的數學基礎

不懂數學者不得入內 1、笛卡爾座標系 旋向性 旋轉正方向 Unity採用的座標系         模型空間及世界空間 - 左手座標系         觀察空間 - 右手座標系 2、點和向量 點積 - 投影 叉積 - 計算垂直於一個平面、三角形的向量；判斷三角

Unity Shader入門精要學習筆記-渲染流水線

一、什麼是渲染流水線 渲染流水線的工作在與有一個三維場景出發，生成或者說渲染一張二維影象。 即計算機從一些列的頂點資料和紋理等資訊出發，將這些資訊轉換成一張人眼可以看到的影象。 《Real-Time Rendering》一書將渲染流程分為三個階段：應用階段 Application Stage，幾何階段

《Unity Shader入門精要》總結 #第五章 開始Unity Shader學習

1、最簡單的頂點／片元著色器 1.1 頂點／片元的基本結構 包含Shader、Properties、SubShader、Fallback等語義塊 Shader "MyShaderName"{ Properties{ //屬性 }

Unity Shader入門精要學習筆記

摘錄自 馮樂樂的《Unity Shader入門精要》 笛卡爾座標系 1）二維笛卡爾座標系 在遊戲製作中，我們使用的數學絕大部分都是計算位置、距離、角度等變數。而這些計算大部分都是在笛卡爾座標系下進行的。 一個二維的笛卡爾座標系包含了兩個部分的資訊： 一個特殊的位置，

Unity Shader入門精要 學習筆記一

前幾章預計都是理論知識。涉及程式碼的也應該是很小一部分，在我想來。先把理論搞搞清楚。再去理解shader會好很多。所以祝福諸君程運昌榮！好了。開始記錄學習筆記 1.渲染流水線是什麼？和shader有什麼關聯？ “渲染流水線的最終目的是生成或者說是渲染一張二維

《Unity Shader入門精要》總結 #第七章 基礎紋理

使用紋理對映可以將一張圖逐紋素地控制模型顏色。 紋理大小可變，但頂點UV座標範圍通常被歸一化道[0,1]範圍內 1、單張紋理 1.1 實踐 【補充一下第三章Properties語義塊支援的屬性型別，之前忘記寫自己還老分不清- -】 Properties{ N

《Unity Shader入門精要》總結 #第九章 更復雜的光照

1、Unity的渲染路徑 主要有3種：前向渲染路徑、延遲渲染路徑、頂點照明渲染路徑 攝像機單獨設定，若選擇User Player Settings，則攝像機會使用Project Settings的設定；否則覆蓋掉Project Settings的設定 ，若當前顯示卡並不

Unity Shader入門精要 閱讀筆記二

Unity Shader 基礎 unity shader在5.2版本以上能夠直接從專案中建立4個shader模板：standard surface shader、Unlit shader、Image Effect shader,computer shader.

Unity Shader入門精要 閱讀筆記十七

前言 這裡講邊緣檢測這一節中的筆記內容。邊緣檢測這裡更多的用到了影象學的一些基本內容，包括卷積核，索貝爾運算元等等一些內容。整個流程還是比較清晰的。 邊緣檢測演算法 獲取到螢幕渲染的顏色緩衝之後，將螢幕中的畫素用索貝爾運算元進行卷積操作，卷積的結果就是

第14章 非真實感渲染

儘管遊戲渲染一般都是以照相寫實主義（ photorealism ） 作為主要目標， 但也有許多遊戲使用了非真實感渲染（ Non-Photorealistic Rendering , NPR）的方法來渲染遊戲畫面。非真實感渲染的一個主要目標是， 使用一些渲染方法使得畫面達到和某些特殊的繪畫風格相似

【《Unity Shader入門精要》 提煉總結】(十五)第十五章·光照系統進階教程&Unity的渲染路徑介紹&前向渲染路徑&頂點照明渲染路徑&延遲渲染路徑

      本文由@唐三十胖子出品，轉載請註明出處。  文章連結：https://blog.csdn.net/iceSony/article/details/84887592    

《Unity Shader入門精要》自學筆記（一）

Shader "Custom/zhudingdian" {Properties {_Diffuse("Diffuse",color) = (1,1,1,1)//用於顏色設定}SubShader {pass{tags{"LightMode" = "ForwardBase"}C

Unity Shader入門精要筆記（十二）：紋理屬性

本系列文章由Aimar_Johnny編寫，歡迎轉載，轉載請標明出處，謝謝。 http://blog.csdn.net/lzhq1982/article/details/75045358 紋理從廣義上講不是一個普通的圖片，我們今後會遇到各種功能性紋理，比如法線紋理，立方體紋

Unity Shader入門精要筆記（七）：Unity Shader內建檔案、變數和語義

本系列文章由Aimar_Johnny編寫，歡迎轉載，轉載請標明出處，謝謝。 http://blog.csdn.net/lzhq1982/article/details/74279052 1、Unity提供的內建檔案和變數 上一篇我們學了一個簡單的頂點/片元著色器。複雜的著