標題起得有點浮誇哈，本文將介紹利用Bat指令以及Git等工具實現自動化拉取遠端分支，同時使用gradle自動編譯打包傳送郵件到指定郵箱的過程，實現自動化編譯與通知功能，因為當時的需求只有自動打包與通知，所以也沒有加入異常處理機制，日誌記錄也不完善，但是整體思路是一致的，其餘的是體驗上的加強，有興趣的朋友可以自己試試，可以藉助實現了功能bat檔案搭建一個web的更平易近人的介面來供每個專案使用。

一、前言

一些基礎的東西這裡將不作贅述，如git、gralde、bat指令等，以及過程中涉及的各個工具的環境搭建，這些都可以自行百度，資料非常多。

二、配置檔案

為了使用上的便利，最好能提供給使用者自行配置具體專案具體引數的檔案，畢竟不是所有人都瞭解bat，下面提供該編譯工具配置所需要的git資源的樣例：

git郵箱|git密碼|git地址|git分支|該分支具體某次提交記錄（放空預設最新）|git專案名
 

打包完成後郵件地址配置樣例：

發件人郵箱
發件人郵箱密碼
這是郵件標題
這是具體郵件內容
收件人1郵箱
收件人2郵箱

三、自動編譯bat檔案內容

因為git內容比較多，所以具體的講解我直接註釋在程式碼裡面，bat的註釋以rem開頭，其中一些重要命令也會稍加註釋，如果有一些沒有註釋的又不清楚的可以百度瞭解一下。

@echo off & setlocal enabledelayedexpansion 
COLOR 0A
:cloneBegin
rem *初始化引數.*
set gitUser="" 
set gitPwd=""
set gitUrl=""
set gitBranch=""
set gitCommit=""
set gitProjectName=""
set cloneStr=""
set /a index=0
set cloneRootPath=""
set cloneBranchPath=""
set cloneCommitPath=""
set currentGitName=""
set /a status=0
set /a mailIndex=0
rem *從git-config檔案中逐行讀取配置資訊，並將專案及其依賴庫拉去至本地.*
for /f "tokens=1-6 delims==|" %%a in (git-config.txt) do (
	rem *初始化引數.*
	set "gitUser=%%a"
	set "gitPwd=%%b"
	set "gitUrl=%%c"
	set "gitBranch=%%d"
	set "gitCommit=%%e"
	rem *轉義@字元.*
	set gitUser=!gitUser:@=%%40!
	set gitUrl=!gitUrl:https://=!
	set gitUrl=!gitUrl:http://=!
	rem *生成git clone的指令.*
	set cloneStr=http://!gitUser!:
 
[email protected]!gitUrl! -b !gitBranch!
	set "currentGitName=%%f"
	
	echo !cloneStr!
	
	if !index! EQU 0 (
		set "gitProjectName=%%f"
		echo ***************!currentGitName! start clone...***************
		rem *拉去主專案到當前目錄下的專案名目錄下.*
		git clone !cloneStr! ./!gitProjectName!
	) else (
		echo ***************!currentGitName! start clone...***************
		cd !gitProjectName!
		rem *拉去依賴專案到主專案目錄下的依賴庫名目錄下.*
		git clone !cloneStr! ./!currentGitName!
		rem *dp0 表示當前該bat檔案的目錄下.*
		cd %~dp0
	)
	rem *設定當前專案的build.gradle路徑以及其分支名與提交記錄路徑.*
	if !index! EQU 0 (
		set "cloneRootPath=%~dp0!gitProjectName!\build.gradle"
		set "cloneBranchPath=%~dp0!gitProjectName!\.git\HEAD"
		set "cloneCommitPath=%~dp0!gitProjectName!\.git\refs\heads\!gitBranch!"
	) else (
		set "cloneRootPath=%~dp0!gitProjectName!\%%f"
		set "cloneBranchPath=%~dp0!gitProjectName!\%%f\.git\HEAD"
		set "cloneCommitPath=%~dp0!gitProjectName!\%%f\.git\refs\heads\!gitBranch!"
	)
	rem *判斷當前專案是否拉取成功，其分支與當前所處提交記錄是否正確*
	if exist !cloneRootPath! (
		echo *******!currentGitName! clone complete...*******
	 	find /i "!gitBranch!" !cloneBranchPath! && (
	 		echo *******!currentGitName! clone branch correctly...*******
			if "!gitCommit!"==" " (
				echo *******!currentGitName! clone latest commit correctly...*******
			)||(
				find /i "!gitCommit!" !cloneCommitPath! && (
					echo *******!currentGitName! clone seleteced commit correctly...*******
				)||(
					if !index! EQU 0 (
						cd %~dp0!gitProjectName!
					) else (
						cd %~dp0!gitProjectName!\!currentGitName!
					)
					rem *更改分支*
					git reset --hard !gitCommit!
					cd %~dp0
					find /i "!gitCommit!" !cloneCommitPath! && (
						echo *******!currentGitName! clone seleteced commit correctly...*******
					)||(
						echo *******!currentGitName! clone seleteced commit failed...*******
						rem rd /s /q %~dp0!gitProjectName!
						goto cloneError
					)
				)
			)
	 	)||(
	 		echo *******!currentGitName! clone branch failed...*******
			rem rd /s /q %~dp0!gitProjectName!
			goto cloneError
	 	)
	 ) else (
	 	echo *******!gitProjectName! clone failed, please try again...*******
		rem rd /s /q %~dp0!gitProjectName!
		goto cloneError
	 )
	 set /a index+=1
)
rem *編譯專案.*
if exist !cloneRootPath! (
	cd !gitProjectName!
	:buildApk
	gradle assembleRelease
	rem *after call other batch such as gradle, turn echo off to make command disappear.*
	@echo off & setlocal enabledelayedexpansion 
	rem *編譯完成的後續處理bat檔案.*
	call build-after.bat
	PAUSE
) else (
	:cloneError
	rem *錯誤處理，列印當前的資訊判斷是否配置錯誤，修改錯誤的配置資訊後按回車重新開始編譯.*
	echo *******!gitProjectName! clone failed, there are your configs in !currentGitName! as follow:*******
	echo        *******gitUser=!gitUser!*******
	echo        *******gitPwd=!gitPwd!*******
	echo        *******gitUrl=!gitUrl!*******
	echo        *******gitBranch=!gitBranch!*******
	echo        *******gitCommit=!gitCommit!*******
	echo        *******repositoryName=!currentGitName!*******
	echo *******please check for errors and correct them, press any key to reclone after all*******
	PAUSE
	goto :cloneBegin
)
PAUSE
 

四、編譯後bat檔案內容

該檔案在上一個bat檔案末尾自動呼叫，也可在編譯後直接執行，判斷是否編譯成功，若編譯成功則呼叫blat工具傳送郵件到指定給指定的收件人。

@echo off & setlocal enabledelayedexpansion 
set status=0
set sendUser=""
set sendPwd=""
set mailTitle=""
set mailContent=""
set /a mailIndex=0
cd %~dp0
rem *從git-config檔案中讀取主專案名.*
for /f "tokens=1-6 delims==|" %%a in (git-config.txt) do (
	if !status! EQU 0 (
		set status=1
		rem *判斷主專案名是否編譯成功.*
		if exist %~dp0%%f\app\build\outputs\apk\app-release.apk (
			echo *******%%f build success*******
			rem *生成當前時間.*
			set time=%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%
			rem *重新命名生成的apk檔案，並將其移至指定目錄.*
			ren %~dp0%%f\app\build\outputs\apk\app-release.apk %%f_1.0.0_!time!.apk
			move %~dp0%%f\app\build\outputs\apk\%%f_1.0.0_!time!.apk %~dp0
			rd /s /q %~dp0%%f
			rem *逐行讀取郵件配置檔案內容，最後呼叫blat傳送郵件給每個收件人.*
			for /f "" %%a in (mail-config.txt) do (
				if !mailIndex! EQU 0 (
					set "sendUser=%%a"
				)
				if !mailIndex! EQU 1 (
					set "sendPwd=%%a"
				)
				if !mailIndex! EQU 2 (
					set "mailTitle=%%a"
				)
				if !mailIndex! EQU 3 (
					set "mailContent=%%a"
				)
				if !mailIndex! GTR 3 (
					blat -body "!mailContent!" -to %%a -s "!mailTitle!" -u !sendUser! -pw !sendPwd! -charset UTF-8
				)
				set /a mailIndex+=1
			)
		) else (
			echo *******%%f build failed*******
			echo *******please check for errors and correct them, press any key to rebuild after all*******
			PAUSE
		)
	)
)
PAUSE

五、結尾

寫這個自動化編譯工具時自己對bat語言一無所知，gradle、blat這些工具也是邊做邊學，但是主要難度還是在於bat的編寫上，有時候一條語句就要琢磨個半天，而且由於所花時間有限，寫的工具只能算是勉強能用，若要談到良好的體驗那肯定是差之甚遠，有興趣的朋友可以自己拿去優化優化然後分享出來，也可以大家一起交流討論，如果有看得上想要轉載的朋友請註明一下本部落格出處，多謝。