2. 程式人生 > >ARM處理器架構-----異常/中斷處理

ARM處理器架構-----異常/中斷處理

阿新 • • 發佈：2018-12-31

中斷是我們嵌入式開發很常用到的一種資源和程式設計手段。這篇文章重點分析arm的中斷處理流程。

 首先，中斷是異常的一種。當發生一種異常時，處理器會進入不同的工作模式。ARM的異常和相應的模式之間的對應關係見下表:

當一個異常導致模式的改變時,ARM核自動地:

1、把cpsr儲存到相應模式下的spsr

2、把pc儲存到相應模式下的lr

3、設定cpsr為相應異常模式

4、設定pc為相應異常處理程式的入口地址

對於IRQ或者FIQ而言,還多一項變化:禁用相關的中斷IRQ或FIQ,禁止同類型的其他中斷被觸發。（這也是自動實現的，因此正常情況下，ARM中斷不可巢狀）

從異常中斷處理程式退出時，需要我們在程式中用軟體實現下面兩個操作

:

1、從spsr_mode中恢復資料到cpsr中

2、從lr_mode中恢復內容到pc中,返回到異常中斷的指令的下一條政令處執行.

2440預設的有一個異常向量表，即發生某一個異常後，會根據異常向量表設定pc為相應的處理函式入口地址。

地址

異常名稱

指令

0x00

復位異常

B  RestHandler

0x04

未定義指令異常

B  HandlerUndef

0x08

軟體中斷異常

B  HandlerSWI

0x0C

指令預取異常

B  HandlerPabort

0x10

資料預取異常

B  HandlerDabort

0x14

保留

0x18

IRQ中斷異常

B  HandlerIRQ

0x1C

FIQ中斷異常

B  HandlerFIQ

上表中的 指令都是在2440init.s中的程式表示。

下面，我們結合板子自帶的2440test原始碼中的2440init.s中的異常處理，來分析arm中斷處理的實現。

首先，在2440init.s中有：

__ENTRY
	b	ResetHandler
	b	HandlerUndef	;handler for Undefined mode
	b	HandlerSWI	    ;handler for SWI interrupt
	b	HandlerPabort	;handler for PAbort
	b	HandlerDabort	;handler for DAbort
	b	.		        ;reserved
	b	HandlerIRQ	;handler for IRQ interrupt
	b	HandlerFIQ	;handler for FIQ interrupt

這裡就是相應的 異常處理向量表。程式正常啟動就跳轉到resethandler，如果是發生中斷就跳轉到handlerIRQ。對於handlerIRQ，它是用一個巨集實現的。

MACRO
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel
	sub	sp,sp,#4	;decrement sp(to store jump address)
	stmfd	sp!,{r0}	;PUSH the work register to stack(lr does't push because it return to original address)
	ldr     r0,=$HandleLabel;load the address of HandleXXX to r0
	ldr     r0,[r0]	 ;load the contents(service routine start address) of HandleXXX
	str     r0,[sp,#4]      ;store the contents(ISR) of HandleXXX to stack
	ldmfd   sp!,{r0,pc}     ;POP the work register and pc(jump to ISR)
	MEND
上面是巨集的宣告。下面是具體用到巨集的地方。
HandlerFIQ      HANDLER HandleFIQ
HandlerIRQ      HANDLER HandleIRQ
HandlerUndef    HANDLER HandleUndef
HandlerSWI      HANDLER HandleSWI
HandlerDabort   HANDLER HandleDabort
HandlerPabort   HANDLER HandlePabort
上面的這段程式在編譯的時候會被編譯器展開，我們可以將其中的IRQ相關的展開如下：

HandlerIRQ   HANDLER  HandleIRQ 會被下面的程式碼段替換：

HandlerIRQ	
	sub	sp,sp,#4	;decrement sp(to store jump address)
	stmfd	sp!,{r0}	;PUSH the work register to stack(lr does''t push because it return to original address)
	ldr     r0,=HandleIRQ   ;load the address of HandleXXX to r0
	ldr     r0,[r0]	        ;load the contents(service routine start address) of HandleXXX
	str     r0,[sp,#4]      ;store the contents(ISR) of HandleXXX to stack
	ldmfd   sp!,{r0,pc}     ;POP the work register and pc(jump to ISR)

因此，發生中斷時，就會b HandlerIRQ，跳轉到上面的程式碼進行執行。按照上面的流程，處理器會把HandleIRQ地址中所儲存的數 付給pc指標，作為下一條指令的地址，然後執行。那麼HandleIRQ地址中儲存的數是什麼呢？

在2440init.s中有這樣一段程式：

ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ    ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0]
從這裡，可以看出，HandleIRQ中存的是IsrIRQ。所以處理器會跳轉到isrIRQ中執行。 
IsrIRQ
	sub	sp,sp,#4       ;reserved for PC
	stmfd	sp!,{r8-r9}

	ldr	r9,=INTOFFSET
	ldr	r9,[r9]
	ldr	r8,=HandleEINT0
	add	r8,r8,r9,lsl #2
	ldr	r8,[r8]
	str	r8,[sp,#8]
	ldmfd	sp!,{r8-r9,pc}

在上面的程式中，INTOFFSET表示的是中斷號對於EINT0的偏移號。這樣計算得到中斷向量號之後，跳轉到中斷函式進行處理。對於，上面的程式奇怪的一點是沒有看到恢復cpsr和pc指標。因此，可以推斷，對於中斷函式在ADS中有特殊的宣告方式，如：static void __irq Uart_DMA_ISR(void)。像這種宣告方式，在編譯的時候，編譯器會自動在函式的末尾新增恢復cpsr和pc的語句。另外， 暫存器r0-r12也是需要保護的，因為在中斷函式和原來的上下文中都會用到，所以，我認為 編譯器在中斷處理函式中對r0-r12也進行了保護和恢復。

另外，在ucosII中，對IsrIRQ函式進行了修改，我們後面再進行分析。

另外，我們用軟體實現了一套中斷向量表：

ALIGN
	AREA RamData, DATA, READWRITE
	^   _ISR_STARTADDRESS		; _ISR_STARTADDRESS=0x33FF_FF00
HandleReset 	#   4
HandleUndef 	#   4
HandleSWI	#   4
HandlePabort    #   4
HandleDabort    #   4
HandleReserved  #   4
HandleIRQ	#   4
HandleFIQ	#   4

;Don''t use the label 'IntVectorTable',
;The value of IntVectorTable is different with the address you think it may be.
;IntVectorTable
;@0x33FF_FF20
HandleEINT0		#   4
HandleEINT1		#   4
HandleEINT2		#   4
HandleEINT3		#   4
HandleEINT4_7	#   4
HandleEINT8_23	#   4
HandleCAM		#   4		; Added for 2440.
HandleBATFLT	#   4
HandleTICK		#   4
HandleWDT		#   4
HandleTIMER0 	#   4
HandleTIMER1 	#   4
HandleTIMER2 	#   4
HandleTIMER3 	#   4
HandleTIMER4 	#   4
HandleUART2  	#   4
;@0x33FF_FF60
HandleLCD 		#   4
HandleDMA0		#   4
HandleDMA1		#   4
HandleDMA2		#   4
HandleDMA3		#   4
HandleMMC		#   4
HandleSPI0		#   4
HandleUART1		#   4
HandleNFCON		#   4		; Added for 2440.
HandleUSBD		#   4
HandleUSBH		#   4
HandleIIC		#   4
HandleUART0 	#   4
HandleSPI1 		#   4
HandleRTC 		#   4
HandleADC 		#   4
;@0x33FF_FFA0
之前，我們在發生中斷時，pc指標就跳轉到了 HandleIRQ地址中所儲存的數 出執行。也就是說在HandleIRQ中存的是異常處理函式的入口地址。這就是異常處理向量表的作用。
所以，我們可以看出，對於2440init.s實現的異常處理，採用的是兩級向量表機制。 第一級向量表是arm核自己實現的，發生相應的異常時，pc指標跳轉到0x18地址中存的數，作為入口地址。 第二級向量表是由Handler巨集實現的，繼續跳轉到 HandleIRQ地址中存的數，繼續執行。 

而對於IRQ來講，還有第三級的向量表，在IsrIRQ中，又會根據中斷號，比如uart2的中斷，跳轉到 HandleUart2地址中 存的數，繼續執行。

在2440init.s中，並沒有給HandleUndef等這些地址處賦值，因此，一旦執行到，程式就會跑飛。

相關推薦

ARM處理器架構-----異常/中斷處理

中斷是我們嵌入式開發很常用到的一種資源和程式設計手段。這篇文章重點分析arm的中斷處理流程。  首先，中斷是異常的一種。當發生一種異常時，處理器會進入不同的工作模式。ARM的異常和相應的模式之間的對應關係見下表: 當一個異常導致模式的改變時,ARM核自動地:

3.ARM異常中斷處理及程式設計

ARM異常中斷處理概述： ARM異常中斷處理包括響應中斷、處理中斷、中斷返回等操作。 所以說當ARM異常中斷產生的時候，CPU在執行完當前指令後，PC跳轉到要執行的中斷處理程式處執行，執行完後再返回開

ARM異常中斷處理概述

1．中斷的概念 什麼是中斷，我們從一個生活中的例子引入。你正在家中看書，突然電話鈴響了，你放下書本，去接電話，和來電話的人交談，然後放下電話，回來繼續看你的書。這就是生活中的“中斷”的現象，就是正常的工作過程被外部的事件打斷了。 在處理器中，所謂中斷，是一個過程，即CPU在正常執行程式的過程中，遇到外部／內

Linux異常中斷處理結構

核心在start_kernel()函式（init/main.c）中會呼叫trap_init()個函式來設定異常的處理函式。 1、trap_init()函式 /* * Copy the vectors, stubs and kuser helpers (in entry

2.ARM中的異常中斷基本概念

ARM中的異常和中斷： 基本概念： 異常和中斷都是處理系統中突發事件的機制，請求處理器打斷正常的程式執行流程，進入特定的處理或服務程式。 異常是一種ARM處理器模式分類： * ARM處理器有七種執行模

ARM流水線與異常中斷返回的幾種情況

重要基礎知識：R15（PC）總是指向“正在取指”的指令，而不是指向“正在執行”的指令或正在“譯碼”的指令。一般來說，人們習慣性約定將“正在執行的指令作為參考點”，稱之為當前第一條指令，因此 PC總是指向第三條指令。當 ARM 狀態時，每條指令為 4 位元組長，所以 PC 始

Arm架構異常處理流程之中斷

arch/arm64/kernel/entry.s:    el0_sync()/el0_irq() -> ret_to_user() -> work_pending() -> do_notify_resume()               // (1) 在arm64架構中，kernel執

ARM處理器異常處理

1.1 處理器異常處理 所謂異常就是正常的使用者程式被暫時中止，處理器就進入異常模式，例如響應一個來自外設的中斷，或者當前程式非法訪問記憶體地址都會進入相應異常模式。 1.1.1  異常分類 （1）復位異常 當CPU剛上電時或按下reset重啟鍵之後進入該異常，該異常在

Arm架構異常處理流程之缺頁異常

【摘要】 本文將為您介紹linux核心是如何實現缺頁異常處理的。缺頁異常、中斷和系統呼叫同屬arm異常處理，筆者計劃分三篇文件分別介紹一下，其實在彙編階段三種處理流程有很多相通之處，不過為了閱讀方便，即使相同的部分也會重新在各自文件中介紹一遍。 【背景】 本部分簡單介紹下為何要寫此文？ 1開發除錯工具：

ARM異常處理（IRQ中斷處理）總結1

之間 roc 圖片 寫法 stack cat 舉例 log 地址 ARM A8的異常處理表如下可以看到vector table的基地址是不固定的但是所有異常的偏移地址是固定的。這張表也為了體現這個偏移量，還有要從硬件角度理解的是在CPU設計的時候這些異常就已經定義好了在發生

Linux中斷 - ARM中斷處理過程

thum nio cti abort 兩個 alloc pos 不同 eve 一、前言 本文主要以ARM體系結構下的中斷處理為例，講述整個中斷處理過程中的硬件行為和軟件動作。具體整個處理過程分成三個步驟來描述： 1、第二章描述了中斷處理的準備過程 2、第三章描述了當發生中的

ARM異常 中斷以及他們的向量表分析

分享一下我老師大神的人工智慧教程！零基礎，通俗易懂！http://blog.csdn.net/jiangjunshow 也歡迎大家轉載本篇文章。分享知識，造福人民，實現我們中華民族偉大復興！        

Linux異常處理結構、中斷處理結構

LINUX 的異常向量在哪裡：0xffff0000(可通過配置某個暫存器來配置) 1、ARM異常向量表 void __init trap_init(void)   //將0x00000000異常向量 複製到 0xffff0000 處     &

ARM學習筆記——異常與中斷——指令ldr及.word偽指令用法

在ARM彙編指令中，ldr是一條常用的記憶體訪問指令，如： ldr r1, [r2] //將地址為r2的記憶體單元位資料讀取到r1中 它也可以作為大範圍的地址讀取偽指令，如： ldr r1, =label //r1=label的地址 label:

【ARM】s3c2410中斷處理例項

目的    為了更好地掌握S3C2410中斷的原理及中斷程式的編寫。    內容利用S3C2410的外部中斷0和外部中斷1實現兩個按鍵功能原理    本次選擇的是外部中斷EXTINT0和EXTINT11。中斷的產生分別來自按鈕SB1202和SB1203，當按鈕按下時，EXT

ARM中的異常和中斷

        上電覆位後，進入管理模式，執行作業系統程式，一般用做對系統初始化，例如開中斷等；然後切換到使用者模式，開始執行正常的使用者程式。        切換到使用者模式可使用下列程式：         MRS R0,CPSR     ；讀狀態暫存器        BIC R0,R0,#03   ；把

ARM中斷處理過程

ARM有七種異常中斷型別，優先順序、工作模式（有七種工作模式）、地址、功能都不一樣。如其中軟體中斷SWI優先順序為6，工作模式管理模式，異常向量地址為0x00000008，功能是使用者定義的中斷指令，可用於使用者模式下的程式呼叫特權操作。 當中斷產生後，除了復位中斷立即中止

Linux kernel的中斷子系統之（六）：ARM中斷處理過程

總結：二中斷處理經過兩種模式：IRQ模式和SVC模式，這兩種模式都有自己的stack，同時涉及到異常向量表中的中斷向量。 三ARM處理器在感知到中斷之後，切換CPSR暫存器模式到IRQ；儲存CPSR和PC；mask irq；PC指向irq vector。 四進入中斷的IRQ模式相關處理，然後根據當前處於使用

【補充】關於ARM的PC指標異常返回處理（PC+8，PC+4，PC-4,PC-8情況）

要理解PC指標，首先就要好好了解LR指標連線暫存器LR（r14）：用來儲存和恢復PC暫存器的內容，它有兩個特殊功能。    （1）儲存子程式返回地址。使用BL或BLX時，跳轉指令自動把返回地址放入r14中；子程式通過把r14複製到PC來實現返回，通常用下列指令之一：     

ARM異常中斷返回的幾種情況

重要基礎知識：R15（PC）總是指向“正在取指”的指令，而不是指向“正在執行”的指令或正在“譯碼”的指令。一般來說，人們習慣性約定將“正在執行的指令作為參考點”，稱之為當前第一條指令，因此 PC總是指向第三條指令。當 ARM 狀態時，每條指令為 4 位元組長，所以 PC 始