String物件是不可變的：意思就是無論是對String的新增或修改，出現一個全新的String內容時，都意味著誕生了一個新的物件。但是如果內容不變的話，增加的只是物件的引用而已。

例如：

String a = "ljh";
String b = "ljh";
String c = "ljh";

System.out.println(a==b);
System.out.println(b==c);

結果都是true

但是這種不可變性會產生一些效能上的問題，所以JVM對String物件過載“+”“+=”進行了一些優化

操作符“+”可以用來連線String

String aaa = "ljh";
String 
 
bbb = "big";
String ccc = aaa+bbb+"aaaa";

在jdk8中，上述程式碼中在底層其實是編譯器擅自呼叫了StringBuilder類進行+的操作，主要原因是StringBuilder的append（）更加高效，我們來看一下位元組碼。

  public static void main(java.lang.String[]);
    Code:
       0: ldc           #2                  // String ljh
       2: astore_1
       3: ldc           #3                  // String big
       5: astore_2
       6: new           #4                  // class java/lang/StringBuilder
       9: dup
      10: invokespecial #5                  // Method java/lang/StringBuilder."<init>":()V
      13: aload_1
      14: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      17: aload_2
      18: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      21: ldc           #7                  // String aaaa
      23: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      26: invokevirtual #8                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      29: astore_3
      30: return
 

可以看出一共有四個物件，分別是三個String 和一個StringBuilder

我們再來看一下+=

String a = "aaa";
a += "bbb";

位元組碼如下

    Code:
       0: ldc           #2                  // String aaa
       2: astore_1
       3: new           #3                  // class java/lang/StringBuilder
       6: dup
       7: invokespecial #4                  // Method java/lang/StringBuilder."<init>":()V
      10: aload_1
      11: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      14: ldc           #6                  // String bbb
      16: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      19: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      22: astore_1
      23: return
 

可以看出先建立了一個“aaa”字串，然後當a遇到+=時，建立了一個StringBuilder物件，並append了aaa字串。之後建立了一個“bbb”物件，然後append了bbb字串，最後呼叫StringBuilder的toString方法。

接下來再看看迴圈中呼叫+=會是什麼樣子

String a = "aaa";
a += "bbb";
for(int i=0;i<5;i++){
    a+="ccc";
}

    Code:
       0: ldc           #2                  // String aaa
       2: astore_1
       3: new           #3                  // class java/lang/StringBuilder
       6: dup
       7: invokespecial #4                  // Method java/lang/StringBuilder."<init>":()V
      10: aload_1
      11: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      14: ldc           #6                  // String bbb
      16: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      19: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      22: astore_1
      23: iconst_0
      24: istore_2
      25: iload_2
      26: iconst_5
      27: if_icmpge     56
      30: new           #3                  // class java/lang/StringBuilder
      33: dup
      34: invokespecial #4                  // Method java/lang/StringBuilder."<init>":()V
      37: aload_1
      38: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      41: ldc           #8                  // String ccc
      43: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      46: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      49: astore_1
      50: iinc          2, 1
      53: goto          25
      56: return

可以看出先建立String物件aaa,之後建立StringBuilder並初始化StringBuilder append aaa，然後建立bbb物件，並append（  bbb），然後我們發現在迴圈中依舊建立了一個新的StringBuilder，也就是沒經過一次迴圈都要建立一個新的StringBuilder物件。

這時我們做一個優化，提前建立StringBuilder物件

String a = "aaa";
a += "bbb";
StringBuilder sb = new StringBuilder(a);
for(int i=0;i<5;i++){
    sb.append("ccc");
}

    Code:
       0: ldc           #2                  // String aaa
       2: astore_1
       3: new           #3                  // class java/lang/StringBuilder
       6: dup
       7: invokespecial #4                  // Method java/lang/StringBuilder."<init>":()V
      10: aload_1
      11: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      14: ldc           #6                  // String bbb
      16: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      19: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      22: astore_1
      23: new           #3                  // class java/lang/StringBuilder
      26: dup
      27: aload_1
      28: invokespecial #8                  // Method java/lang/StringBuilder."<init>":(Ljava/lang/String;)V
      31: astore_2
      32: iconst_0
      33: istore_3
      34: iload_3
      35: iconst_5
      36: if_icmpge     52
      39: aload_2
      40: ldc           #9                  // String ccc
      42: invokevirtual #5                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      45: pop
      46: iinc          3, 1
      49: goto          34
      52: return