2. 程式人生 > >Gradle 使用教程之 Task 詳解

Gradle 使用教程之 Task 詳解

阿新 • • 發佈：2019-12-23

最近打算學習下 gradle 在 Android 中的使用，結果百度出來的文章都是介紹性文章，沒啥乾貨。後來找到 gradle 官網教程，自己對著擼。

Gradle 概述：

Gradle 是一個基於 Apache Ant 和 Apache Maven 概念的專案自動化構建工具。它使用一種基於 Groovy 的特定領域語言來宣告專案設定，而不是傳統的 XML。Gradle 就是工程的管理，幫我們做了依賴、打包、部署、釋出、各種渠道的差異管理等工作。

Gradle優勢：

  1. 一款最新的，功能最強大的構建工具，用它逼格更高

  2. 使用程式代替傳統的XML配置，專案構建更靈活

  3. 豐富的第三方外掛，讓你隨心所欲使用

  4. Maven、Ant能做的，Gradle都能做，但是Gradle能做的，Maven、Ant不一定能做。

Groovy 是一種基於JVM的敏捷開發語言，結合了Python、Ruby和Smalltalk的許多強大的特性。Groovy可以與Java完美結合，而且可以使用Java所有的庫，在語法上支援動態型別、閉包等新一代語言特性，無縫整合所有已經存在的Java類庫，既支援面向物件程式設計也支援面向過程程式設計

Groovy 優勢：

  1. 一種更加敏捷的程式語言
  2. 入門非常的容易，且功能非常的強大
  3. 既可以作為程式語言也可以作為指令碼語言

剛開始的時候，我對 Gradle 和 Groovy 傻傻分不清楚，以為都是一種語言。後來才懂了，gradle 是一個構建工具，使用的語言是 Groovy。

準備工作：

下面進入實戰。

首先為了使用 gradle，大家可以在  Android studio 新建一個 Android 工程。使用其他 IDE 或者需要配置的環境的朋友，可以自己百度相關文章。

文章示例基於  Gradle 5.1.1 構建的。 

 Task 

Gradle 中的所有內容都基於兩個基本概念：專案和任務。

每個 Gradle 構建都由一個或多個專案組成。專案代表什麼取決於您在 Gradle 中所做的事情。例如，一個專案可能代表一個 JAR 庫或一個 Web 應用程式。它可能表示從其他專案產生的 JAR 組裝而成的發行版 ZIP。專案不一定代表要構建的事物。它可能表示要完成的事情，例如將應用程式部署到暫存或生產環境。暫時不要擔心這似乎還不清楚。Gradle 的按慣例構建支援為專案的定義添加了更具體的定義。

每個專案由一個或多個任務組成。任務代表構建執行的一些原子工作。這可能是編譯某些類，建立 JAR，生成 Javadoc 或將一些存檔釋出到儲存庫。

現在，將研究在一個專案中構建一些簡單的任務。後面的章節將介紹處理多個專案，以及有關處理專案和任務的更多資訊。

Hello world 

同樣，也是先從 hello world 入門。您可以使用以下 gradle 命令執行 Gradle 構建。該 gradle 命令在當前目錄中查詢名為 build.gradle 的檔案。這個 build.gradle 檔案稱為構建指令碼，儘管嚴格來說，它是一個構建配置指令碼，我們將在後面看到。構建指令碼定義專案及其任務。

要嘗試此操作，請建立以下名為的構建指令碼 build.gradle。

例子1. 第一個構建指令碼，在 android 專案中找到 build.gradle，在裡面新增以下程式碼： 
// build.gradle
task hello {
    doLast {
        println 'Hello world!'
    }
}

在專案的移至包含的目錄並使用以下命令執行構建指令碼：

./gradlew -q hello // Android 使用者在根目錄使用 ./gradlew
gradle -q hello  // 非 Android 使用者使用 gradle

使用 -q 命令列選項執行。這將取消 Gradle 的日誌訊息，因此僅顯示任務的輸出。這樣可以使示例輸出更加清晰。如果不想，則不需要使用此選項。

後面直接將執行構建指令碼的命令放在註釋前，不在單行作為展示了。

定義任務

在這裡，你將看到了如何使用字串作為任務名稱來定義任務。此樣式有一些變體，您可能需要在某些情況下使用。

task('hello') {
    doLast {
        println "hello"
    }
}

task('copy', type: Copy) {
    from(file('srcDir'))
    into(buildDir)
}

上面建立了兩個任務分別是 hello 和 copy。有一種定義任務的替代語法，您可能更喜歡使用：

tasks.create('hello') {
    doLast {
        println "hello"
    }
}

tasks.create('copy', Copy) {
    from(file('srcDir'))
    into(buildDir)
}

上面同樣建立了兩個任務分別是 hello 和 copy。 最後，Groovy 和 Kotlin DSL 有特定於語言的語法：

// Using Groovy dynamic keywords

task(hello) {
    doLast {
        println "hello"
    }
}

task(copy, type: Copy) {
    from(file('srcDir'))
    into(buildDir)
}

採用程式碼構建指令碼

Gradle 的構建指令碼為您提供了 Groovy 和 Kotlin 的全部功能。作為一個開胃菜，看看這個：在Gradle的任務中使用 Groovy 或 Kotlin ：

// gradle -q upper
task upper {
    doLast {
        String someString = 'mY_nAmE'
        println "Original: $someString"
        println "Upper case: ${someString.toUpperCase()}"
    }
}
// gradle -q count
task count {
    doLast {
        4.times { print "$it " }
    }
}
 

任務之間的依賴

任務之間可以具有依賴性，關鍵字 dependsOn ：

// gradle -q intro
task hello {
    doLast {
        println 'Hello world!'
    }
}
task intro {
    dependsOn hello
    doLast {
        println "I'm Gradle"
    }
}

上面的依賴是依賴的任務先宣告，然後再進行依賴，還有一種依賴是懶惰性依賴，被依賴的任務可以後面再宣告，但是如果不宣告的會報錯：

// gradle -q taskX 
task taskX {
    dependsOn 'taskY'
    doLast {
        println 'taskX'
    }
}
task taskY {
    doLast {
        println 'taskY'
    }
}

任務 taskX 依賴的任務 taskY 是後宣告的。

您可以通過多種方式定義任務的依賴關係。在“ 任務依賴項”中，介紹了使用任務名稱定義依賴項。任務名稱可以引用與該任務在同一專案中的任務，也可以引用其他專案中的任務。要引用另一個專案中的任務，請在任務名稱前新增其所屬專案的路徑。以下是新增從 projectA:taskX 到的依賴的示例 projectB:taskY：

// gradle -q taskX
project('projectA') {
    task taskX {
        dependsOn ':projectB:taskY'
        doLast {
            println 'taskX'
        }
    }
}

project('projectB') {
    task taskY {
        doLast {
            println 'taskY'
        }
    }
}

此處的 projectA，projectB 要改成你專案中的名字，簡單來說，就是不同層級的任務也是可以相互依賴的。

動態任務

Groovy 或 Kotlin 的功能可用於定義任務以外的其他功能。例如，您也可以使用它來動態建立任務。

// gradle -q task1
4.times { counter ->
    task "task$counter" {
        doLast {
            println "I'm task number $counter"
        }
    }
}

 上述建立了 4 個 task，分別是 task0，task1，task2，task3。

操作已建立的任務

任務建立後，就可以通過 API 對其進行訪問。例如，您可以在執行時為任務動態新增依賴項。

// gradle -q task0
4.times { counter ->
    task "task$counter" {
        doLast {
            println "I'm task number $counter"
        }
    }
}
task0.dependsOn task2, task3

或者，您可以將行為新增到現有任務。

// gradle -q hello
task hello {
    doLast {
        println 'Hello Earth'
    }
}
hello.doFirst {
    println 'Hello Venus'
}
hello.configure {
    doLast {
        println 'Hello Mars'
    }
}
hello.configure {
    doLast {
        println 'Hello Jupiter'
    }
}

呼叫 doFirst 和 doLast 可以執行多次。他們將操作新增到任務操作列表的開頭或結尾。執行任務時，將按順序執行操作列表中的操作。

Groovy DSL快捷方式符號

訪問現有任務有一種方便的表示法。每個任務都可以作為構建指令碼的屬性來使用：

// gradle -q hello
task hello {
    doLast {
        println 'Hello world!'
    }
}
hello.doLast {
    println "Greetings from the $hello.name task."
}

例子中，通過獲取任務的名字可以知道這個是來自於 task hello 的任務所做的事。這樣可以提高程式碼的可讀性，尤其是在使用外掛提供的任務（例如compile任務）時。

額外任務屬性

您可以將自己的屬性新增到任務上。要新增名為的屬性 myProperty，併為 ext.myProperty 設定初始值。就可以像預定義的任務屬性一樣讀取和設定屬性。

// gradle -q printTaskProperties
task myTask {
    ext.myProperty = "myValue"
}

task printTaskProperties {
    doLast {
        println myTask.myProperty
    }
}

預設任務

如果未指定其他任務，則Gradle允許您定義一個或多個預設任務。

// gradle -q
defaultTasks 'clean', 'run'

task clean {
    doLast {
        println 'Default Cleaning!'
    }
}

task run {
    doLast {
        println 'Default Running!'
    }
}

task other {
    doLast {
        println "I'm not a default task!"
    }
}

這等效於執行 gradle clean run。在多專案構建中，每個子專案都可以有其自己的特定預設任務。如果子專案未指定預設任務，則使用父專案的預設任務（如果已定義）

通過DAG進行配置

正如我們稍後將詳細描述的（請參閱 Build Lifecycle），Gradle具有配置階段和執行階段。在配置階段之後，Gradle 知道應該執行的所有任務。Gradle 為您提供了一個利用此資訊的機會。一個用例是檢查釋出任務是否在要執行的任務中。以此為基礎，您可以為某些變數分配不同的值。

在以下示例中，distribution 和 release 任務的執行導致 version 變數的值不同。

// gradle -q distribution
// gradle -q release
task distribution {
    doLast {
        println "We build the zip with version=$version"
    }
}

task release {
    dependsOn 'distribution'
    doLast {
        println 'We release now'
    }
}

gradle.taskGraph.whenReady { taskGraph ->
    if (taskGraph.hasTask(":release")) {
        version = '1.0'
    } else {
        version = '1.0-SNAPSHOT'
    }
}

可以發現，此處，執行不同的 task 具有不同結果。

構建指令碼的外部依賴關係

如果構建指令碼需要使用外部庫，則可以將它們新增到構建指令碼本身中的指令碼的類路徑中。您可以使用 buildscript() 方法執行此操作，並傳入一個宣告構建指令碼類路徑的塊。

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath group: 'commons-codec', name: 'commons-codec', version: '1.2'
    }
}

 buildscript()方法中的程式碼塊將構成 ScriptHandler 例項。您可以通過向 classpath 配置新增依賴項來宣告構建指令碼類路徑。這與您宣告 Java 編譯類路徑的方式相同。您可以使用除專案依賴項以外的任何 依賴項型別。

聲明瞭構建指令碼類路徑後，就可以像在該類路徑上的任何其他類一樣使用構建指令碼中的類。以下示例將新增到前面的示例中，並使用構建指令碼類路徑中的類。

// gradle -q encode
import org.apache.commons.codec.binary.Base64

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath group: 'commons-codec', name: 'commons-codec', version: '1.2'
    }
}

task encode {
    doLast {
        def byte[] encodedString = new Base64().encode('hello world\n'.getBytes())
        println new String(encodedString)
    }
}

這裡先是添加了依賴項，然後再建立了一個任務，引用了依賴項中的類來實現對字串的加密。

訪問任務的屬性

您通常需要找到在構建檔案中定義的任務，例如，對其進行配置或將其用於依賴項。有很多方法可以做到這一點。首先，就像定義任務一樣，Groovy和Kotlin DSL具有特定於語言的語法

task hello
task copy(type: Copy)

// Access tasks using Groovy dynamic properties on Project

println hello.name
println project.hello.name

println copy.destinationDir
println project.copy.destinationDir

任務也可以通過 tasks 集合獲得。

task hello
task copy(type: Copy)

println tasks.hello.name
println tasks.named('hello').get().name

println tasks.copy.destinationDir
println tasks.named('copy').get().destinationDir

您可以使用 tasks.getByPath() 方法使用任務的路徑從任何專案訪問任務。您可以 getByPath() 使用任務名稱，相對路徑或絕對路徑來呼叫該方法。

project(':projectA') {
    task hello
}

task hello

println tasks.getByPath('hello').path
println tasks.getByPath(':hello').path
println tasks.getByPath('projectA:hello').path
println tasks.getByPath(':projectA:hello').path

將引數傳遞給任務建構函式

與 Task 在建立後配置變數的可變屬性相反，您可以將引數值傳遞給 Task 類的建構函式。為了將值傳遞給 Task 建構函式，您必須使用註釋相關的建構函式 @javax.inject.Inject。

class CustomTask extends DefaultTask {
    final String message
    final int number

    @Inject
    CustomTask(String message, int number) {
        this.message = message
        this.number = number
    }
}

然後，您可以建立一個任務，並在引數列表的末尾傳遞建構函式引數。

tasks.create('myTask', CustomTask, 'hello', 42)
task myTask(type: CustomTask, constructorArgs: ['hello', 42])

上述兩種方法都可以。在所有情況下，作為建構函式引數傳遞的值都必須為非 null。如果您嘗試傳遞一個 null 值，Gradle 將丟擲一個 NullPointerException 指示，指出哪個執行時值是 null。

向任務新增描述

您可以在任務中新增描述。執行 gradle tasks 時將顯示此描述。

// gradle tasks
task copy(type: Copy) {
   description 'Copies the resource directory to the target directory.'
   from 'resources'
   into 'target'
   include('**/*.txt', '**/*.xml', '**/*.properties')
}

更換任務

有時您想替換任務。例如，如果要將 Java 外掛新增的任務與其他型別的自定義任務交換。您可以使用以下方法實現此目的：

// gradle -q copy
task copy(type: Copy)

task copy(overwrite: true) {
    doLast {
        println('I am the new one.')
    }
}

定義新任務時，必須將 overwrite 屬性設定為 true。否則，Gradle 會引發異常，說該名稱的任務已經存在。

跳過任務

Gradle 提供了多種方法來跳過任務的執行。

使用謂詞

您可以使用該 onlyIf() 方法將謂詞附加到任務。僅當謂詞評估為 true 時，才執行任務的動作。您將謂詞實現為閉包。閉包作為引數傳遞給任務，如果任務應執行，則應返回 true；如果應跳過任務，則應返回 false。在即將執行任務之前就對謂詞進行評估。

// gradle hello -PskipHello
task hello {
    doLast {
        println 'hello world'
    }
}

hello.onlyIf { !project.hasProperty('skipHello') }

使用StopExecutionException

如果不能用謂詞來表示跳過任務的邏輯，則可以使用 StopExecutionException。如果某個動作引發了此異常，則將跳過該動作的進一步執行以及該任務的任何後續動作的執行。構建繼續執行下一個任務。

// gradle -q myTask
task compile {
    doLast {
        println 'We are doing the compile.'
    }
}

compile.doFirst {
    // Here you would put arbitrary conditions in real life.
    // But this is used in an integration test so we want defined behavior.
    if (true) { throw new StopExecutionException() }
}
task myTask {
    dependsOn('compile')
    doLast {
        println 'I am not affected'
    }
}

啟用和禁用任務

每個任務都有一個 enabled 預設為的標誌 true。將其設定為 false 阻止執行任何任務動作。禁用的任務將標記為“跳過”。

task disableMe {
    doLast {
        println 'This should not be printed if the task is disabled.'
    }
}
disableMe.enabled = false

任務超時

每個任務都有一個 timeout 可用於限制其執行時間的屬性。當任務達到超時時，其任務執行執行緒將被中斷。該任務將被標記為失敗。終結器任務仍將執行。如果 --continue 使用，其他任務可以在此之後繼續執行。不響應中斷的任務無法超時。Gradle 的所有內建任務均會及時響應超時

task hangingTask() {
    doLast {
        Thread.sleep(100000)
    }
    timeout = Duration.ofMillis(500)
}

任務規則

有時您想執行一個任務，該任務的行為取決於較大或無限數量的引數值範圍。提供此類任務的一種非常好的表達方式是任務規則：

// gradle -q pingServer1
tasks.addRule("Pattern: ping<ID>") { String taskName ->
    if (taskName.startsWith("ping")) {
        task(taskName) {
            doLast {
                println "Pinging: " + (taskName - 'ping')
            }
        }
    }
}

規則不僅在從命令列呼叫任務時使用。您還可以在基於規則的任務上建立 dependsOn 關係：

// gradle -q groupPing
tasks.addRule("Pattern: ping<ID>") { String taskName ->
    if (taskName.startsWith("ping")) {
        task(taskName) {
            doLast {
                println "Pinging: " + (taskName - 'ping')
            }
        }
    }
}

task groupPing {
    dependsOn pingServer1, pingServer2
}

如果執行“ gradle -q tasks”，將找不到名為“ pingServer1”或“ pingServer2” 的任務，但是此指令碼正在根據執行這些任務的請求執行邏輯。

Finalizer tasks

當計劃執行終結任務時，Finalizer tasks 會自動新增到任務圖中。

// gradle -q taskX
task taskX {
    doLast {
        println 'taskX'
    }
}
task taskY {
    doLast {
        println 'taskY'
    }
}

taskX.finalizedBy taskY

即使終結任務失敗，也將執行 Finalizer tasks。

// gradle -q taskX
task taskX {
    doLast {
        println 'taskX'
        throw new RuntimeException()
    }
}
task taskY {
    doLast {
        println 'taskY'
    }
}

taskX.finalizedBy taskY 

執行結果：

Output of gradle -q taskX
> gradle -q taskX
taskX
taskY

FAILURE: Build failed with an exception.

* Where:
Build file '/home/user/gradle/samples/groovy/build.gradle' line: 4

* What went wrong:
Execution failed for task ':taskX'.
> java.lang.RuntimeException (no error message)

* Try:
Run with --stacktrace option to get the stack trace. Run with --info or --debug option to get more log output. Run with --scan to get full insights.

* Get more help at https://help.gradle.org

BUILD FAILED in 0s

在構建建立無論構建失敗還是成功都必須清除的資源的情況下，終結器任務很有用。這種資源的一個示例是一個Web容器，它在整合測試任務之前啟動，並且即使某些測試失敗，也應始終將其關閉。

要指定終結器任務，請使用 Task.finalizedBy（java.lang.Object ...） 方法。此方法接受Task例項，任務名稱或 Task.dependsOn（java.lang.Object…） 接受的任何其他輸入。

到此，關於 task 的講解到這裡就結束了。

相關推薦

Gradle 使用教程之 Task 詳解

最近打算學習下 gradle 在 Android 中的使用，結果百度出來的文章都是介紹性文章，沒啥乾貨。後來找到 gradle 官網教程，自己對著擼。 Gradle 概述： Gradle 是一個基於 Apache Ant 和 Apache Maven 概念的專案自動化構建工具。它使用一種基於 Groovy

Vue 進階教程之：詳解 v-model

com 方式 事件 變化 復習 簡寫 mage fine 需要 分享 Vue 官網教程上關於 v-model 的講解不是十分的詳細，寫這篇文章的目的就是詳細的剖析一下， 並介紹 Vue 2.2 v-model改進的地方，然後穿插的再說點 Vue 的小知識。 在 Vue 中，

Android Gradle 自定義Task 詳解

png 發布 我們 批處理 使用總結 實用 shift fonts 博客 轉載請標明出處：http://blog.csdn.net/zhaoyanjun6/article/details/76408024 本文出自【趙彥軍的博客】 一：Gradle 是什麽 Gradl

ShadeGraph教程之節點詳解8：UV Nodes

本文首發於洪流學堂微信公眾號。 洪流學堂，學Unity快人幾步 洪流學堂公眾號回覆節點，獲取ShaderGraph節點詳解PDF檔案（帶目錄）。 UV Nodes UV節點 與UV相關的節點。 Flipbook 圖象序列 建立一個影象畫素列，作為

ShadeGraph教程之節點詳解7：Utility Nodes

本文首發於洪流學堂微信公眾號。 洪流學堂，學Unity快人幾步 洪流學堂公眾號回覆節點，獲取ShaderGraph節點詳解PDF檔案（帶目錄）。 Utility Nodes 工具節點 一些有用的工具節點。 Preview 預覽 顯示一個預覽視窗，

Gradle技術之四 - Gradle的Task詳解

1 Gradle的Task詳解 1 Task定義和配置 2 Task的執行 3 Task的依賴和執行順序 4 Task型別 5 Task結合gradle的生命週期 6 Task實戰 1.1 Task定義和配置 1.1.1 檢視所有的task ./gradlew tasks

javaweb之監聽器詳解

兩個 rec roman 虛擬 銷毀 mar host swap 技術 在servlet中定義了多種類型的監聽器，他們用於監聽事件源分別是servletContext,httpsession,servletrequest 這三個域對象。 servlet中監聽器主要有三類：

IO測試工具之fio詳解

沒有 性能 同時 rac 目前 code linux系統 安裝 enc 目前主流的第三方IO測試工具有fio、iometer和Orion，這三種工具各有千秋。 fio在Linux系統下使用比較方便，iometer在window系統下使用比較方便，Orion是oracle的I

多媒體開發庫 之 SDL 詳解

詳解 lang 模擬 llb 創建 mac os 視頻 內置 bsp SDL 簡介 SDL（Simple DirectMedia Layer）是一套開放源代碼的跨平臺多媒體開發庫，使用C語言寫成。SDL提供了數種控制圖像、聲音、輸出入的函數，讓開發者只要用相同或是相似的代碼

Hadoop之WordCount詳解

ride 開始 zookeepe ati 程序 form 數組 -c 狀態 花了好長時間查找資料理解、學習、總結 這應該是一篇比較全面的MapReduce之WordCount文章了 耐心看下去 1，創建本地文件 在hadoop-2.6.0文件夾下創建一個文件夾data，在其

MVC 5 + EF6 完整教程16 -- 控制器詳解

cpp tpc 當我 出了 多個 展現 dts model類 路由規則 Controller作為持久層和展現層的橋梁, 封裝了應用程序的邏輯，是MVC中的核心組件之一。 本篇文章我們就來談談 Controller, 主要討論兩個方面： Controller運行機制簡介 C

CEF3開發者系列之CefEnableHighDPISupport詳解

html use enable val 情況 immediate zoom brush 放大 在CEF3中，CefEnableHighDPISupport()這個接口函數在使用時一般不為人所註意，但是如果稍有不慎，會造成打開的網頁不能填滿窗口的問題。如果是需要flash插件

Linux性能監控命令之lsof詳解

轉換 device symbol 能夠 基礎 打開 init 可執行文件 ive 1. lsof 命令介紹 lsof(list open files)是一個列出當前系統打開文件的工具。在linux環境下，任何事物都以文件的形式存在，通過文件不僅僅可以訪問常規數據，還可以訪問

MySQL官方教程及各平臺的安裝教程和配置詳解入口

www 官方 apt源 nbsp chrom 版本選擇 rom gui apt 官方文檔入口： https://dev.mysql.com/doc/ 一般選擇MySQL服務器版本入口： https://dev.mysql.com/doc/refman/en/

Linux命令之CP詳解

linux命令之cp詳解Linux命令之CP詳解嘿嘿，又一周過去了，大家過的怎麽樣呢，在這一周時間裏，小編可是又學到不少新知識呢。今天呢，小編就和大家分享一下Linux中我們常用的CP的命令，這裏的cp可是copy的簡寫噢。（容我嘚瑟一下） 學過linux的都知道，在我們操作的過程中，我們常常會用到cp這個命

aNDROID之MEDIapLaYER詳解

iap music media 詳解 list oid aid 5% layer %E8%BD%AC%E8%BD%BD%E4%B8%80%E4%B8%AA%E5%9B%BE%E7%89%87%E5%A4%84%E7%90%86%E5%B7%A5%E5%85%B7%E7%B1

MyBatis之Mapper詳解及常用技巧

mybatis mapperselect先看一個簡單的案例:<select id="selectPerson" parameterType="int" resultType="hashmap"> SELECT * FROM PERSON WHERE ID = #{id} </selec

[持續交付實踐] pipeline：pipeline 使用之語法詳解

安裝工具 詳細 href 3.0 def 實現 能夠 action roo 一、引言 jenkins pipeline語法的發展如此之快用日新月異來形容也不為過，而目前國內對jenkins pipeline關註的人還非常少，相關的文章更是稀少，唯一看到w3c有篇相關的估計是

python模塊之XlsxWriter 詳解

som hnu ima conf all 合並單元格 stack from pen Xlsx是python用來構造xlsx文件的模塊，可以向excel2007+中寫text，numbers，formulas 公式以及hyperlinks超鏈接。 可以完成xlsx文件的自動化

MySQL之索引詳解

分布 i/o .cn 能夠 b+ images 電路 普通 磁道 這篇博客將要闡述為什麽使用b+樹作為索引，而不是b樹或者其他樹 1.什麽是b樹