2. 程式人生 > >VB.net操作oracle資料庫

VB.net操作oracle資料庫

阿新 • • 發佈：2019-02-08

特鬱悶的一件事情，費時費力！記下來，為後來者鋪路。

首先，我用VS2010開發對oracle10g資料庫的操作，結果發現微軟自帶的System.Data.OracleClient已經有一些常用物件提示過時；網上說最好用oracle自帶的ODP.net操作。

我到oracle網站下載ODAC這個安裝包，還註冊了使用者名稱，200多M，而且下載特慢，下載後結果是除錯了很久都不行。

其次，問用oracle的同事，告訴我安裝了oracle客戶端後在安裝目錄下有ODP.net的DLL，直接引用那個就OK了；我在我的oracle客戶端安裝錄D:\oracle\product\10.2.0\db_1\BIN下真的還找到了 Oracle.DataAccess.dll。

最後，VS2010的vb.net工程中引用這個dll,編寫對遠端oracle資料庫的操作測試，通過！

寫這麼多隻是因為忒鬱悶！我喜歡開源mysql、sqlite；還沒有自己創業，給別人打工不自由啊，只能按照專案要求來。鬱悶！！！

'引入oracle本身提供的.net資料引擎


Imports System
Imports System.Collections.Generic
Imports System.Text
Imports System.Data
Imports System.Xml
Imports System.Collections
Imports Oracle.DataAccess
Imports Oracle.DataAccess.Server
Imports Oracle.DataAccess.Client
Imports Oracle.DataAccess.Types




'引入開源日誌類庫
Imports log4net
Public Class OracleDbOperations
    '定義日誌物件 OracleHelper.Logging
    'Private Shared Log As log4net.ILog = log4net.LogManager.GetLogger(System.Reflection.MethodBase.GetCurrentMethod().DeclaringType)
    Private Shared Log As log4net.ILog = log4net.LogManager.GetLogger("OracleHelper.Logging")
    '資料庫連線物件
    Dim Conn As OracleConnection = Nothing
    '事務處理物件
    Dim Trans As OracleTransaction = Nothing
    '資料庫連線字串
    Dim ConnectionStr As String = Nothing
    '建構函式
    Sub New(ByVal ConnStr As String)
        ConnectionStr = ConnStr
        Conn = New OracleConnection(ConnectionStr)
    End Sub
    ''' <summary>
    ''' 關閉資料庫連線
    ''' </summary>
    ''' <returns>布林值</returns>
    ''' <remarks>成功關閉返回true;否則返回false</remarks>
    Public Function ConnClose() As Boolean
        Try
            If Conn.State <> ConnectionState.Closed Then
                Conn.Close()
                Conn.Dispose()
                Conn = Nothing
                Log.Info("資料庫關閉連線成功！")
                Return True
            End If
        Catch ex As Exception
            '寫日誌
            Log.Error("資料庫關閉連線失敗！")
        End Try
        Return False
    End Function
    ''' <summary>
    ''' 開啟資料庫連線
    ''' </summary>
    ''' <returns>布林值</returns>
    ''' <remarks>成功關閉返回true;否則返回false</remarks>
    Public Function ConnOpen() As Boolean
        Try
            If Conn.State <> ConnectionState.Open Then
                Conn.Open()
                Log.Info("資料庫開啟連線成功！")
                Return True
            End If
        Catch ex As Exception
            '寫日誌
            Log.Error("資料庫開啟連線失敗！")
        End Try
        Return False
    End Function
    ''' <summary>
    ''' 執行SQL語句或者儲存過程（對於輸入輸出引數值為nothing的欄位進行特殊處理為DBNull.Value）；此為查詢型別，不提供事務處理支援
    ''' </summary>
    ''' <param name="cmdType">執行型別</param>
    ''' <param name="cmdText">執行文字</param>
    ''' <param name="params">輸入輸出引數資訊</param>
    ''' <returns>返回影響的行數</returns>
    ''' <remarks></remarks>
    Public Function ExecuteNoneQuery(ByVal cmdType As CommandType, ByVal cmdText As String, ByVal params As OracleParameter()) As Integer
        Dim rows As Integer = 0
        Try
            If ConnOpen() Then
                Dim cmd As New OracleCommand
                cmd.Connection = Conn
                cmd.CommandType = cmdType
                cmd.CommandText = cmdText
                '有引數時
                If params IsNot Nothing AndAlso params.Length > 0 Then
                    For Each p As OracleParameter In params
                        '對NULL值的引數資料進行特殊處理（VB中對NULL賦值為Nohting）
                        If p.Direction = ParameterDirection.InputOutput AndAlso p.Value Is Nothing Then
                            p.Value = DBNull.Value
                        End If
                        cmd.Parameters.Add(p)
                    Next
                End If
                rows = cmd.ExecuteNonQuery()
                '清理資源
                cmd.Parameters.Clear()
                cmd.Dispose()
                cmd = Nothing
                '關閉連線
                ConnClose()
            Else
                '寫日誌
                Log.Error("資料庫開啟連線失敗！")
            End If
        Catch ex As Exception
            '寫日誌
            Log.Error("<" & cmdText & ">執行ExecuteNonQuery出現異常！")
        End Try
        Return rows
    End Function
    ''' <summary>
    ''' 執行SQL語句或者儲存過程（對於輸入輸出引數值為nothing的欄位進行特殊處理為DBNull.Value）；此為增刪改，提供事務處理支援
    ''' </summary>
    ''' <param name="cmdType">執行型別</param>
    ''' <param name="cmdText">執行文字</param>
    ''' <param name="params">輸入輸出引數資訊</param>
    ''' <returns>返回影響的行數</returns>
    ''' <remarks></remarks>
    Public Function ExecuteNoneQueryTrans(ByVal cmdType As CommandType, ByVal cmdText As String, ByVal params As OracleParameter()) As Integer
        Dim rows As Integer = 0
        Try
            If ConnOpen() Then
                Trans = Conn.BeginTransaction
                Dim cmd As New OracleCommand
                cmd.Connection = Conn
                cmd.CommandType = cmdType
                cmd.CommandText = cmdText
                '有引數時
                If params IsNot Nothing AndAlso params.Length > 0 Then
                    For Each p As OracleParameter In params
                        '對NULL值的引數資料進行特殊處理（VB中對NULL賦值為Nohting）
                        If p.Direction = ParameterDirection.InputOutput AndAlso p.Value Is Nothing Then
                            p.Value = DBNull.Value
                        End If
                        cmd.Parameters.Add(p)
                    Next
                End If
                rows = cmd.ExecuteNonQuery()
                Trans.Commit()
                '清理資源
                Trans.Dispose()
                Trans = Nothing
                cmd.Parameters.Clear()
                cmd.Dispose()
                cmd = Nothing
                '關閉連線
                ConnClose()
            Else
                '寫日誌
                Log.Error("資料庫開啟連線失敗！")
            End If
        Catch ex As Exception
            '寫日誌
            Log.Error("<" & cmdText & ">執行ExecuteNonQuery出現異常！")
            If IsNothing(Trans) = False Then
                Trans.Rollback()
                Trans.Dispose()
                Trans = Nothing
            End If
        End Try
        Return rows
    End Function


    ''' <summary>
    ''' 返回記錄集
    ''' </summary>
    ''' <param name="DsTable">記錄集中表名</param>
    ''' <param name="cmdType">型別</param>
    ''' <param name="cmdText">文字</param>
    ''' <param name="params">輸入輸出引數</param>
    ''' <returns>返回dateset或者nothing</returns>
    ''' <remarks>必須首先判斷返回值是否是nothing</remarks>
    Public Function ExecuteDataSet(ByVal DsTable As String, ByVal cmdType As CommandType, ByVal cmdText As String, ByVal params As OracleParameter()) As DataSet
        Dim ds As DataSet = Nothing
        Try
            If ConnOpen() Then
                Dim cmd As New OracleCommand
                cmd.Connection = Conn
                cmd.CommandType = cmdType
                cmd.CommandText = cmdText
                '有引數時
                If params IsNot Nothing AndAlso params.Length > 0 Then
                    For Each p As OracleParameter In params
                        '對NULL值的引數資料進行特殊處理（VB中對NULL賦值為Nohting）
                        If p.Direction = ParameterDirection.InputOutput AndAlso p.Value Is Nothing Then
                            p.Value = DBNull.Value
                        End If
                        cmd.Parameters.Add(p)
                    Next
                End If
                Dim da As New OracleDataAdapter(cmd)
                ds = New DataSet
                da.Fill(ds, DsTable)
                '清理資源
                cmd.Parameters.Clear()
                cmd.Dispose()
                cmd = Nothing
                da.Dispose()
                da = Nothing
                '關閉連線
                ConnClose()
            Else
                '寫日誌
                Log.Error("資料庫開啟連線失敗！")
            End If
        Catch ex As Exception
            '寫日誌
            Log.Error("<" & cmdText & ">執行ExecuteDataSet出現異常！")
        End Try
        Return ds
    End Function
    ''' <summary>
    ''' 返回XmlReader
    ''' </summary>
    ''' <param name="cmdType">型別</param>
    ''' <param name="cmdText">文字</param>
    ''' <param name="params">輸入輸出引數</param>
    ''' <returns>返回 或者nothing</returns>
    ''' <remarks>注意：呼叫該方法後，一定要對XmlReader進行Close</remarks>
    Public Function ExecuteXmlReader(ByVal cmdType As CommandType, ByVal cmdText As String, ByVal params As OracleParameter()) As XmlReader
        Dim dr As XmlReader = Nothing
        Try
            If ConnOpen() Then
                Dim cmd As New OracleCommand
                cmd.Connection = Conn
                cmd.CommandType = cmdType
                cmd.CommandText = cmdText
                '有引數時
                If params IsNot Nothing AndAlso params.Length > 0 Then
                    For Each p As OracleParameter In params
                        '對NULL值的引數資料進行特殊處理（VB中對NULL賦值為Nohting）
                        If p.Direction = ParameterDirection.InputOutput AndAlso p.Value Is Nothing Then
                            p.Value = DBNull.Value
                        End If
                        cmd.Parameters.Add(p)
                    Next
                End If
                '執行
                dr = cmd.ExecuteXmlReader
                '清理資源
                cmd.Parameters.Clear()
                cmd.Dispose()
                cmd = Nothing
            Else
                '寫日誌
                Log.Error("資料庫開啟連線失敗！")
            End If
        Catch ex As Exception
            '寫日誌
            Log.Error("<" & cmdText & ">執行ExecuteXmlReader出現異常！")
        End Try
        Return dr
    End Function


    ''' <summary>
    ''' 執行SQL語句或者儲存過程（對於輸入輸出引數值為nothing的欄位進行特殊處理為DBNull.Value）；此為查詢型別，不提供事務處理支援
    ''' </summary>
    ''' <param name="cmdType">執行型別</param>
    ''' <param name="cmdText">執行文字</param>
    ''' <param name="params">輸入輸出引數資訊</param>
    ''' <returns>返回一個object型別的結果</returns>
    ''' <remarks>對返回值進行ctype()型別裝換後使用</remarks>
    Public Function ExecuteScalar(ByVal cmdType As CommandType, ByVal cmdText As String, ByVal params As OracleParameter()) As Object
        Dim Result As Object = 0
        Try
            If ConnOpen() Then
                Dim cmd As New OracleCommand
                cmd.Connection = Conn
                cmd.CommandType = cmdType
                cmd.CommandText = cmdText
                '有引數時
                If params IsNot Nothing AndAlso params.Length > 0 Then
                    For Each p As OracleParameter In params
                        '對NULL值的引數資料進行特殊處理（VB中對NULL賦值為Nohting）
                        If p.Direction = ParameterDirection.InputOutput AndAlso p.Value Is Nothing Then
                            p.Value = DBNull.Value
                        End If
                        cmd.Parameters.Add(p)
                    Next
                End If
                Result = cmd.ExecuteScalar()
                '清理資源
                cmd.Parameters.Clear()
                cmd.Dispose()
                cmd = Nothing
                '關閉連線
                ConnClose()
            Else
                '寫日誌
                Log.Error("資料庫開啟連線失敗！")
            End If
        Catch ex As Exception
            '寫日誌
            Log.Error("<" & cmdText & ">執行ExecuteScalar出現異常！")
        End Try
        Return Result
    End Function


    ''' <summary>
    ''' 返回datareader
    ''' </summary>
    ''' <param name="cmdType">型別</param>
    ''' <param name="cmdText">文字</param>
    ''' <param name="params">輸入輸出引數</param>
    ''' <returns>返回 或者nothing</returns>
    ''' <remarks>注意：呼叫該方法後，一定要對OracleDataReader進行Close</remarks>
    Public Function ExecuteDataReader(ByVal cmdType As CommandType, ByVal cmdText As String, ByVal params As OracleParameter()) As OracleDataReader
        Dim dr As OracleDataReader = Nothing
        Try
            If ConnOpen() Then
                Dim cmd As New OracleCommand
                cmd.Connection = Conn
                cmd.CommandType = cmdType
                cmd.CommandText = cmdText
                '有引數時
                If params IsNot Nothing AndAlso params.Length > 0 Then
                    For Each p As OracleParameter In params
                        '對NULL值的引數資料進行特殊處理（VB中對NULL賦值為Nohting）
                        If p.Direction = ParameterDirection.InputOutput AndAlso p.Value Is Nothing Then
                            p.Value = DBNull.Value
                        End If
                        cmd.Parameters.Add(p)
                    Next
                End If
                '執行
                dr = cmd.ExecuteReader(CommandBehavior.CloseConnection)
                '清理資源
                cmd.Parameters.Clear()
                cmd.Dispose()
                cmd = Nothing
            Else
                '寫日誌
                Log.Error("資料庫開啟連線失敗！")
            End If
        Catch ex As Exception
            '寫日誌
            Log.Error("<" & cmdText & ">執行ExecuteDataReader出現異常！")
        End Try
        Return dr
    End Function






End Class

相關推薦

VB.net操作oracle資料庫

特鬱悶的一件事情，費時費力！記下來，為後來者鋪路。 首先，我用VS2010開發對oracle10g資料庫的操作，結果發現微軟自帶的System.Data.OracleClient已經有一些常用物件提示過時；網上說最好用oracle自帶的ODP.net操作。 我到oracle

基於VB.Net的SQL資料庫操作

 本人是根據自己的經歷，將有基於VB.Net的資料庫的操作整理如下，或許不是很完整，後面有機會再補充。現將程式碼裡面的大概內容敘述一下： New(connectstr)方法是建立帶引數的SQLDataBase的例項； UpdateSQL(updatecmd)方法是執行up

.NET/C#/Oracle資料庫操作類

using System; using System.Data; using System.Collections.Generic; using System.Configuration; using System.Data.OracleClient;

在.NetCore(C#)中使用ODP.NET Core+Dapper操作Oracle資料庫

## 前言 雖然一直在說“去IOE化”，但是在國企和政府，Oracle的歷史包袱實在太重了，甚至很多業務邏輯都是寫在Oracle的各種儲存過程裡面實現的…… 我們的系統主要的技術棧是Django / Spring / AspNetCore，Java的不必說對Oracle支援肯定沒問題，關鍵在於Djang

C# /VB.NET 操作Word——插入、修改、刪除Word批註

C# .NET Word API Word批註 VB.NET 類庫 批註內容可以是對某段文字或內容的註釋，也可以是對文段中心思想的概括提要，或者是對文章內容的評判、疑問，以及在閱讀時給自己或他人起到提示作用。本篇文章中將介紹如何在C#/VB中操作Word批註，主要包含以下要點: 插入Wo

使用批處理檔案批量操作Oracle資料庫

最近，因為業務需要，需要做個批處理檔案，雙擊後，能夠遠端執行一些SQL語句。適合沒有任何資料庫基礎的人使用。查了相關文件，做了個簡單的例子，一共有3個檔案，insert.bat,insert.sql ,log1.txt. 其中insert.bat 這個檔案是批處理，雙擊會執行，或者

利用oracle官網提供的occi庫在windows下操作oracle資料庫

1、先前用occi操作oracle資料庫都是失敗，後來發現是我下載的庫版本和對應的dll版本不一致導致：如32庫， 卻下載了64位的dll，因此導致在初始化環境就失敗，百思不得其解。 2、在下載好對應的32位庫和32位dll，可以正常初始化環境，操作oracle資料庫。 3、只需下載2個檔案

Python操作Oracle資料庫時出現ImportError libclntsh so 10 1 cannot o

分享一下我老師大神的人工智慧教程！零基礎，通俗易懂！http://blog.csdn.net/jiangjunshow 也歡迎大家轉載本篇文章。分享知識，造福人民，實現我們中華民族偉大復興！        

QT操作Oracle資料庫(事務、儲存過程)

QT操作Oracle資料庫可以使用QODBC、QOCI兩種驅動，這裡使用QODBC驅動。在使用QOCI驅動操作oracle時，事務不能回滾，可能是我編譯的QOCI驅動有問題，但是暫時沒有找到原因。 #ifndef QTTEST_H #define QTTEST_H #include <

JDBC操作Oracle資料庫前期準備及程式設計初體驗

第一步：前期準備 (1).首先需要獲取到所使用資料的驅動jar包，比如Oracle，在安裝好Oracle11g桌面版後，其已經自帶了orcale的jdbc了。我的電腦在安裝目錄：C:\app\youmingke\product\11.2.0\dbhome_1\jdbc\lib，下面有ojdbc5

nodejs操作oracle資料庫簡單封裝-node-oracledb模組

一 安裝模組 npm install oracledb 官方文件：https://www.npmjs.com/package/oracledb 二 安裝免費的Oracle Instant Client ZIP 如果資料庫位於遠端計算機上，請執行以下步驟。其他條件請見

使用LabVIEW通過動態連結庫DLL遠端操作Oracle資料庫

很多情況下，遠端操作資料庫時，需要在不裝Oracle客戶端的情況下進行，儘可能降低客戶端安裝各類軟體的時間。 首先我們從網上下載Oracle資料庫操作dll檔案。 動態連結庫通過ildasm.exe反彙編檢視，這個檔案是.net 4.0版本的封裝檔案。 在LabVI

ASP.Net操作Access資料庫總結

1、資料庫的連線 引入名稱空間 using System.Data; using System.Data.OleDb; 連線程式碼：    string strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;";      

ASP.NET操作mysql資料庫的例項（傻瓜都能看懂，已測試過）

一、把MySql.Data.dll放到BIN目錄下。二、這是aspx.cs的全部原始碼，修改引數直接執行即可！using MySql.Data.MySqlClient; using System; using System.Collections.Generic; usin

用shell命令操作oracle資料庫

啟動步驟：注意$代表shell命令提示符，這裡的oracle是9.0以上版本。   1.$ su - oracle  2.$ sqlplus / nolog  3.sql> conn / as sysdba  4.sql> startup (一般不需要加引數，只要設定好環境變數）  5.sql&g

用C# 來操作ORACLE 資料庫

   /// <summary>    /// 執行SQL語句，返回影響的記錄數    /// </summary>    /// <param name="SQLString">SQL語句</param>    /// <returns>影響的記錄

jpa操作oracle資料庫報SQL命令未正確結束

springboot專案，連線oracle資料庫，用自帶PagingAndSortingRepository<Data,  String>進行資料分頁，專案可以正常啟動，但是分頁資料無法重新整理，後臺報sql命令 未正確結束 註釋掉自帶分頁程式碼，使用sql語句可以

使用plsql操作oracle資料庫小技巧之儲存使用者名稱和密碼

每次plsql連線資料庫，輸入使用者名稱密碼很煩，直接點選儲存好的使用者名稱密碼： 步驟： 1、點選plsql的preferneces首選項，進入首選項視窗， 2、找到oracle項，下面有logon history，登入歷史， 3、點選登入歷史項，找到fixed U

ASP.NET 操作MySQL資料庫的方法說明

using System;using System.Data;using System.Diagnostics;using System.Collections.Generic;using MySql.Data.MySqlClient; namespace System{ /// &l

vb.net操作excel彙集

Dim xl As New Excel.Application Dim xlBook As Excel.Workbook = xl.Workbooks.Open(strSaveExcelFile) Dim xlSheet As