列印設定對話方塊點選確定頁邊距不斷變化的問題，網上找到了一部分解決辦法，都是隻解決了列印設定對話方塊點選確定頁邊距不斷變化的問題，沒有解決初次開啟對話方塊的資料準確問題、沒有考慮和列印預覽、真實列印設定資料準確聯動的問題，也就是列印預覽裡的邊距那些資料的同步。

       如果使用者的區域採用美製，那麼完全沒有此BUG；但採用公制，系統底層一律會將對話方塊設定的邊距儲存為以百分之一英寸為單位，但是讀取的時候出了叉子，以十分之一毫米為單位提取到對話方塊裡，這就是bug的由來。比如預設設定100（官方說明：Margins ，表示頁邊距，以百分之一英寸為單位。 預設情況下各邊的邊距都為 1 英寸），100（十分之一毫米）轉換為毫米，那麼對話方塊裡顯示10毫米，實際上應該為25.4毫米，也就是1英寸。同時預覽對話方塊（以百分之一英寸為單位）理應為100。另外，如果幾個對話方塊都關聯到列印文件的話，無論設定哪個的頁邊距，都會同時變化，也就是說他們引用和設定的都是同一個物件。上程式碼：

Imports System.IO
Imports System.Drawing.Printing

Public Class Form1

    Private stringToPrint As String
    Private printFont As New Font("Arial", 10)
    Private blnMetric As Boolean    '記錄頁面邊距的單位是否是公制

    Private Sub btnOpen_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnOpen.Click
        OpenFileDialog1.Filter = "Text files (*.txt)|*.txt"
        OpenFileDialog1.ShowDialog()
        If OpenFileDialog1.FileName <> "" Then
            Try
                Dim MyFileStream As New FileStream(OpenFileDialog1.FileName, FileMode.Open)
                RichTextBox1.LoadFile(MyFileStream, RichTextBoxStreamType.PlainText)
                MyFileStream.Close()
                btnPrint.Enabled = True
                btnSetup.Enabled = True
                btnPreview.Enabled = True
            Catch ex As Exception
                MessageBox.Show(ex.Message)
            End Try
        End If
    End Sub

    Private Sub btnPrint_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrint.Click
        Try
            stringToPrint = RichTextBox1.Text
            PrintDialog1.Document = PrintDocument1
            If blnMetric Then
                PageSetupDialog1.PageSettings.Margins = PrinterUnitConvert.Convert( _
                    PageSetupDialog1.PageSettings.Margins, PrinterUnit.TenthsOfAMillimeter, PrinterUnit.Display)
                blnMetric = False
            End If
            Dim result As DialogResult = PrintDialog1.ShowDialog()
            If result = DialogResult.OK Then
                PrintDocument1.DocumentName = "我的文件"
                PrintDocument1.Print()
            End If
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Sub

    Private Sub PrintDocument1_PrintPage(ByVal sender As System.Object, ByVal e As System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
        Dim numChars, numLines As Integer
        Dim stringOnePage As String
        Dim strFormat As New StringFormat
        Dim rectDraw As New RectangleF(e.MarginBounds.Left, e.MarginBounds.Top, e.MarginBounds.Width, e.MarginBounds.Height)
        Dim sizeMeasure As New SizeF(e.MarginBounds.Width, e.MarginBounds.Height - printFont.GetHeight(e.Graphics))
        strFormat.Trimming = StringTrimming.Word
        e.Graphics.MeasureString(stringToPrint, printFont, sizeMeasure, strFormat, numChars, numLines)
        Console.WriteLine(numLines)
        stringOnePage = stringToPrint.Substring(0, numChars)
        e.Graphics.DrawString(stringOnePage, printFont, Brushes.Black, rectDraw, strFormat)
        If numChars < stringToPrint.Length Then
            stringToPrint = stringToPrint.Substring(numChars)
            e.HasMorePages = True
        Else
            e.HasMorePages = False
            stringToPrint = RichTextBox1.Text    '無此句則列印預覽裡列印一次過後再次列印只打最後一頁
        End If
    End Sub

    Private Sub btnSetup_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSetup.Click
        Try
            PageSetupDialog1.Document = PrintDocument1
            If Not blnMetric Then     '載入列印設定對話方塊,如果現在的單位是美製，則轉為公制
                PageSetupDialog1.PageSettings.Margins = PrinterUnitConvert.Convert( _
                PageSetupDialog1.PageSettings.Margins, PrinterUnit.Display, PrinterUnit.TenthsOfAMillimeter)
                blnMetric = True
            End If
            If PageSetupDialog1.ShowDialog() = Windows.Forms.DialogResult.OK Then
                PageSetupDialog1.PageSettings.Margins = PrinterUnitConvert.Convert( _
                PageSetupDialog1.PageSettings.Margins, PrinterUnit.Display, PrinterUnit.TenthsOfAMillimeter)
            End If
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Sub

    Private Sub btnPreview_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPreview.Click
        Try
            PrintPreviewDialog1.Document = PrintDocument1
            If blnMetric Then
                PageSetupDialog1.PageSettings.Margins = PrinterUnitConvert.Convert( _
                    PageSetupDialog1.PageSettings.Margins, PrinterUnit.TenthsOfAMillimeter, PrinterUnit.Display)
                blnMetric = False
            End If
            stringToPrint = RichTextBox1.Text
            PrintPreviewDialog1.ShowDialog()
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Sub

    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        PrintDocument1.DefaultPageSettings.Margins.Top = 100
        PrintDocument1.DefaultPageSettings.Margins.Bottom = 100
        PrintDocument1.DefaultPageSettings.Margins.Left = 80
        PrintDocument1.DefaultPageSettings.Margins.Right = 80
    End Sub
End Class