/* Set up the stack                            */
stack_setup:
    ldr    r0, _TEXT_BASE        /* upper 128 KiB: relocated uboot   */
    sub    r0, r0, #CFG_MALLOC_LEN    /* malloc area                      */
    sub    r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
#ifdef CONFIG_USE_IRQ
    sub    r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
    sub    sp, r0, #12        /* leave 3 words for abort-stack    */

clear_bss:
    ldr    r0, _bss_start        /* find start of bss segment        */
    ldr    r1, _bss_end        /* stop here                        */
    mov     r2, #0x00000000        /* clear                            */

clbss_l:str    r2, [r0]        /* clear loop...                    */
    add    r0, r0, #4
    cmp    r0, r1
    ble    clbss_l
    這一段程式碼的功能是設定棧和清零.bss段。從程式碼中也可以看出，程式碼段是在高地址處，程式碼段前面是堆（也就是給動態記憶體分配預留的空間）。CFG_GBL_DATA_SIZE在config檔案中定義，start.S中會根據這個值分配棧空間用於儲存board的有關資訊。bdinfo之前的就是IRQ和FIQ的棧空間，當然這個是否分配是取決於是否定義了CONFIG_USE_IRQ這個巨集。後面緊跟著的一條語句
sub    sp, r0, #1
    這裡沒有直接將r0的值賦值給棧指標sp，而是將r0-12的值賦值給了sp，當然必須清楚的一點是這裡的棧是向下增長的，也就是相當於sp會從當前的地址往地址更小的地方生長。這裡留出來的這多餘的12個位元組是為了給FIQ或者IRQ中斷棧預留的空間（防止其棧溢位而破壞sp棧中的資料）。
    後面的程式碼是用了一段迴圈來將.bss段全部清零，因為邏輯比較清晰，也就不再贅述了。

    ldr    pc, _start_armboot

_start_armboot:    .word start_armboot
    這是比較關鍵的一個地方，因為程式執行到這裡，將會跳轉到到C語言部分去執行。這個start_armboot函式的路徑為lib_arm\Board.c。

cpu_init_crit:
    /*
     * flush v4 I/D caches
     */
    mov    r0, #0
    mcr    p15, 0, r0, c7, c7, 0    /* flush v3/v4 cache */
    mcr    p15, 0, r0, c8, c7, 0    /* flush v4 TLB */

    /*
     * disable MMU stuff and caches
     */
    mrc    p15, 0, r0, c1, c0, 0
    bic    r0, r0, #0x00002300    @ clear bits 13, 9:8 (--V- --RS)
    bic    r0, r0, #0x00000087    @ clear bits 7, 2:0 (B--- -CAM)
    orr    r0, r0, #0x00000002    @ set bit 2 (A) Align
    orr    r0, r0, #0x00001000    @ set bit 12 (I) I-Cache
    mcr    p15, 0, r0, c1, c0, 0

    /*
     * before relocating, we have to setup RAM timing
     * because memory timing is board-dependend, you will
     * find a lowlevel_init.S in your board directory.
     */
    mov    ip, lr
    bl    lowlevel_init
    mov    lr, ip
    mov    pc, lr
#endif /* CONFIG_SKIP_LOWLEVEL_INIT */
    程式mov    r0, #0開始的這三行重新整理cache和TLB。cache是一種快取記憶體儲存器，用於儲存CPU頻繁使用的資料。在使用Cache技術的處理器上，當一條指令要訪問記憶體的資料時，首先查詢cache快取中是否有資料以及資料是否過期，如果資料未過期則從cache讀出資料。處理器會定期回寫cache中的資料到記憶體。根據程式的區域性性原理，使用cache後可以大大加快處理器訪問記憶體資料的速度。
    TLB的作用是在處理器訪問記憶體資料的時候做地址轉換。TLB的全稱是Translation Lookaside Buffer，可以翻譯做旁路緩衝。TLB中存放了一些頁表文件，檔案中記錄了虛擬地址和實體地址的對映關係。當應用程式訪問一個虛擬地址的時候，會從TLB中查詢出對應的實體地址，然後訪問實體地址。TLB通常是一個分層結構，使用與Cache類似的原理。處理器使用一定的演算法把最常用的頁表放在最先訪問的層次。提示：ARM處理器Cache和TLB的配置暫存器可以參考ARM體系結構手冊。
    程式以mrc    p15, 0, r0, c1, c0, 0開始的這6行關閉MMU。MMU是記憶體管理單元（Memory Management Unit）的縮寫。在現代計算機體系結構上，MMU被廣泛應用。使用MMU技術可以嚮應用程式提供一個巨大的虛擬地址空間。在U-Boot初始化的時候，程式看到的地址都是實體地址，無須使用MMU。
    程式bl    lowlevel_init跳轉到lowlevel_init標號，執行與開發板相關的初始化配置。需要注意的是bl是一個會返回的跳轉，程式執行完與開發板相關的操作之後會跳轉回來繼續往下執行。
mov    ip, lr
bl    lowlevel_init
mov    lr, ip
mov    pc, lr
    ip是r12暫存器的別名，它在過程連結膠合程式碼（例如，互動操作膠合程式碼）中用於此角色。在過程呼叫之間，可以將它用於任何用途。被呼叫函式在返回之前不必恢復r12。
    r14是連結暫存器lr。如果您儲存了返回地址，則可以在呼叫之間將 r14 用於其它用途，程式返回時要恢復。
    這一段程式碼需要說明的是，相當於在子程式內部還要呼叫一個子程式，但是這裡是彙編程式碼，第一次被呼叫的子程式（也就是cpu_init_crit這個標號）時返回地址被硬體自動的儲存在了lr暫存器中，但是當在cpu_init_crit還要呼叫一個子程式的時候這是lr會被重新賦值，那麼以前的lr的值就丟了！所以程式在這裡用了ip來儲存lr最開始的值，子程式內部的子程式呼叫結束後再將其復原回來，這樣通過mov pc, lr就可以返回最初的呼叫點後面繼續執行了。

#define S_FRAME_SIZE    72

#define S_OLD_R0    68
#define S_PSR        64
#define S_PC        60
#define S_LR        56
#define S_SP        52

#define S_IP        48
#define S_FP        44
#define S_R10        40
#define S_R9        36
#define S_R8        32
#define S_R7        28
#define S_R6        24
#define S_R5        20
#define S_R4        16
#define S_R3        12
#define S_R2        8
#define S_R1        4
#define S_R0        0
    這一部分巨集看起來很讓人迷惑，感覺像是定義的地址。其實這就是pt_regs結構體的偏移值,該結構體定義在include\asm-arm\proc-armv\ptrace.h中。

/*
 * use bad_save_user_regs for abort/prefetch/undef/swi ...
 * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 */

    .macro    bad_save_user_regs
    sub    sp, sp, #S_FRAME_SIZE
    stmia    sp, {r0 - r12}            @ Calling r0-r12
    ldr    r2, _armboot_start
    sub    r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
    sub    r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
    ldmia    r2, {r2 - r3}            @ get pc, cpsr
    add    r0, sp, #S_FRAME_SIZE        @ restore sp_SVC

    add    r5, sp, #S_SP
    mov    r1, lr
    stmia    r5, {r0 - r3}            @ save sp_SVC, lr_SVC, pc, cpsr
    mov    r0, sp
    .endm

    .macro    irq_save_user_regs
    sub    sp, sp, #S_FRAME_SIZE
    stmia    sp, {r0 - r12}            @ Calling r0-r12
    add     r8, sp, #S_PC
    stmdb   r8, {sp, lr}^                   @ Calling SP, LR
    str     lr, [r8, #0]                    @ Save calling PC
    mrs     r6, spsr
    str     r6, [r8, #4]                    @ Save CPSR
    str     r0, [r8, #8]                    @ Save OLD_R0
    mov    r0, sp
    .endm

    .macro    irq_restore_user_regs
    ldmia    sp, {r0 - lr}^            @ Calling r0 - lr
    mov    r0, r0
    ldr    lr, [sp, #S_PC]            @ Get PC
    add    sp, sp, #S_FRAME_SIZE
    subs    pc, lr, #4            @ return & move spsr_svc into cpsr
    .endm

    .macro get_bad_stack
    ldr    r13, _armboot_start        @ setup our mode stack
    sub    r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
    sub    r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack

    str    lr, [r13]            @ save caller lr / spsr
    mrs    lr, spsr
    str     lr, [r13, #4]

    mov    r13, #MODE_SVC            @ prepare SVC-Mode
    @ msr    spsr_c, r13
    msr    spsr, r13
    mov    lr, pc
    movs    pc, lr
    .endm

    .macro get_irq_stack            @ setup IRQ stack
    ldr    sp, IRQ_STACK_START
    .endm

    .macro get_fiq_stack            @ setup FIQ stack
    ldr    sp, FIQ_STACK_START
    .endm

/*
 * exception handlers
 */
    .align  5
undefined_instruction:
    get_bad_stack
    bad_save_user_regs
    bl     do_undefined_instruction

    .align    5
software_interrupt:
    get_bad_stack
    bad_save_user_regs
    bl     do_software_interrupt

    .align    5
prefetch_abort:
    get_bad_stack
    bad_save_user_regs
    bl     do_prefetch_abort

    .align    5
data_abort:
    get_bad_stack
    bad_save_user_regs
    bl     do_data_abort

    .align    5
not_used:
    get_bad_stack
    bad_save_user_regs
    bl     do_not_used

#ifdef CONFIG_USE_IRQ

    .align    5
irq:
    get_irq_stack
    irq_save_user_regs
    bl     do_irq
    irq_restore_user_regs

    .align    5
fiq:
    get_fiq_stack
    /* someone ought to write a more effiction fiq_save_user_regs */
    irq_save_user_regs
    bl     do_fiq
    irq_restore_user_regs

#else

    .align    5
irq:
    get_bad_stack
    bad_save_user_regs
    bl     do_irq

    .align    5
fiq:
    get_bad_stack
    bad_save_user_regs
    bl     do_fiq
    這一部分是中斷處理的中間部分，這裡會完成儲存中斷現場並跳轉到中斷處理函式的功能，使用了巨集程式碼段來使這部分的邏輯更為清晰。