聚合函式也叫分組函式，是對多行進行計算的一種函式，比如SUM、COUNT、AVG、MAX、MIN等等。

Oracle中為了增強擴充套件性，提供了一個自定義聚合函式的介面，ODCIAggregate()，使用者可以用Oracle支援的各類程式語言（PLSQL、C、C++、JAVA等）定義一個聚合函式，並在程式中按照一樣的語法進行使用。

實際應用中，使用到自定義聚合函式的場景極少，理由是：

1.PLSQL語言已經足夠豐富，可以輕鬆實現絕大部分聚合場景；

2.自定義聚合函式的效率不見得比直接PLSQL實現更高。

比如ITPUB上有個求加權中位數的帖子，答主給出了兩種方案的比較，實際上自定義聚合函式只是對PLSQL實現的一個包裝，詳細可以參考原文 

http://www.itpub.net/forum.php?mod=viewthread&tid=1377770

那麼，自定義聚合函式到底有啥用呢？個人覺得只有一個：封裝的需要，有時是為了改善程式碼可讀性，有時是基於技術細節的保密。

下面把Oracle官方文件的一個自定義聚合案例記錄一下，該案例中的函式SecondMax()是取第二大的數，實際上用分析函式分分鐘就可以解決，這不是一個恰當的使用場景，但可以解釋作為描述自定義聚合函式建立過程的樣例。

1. 定義一個包含ODCIAggregate例程的物件型別SecondMaxImpl:

   create type SecondMaxImpl as object
   (
     max NUMBER,          -- highest value seen so far 
     secmax NUMBER,       -- second highest value seen so far
     static function ODCIAggregateInitialize(sctx IN OUT SecondMaxImpl) 
       return number,
     member function ODCIAggregateIterate(self IN OUT SecondMaxImpl, 
       value IN number) return number,
     member function ODCIAggregateTerminate(self IN SecondMaxImpl, 
       returnValue OUT number, flags IN number) return number,
     member function ODCIAggregateMerge(self IN OUT SecondMaxImpl, 
       ctx2 IN SecondMaxImpl) return number
   );
   /
   

2. SecondMaxImpl型別具體實現:

   create or replace type body SecondMaxImpl is 
   static function ODCIAggregateInitialize(sctx IN OUT SecondMaxImpl) 
   return number is 
   begin
     sctx := SecondMaxImpl(0, 0);
     return ODCIConst.Success;
   end;
   
   member function ODCIAggregateIterate(self IN OUT SecondMaxImpl, value IN number) return number is
   begin
     if value > self.max then
       self.secmax := self.max;
       self.max := value;
     elsif value > self.secmax then
       self.secmax := value;
     end if;
     return ODCIConst.Success;
   end;
   
   member function ODCIAggregateTerminate(self IN SecondMaxImpl, 
       returnValue OUT number, flags IN number) return number is
   begin
     returnValue := self.secmax;
     return ODCIConst.Success;
   end;
   
   member function ODCIAggregateMerge(self IN OUT SecondMaxImpl, ctx2 IN SecondMaxImpl) return number is
   begin
     if ctx2.max > self.max then
       if ctx2.secmax > self.secmax then 
         self.secmax := ctx2.secmax;
       else
         self.secmax := self.max;
       end if;
       self.max := ctx2.max;
     elsif ctx2.max > self.secmax then
       self.secmax := ctx2.max;
     end if;
     return ODCIConst.Success;
   end;
   end;
   /
   

3. 建立使用者自定義聚合函式SecondMax:

   CREATE FUNCTION SecondMax (input NUMBER) RETURN NUMBER 
   PARALLEL_ENABLE AGGREGATE USING SecondMaxImpl;
   

4. 在sql語句中應用自定義聚合函式:

   SELECT SecondMax(salary), department_id
      FROM MyEmployees
      GROUP BY department_id
      HAVING SecondMax(salary) > 9000;